It is used to find text or images on the screen.
Hope you like it !
Detailed usage can refer to:
1、The introduction by ed1chandler.
2、The introduction by c4p (latest).
Code: Select all
;/*
;===========================================
; FindText - Capture screen image into text and then find it
; https://autohotkey.com/boards/viewtopic.php?f=6&t=17834
;
; Author : FeiYue
; Version : 8.1
; Date : 2021-02-19
;
; Usage: (required AHK v1.1.31+)
; 1. Capture the image to text string.
; 2. Test find the text string on full Screen.
; 3. When test is successful, you may copy the code
; and paste it into your own script.
; Note: Copy the "FindText()" function and the following
; functions and paste it into your own script Just once.
; 4. The more recommended way is to save the script as
; "FindText.ahk" and copy it to the "Lib" subdirectory
; of AHK program, instead of copying the "FindText()"
; function and the following functions, add a line to
; the beginning of your script: #Include <FindText>
;
;===========================================
;*/
if (!A_IsCompiled and A_LineFile=A_ScriptFullPath)
FindText.Gui("Show")
;===== Copy The Following Functions To Your Own Code Just once =====
;--------------------------------
; FindText - Capture screen image into text and then find it
;--------------------------------
; returnArray := FindText(
; X1 --> the search scope's upper left corner X coordinates
; , Y1 --> the search scope's upper left corner Y coordinates
; , X2 --> the search scope's lower right corner X coordinates
; , Y2 --> the search scope's lower right corner Y coordinates
; , err1 --> Fault tolerance percentage of text (0.1=10%)
; , err0 --> Fault tolerance percentage of background (0.1=10%)
; , Text --> can be a lot of text parsed into images, separated by "|"
; , ScreenShot --> if the value is 0, the last screenshot will be used
; , FindAll --> if the value is 0, Just find one result and return
; , JoinText --> if the value is 1, Join all Text for combination lookup
; , offsetX --> Set the max text offset (X) for combination lookup
; , offsetY --> Set the max text offset (Y) for combination lookup
; , dir --> Four directions for searching: up, down, left and right
; )
;
; The function returns a second-order array containing
; all lookup results, Any result is an associative array
; {1:X, 2:Y, 3:W, 4:H, x:X+W//2, y:Y+H//2, id:Comment}
; if no image is found, the function returns 0.
; All coordinates are relative to Screen, colors are in RGB format
;
; If the return variable is set to "ok", ok.1 is the first result found.
; Where ok.1.1 is the X coordinate of the upper left corner of the found image,
; and ok.1.2 is the Y coordinate of the upper left corner of the found image,
; ok.1.3 is the width of the found image, and ok.1.4 is the height of the found image,
; ok.1.x <==> ok.1.1+ok.1.3//2 ( is the Center X coordinate of the found image ),
; ok.1.y <==> ok.1.2+ok.1.4//2 ( is the Center Y coordinate of the found image ),
; ok.1.id is the comment text, which is included in the <> of its parameter.
; ok.1.x can also be written as ok[1].x, which supports variables. (eg: ok[A_Index].x)
;
;--------------------------------
FindText(args*)
{
return FindText.FindText(args*)
}
Class FindText
{ ;// Class Begin
static bind:=[], bits:=[], Lib:=[]
__New()
{
this.bind:=[], this.bits:=[], this.Lib:=[]
}
__Delete()
{
if (this.bits.hBM)
DllCall("DeleteObject", "Ptr",this.bits.hBM)
}
FindText(x1:=0, y1:=0, x2:=0, y2:=0, err1:=0, err0:=0
, text:="", ScreenShot:=1, FindAll:=1
, JoinText:=0, offsetX:=20, offsetY:=10, dir:=1)
{
local
SetBatchLines, % (bch:=A_BatchLines)?"-1":"-1"
if (x1*x1+y1*y1+x2*x2+y2*y2)<=0
n:=150000, x:=y:=-n, w:=h:=2*n
else
x:=Min(x1,x2), y:=Min(y1,y2), w:=Abs(x2-x1)+1, h:=Abs(y2-y1)+1
bits:=this.GetBitsFromScreen(x,y,w,h,ScreenShot,zx,zy,zw,zh)
, info:=[]
Loop, Parse, text, |
if IsObject(j:=this.PicInfo(A_LoopField))
info.Push(j)
if (w<1 or h<1 or !(num:=info.MaxIndex()) or !bits.Scan0)
{
SetBatchLines, %bch%
return 0
}
arr:=[], in:={zx:zx, zy:zy, zw:zw, zh:zh
, sx:x-zx, sy:y-zy, sw:w, sh:h}, k:=0
For i,j in info
k+=Round(j.8=5 ? j.10 : j.2*j.3), in.comment .= j.11
VarSetCapacity(s1, k*4), VarSetCapacity(s0, k*4)
, VarSetCapacity(gs, (w+2)*(h+2)), VarSetCapacity(ss, w*h)
, JoinText:=(num=1 ? 0 : JoinText)
, allpos_max:=(FindAll or JoinText ? 10240 : 1)
, VarSetCapacity(allpos, allpos_max*2*4)
Loop, 2
{
if (err1=0 and err0=0) and (num>1 or A_Index>1 or info.1.8=5)
err1:=0.05, err0:=0.05
Loop, % JoinText ? 1 : num
{
this.PicFind(arr, in, info, A_Index, err1, err0, dir
, bits, 0, 0, offsetX, offsetY, gs, ss, s1, s0
, allpos, allpos_max, FindAll, JoinText)
if (!FindAll and arr.MaxIndex())
Break
}
if (err1!=0 or err0!=0 or arr.MaxIndex())
Break
}
SetBatchLines, %bch%
return arr.MaxIndex() ? arr:0
}
PicFind(arr, in, info, index, err1, err0, dir
, bits, x, y, offsetX, offsetY
, ByRef gs, ByRef ss, ByRef s1, ByRef s0
, ByRef allpos, allpos_max, FindAll, JoinText)
{
local
static MyFunc:=""
if (!MyFunc)
{
x32:=""
. "5557565383EC5C8B8424900000008B9424980000008B8C24940000008B7C2470"
. "01C23B9424880000000F4F94248800000089D68954242431D285C00F48C289C3"
. "8944243089F029D8894424108B84249C00000001C83B84248C0000000F4F8424"
. "8C00000085C90F49D183FF0589542438894424180F84BF0200008B9C24B80000"
. "0085DB0F8E5007000031C0897C2470C744240C00000000C744240800000000C7"
. "4424040000000031EDC74424140000000089C78B4C24088BB424B40000008B5C"
. "24148B54240C01CE89C829CB8B8C24B4000000039C24B000000085C97E618934"
. "2489F989D6EB2189F68DBC27000000008BBC24AC00000083C60483C0018914AF"
. "83C501390424742A837C24700389F20F45D0803C033175D88BBC24A800000083"
. "C60483C00139042489148F8D790189F975D68BB424B40000000174241489CF83"
. "442404018B5C24108B442404015C24088B9C2484000000015C240C398424B800"
. "00000F854BFFFFFF897C24288B7C247031C08B74242839B424BC0000000F4DF0"
. "39AC24C0000000897424280F4DE839EE0F4CF583FF038974243C0F84A9010000"
. "8B4424388B7424188B4C243029C60FAF842484000000C1E1028974241C894C24"
. "2C01C88B8C2484000000894424148B442410F7D885FF8D0481894424200F853D"
. "0300008B442474C1E81085F60FB6C0894424048B4424740FB6C4894424080FB6"
. "4424748944240C0F8EEB0000008B442410C744241800000000C7442424000000"
. "00896C24448D3C8500000000897C242C897C24348B7C2440908DB42600000000"
. "8B44241085C00F8E890000008B4424148BB424800000008B6C242403AC24A400"
. "000001C60344242C038424800000008904240FB67E028B4C24040FB6160FB646"
. "012B54240C2B44240889FB01CF29CB8D8F000400000FAFC00FAFCBC1E00B0FAF"
. "CBBBFE05000029FB0FAFDA01C80FAFD301C2395424780F93450083C60483C501"
. "3B342475AD8B742434017424148B7424100174242483442418018B4C24208B44"
. "2418014C24143944241C0F8550FFFFFF8B6C2444897C24408B4424102B8424B4"
. "000000C644242000C744240400000000C7042400000000C74424180100000089"
. "4424088B44241C2B8424B8000000C644241C008944240CEB558B442478894424"
. "3C8B4424748944244083FF058B4424240F9444242083FF030F9444241C2B8424"
. "B4000000894424088B4424182B8424B8000000C7442418000000008944240C8B"
. "442438894424048B4424308904248B44247C83E80283F8020F874E090000837C"
. "247C020F8403030000837C247C030F842C0300008B742408C744241400000000"
. "3B34248B7C24040F8CD10200003B7C240CC7442448040000000F8F5706000080"
. "7C2420000F8554060000807C241C000F85740700008B4424108B54243C0FAFC7"
. "01F085D289C18944244C0F8E7F0000008B8424BC0000008B9C24C0000000038C"
. "24A40000008974242C8B742428897C243489D789442424895C244431C08D7600"
. "39F07D1C8B9C24A80000008B148301CA803A00750B836C2424010F8877080000"
. "39E87D1C8B9C24AC0000008B148301CA803A00740B836C2444010F8857080000"
. "83C00139F875B98B74242C8B7C24348B4C242885C974258B8424A80000008B54"
. "244C8D1C888B8C24A400000001D18B1083C00401CA39C3C6020075F28B5C2418"
. "8B4424308B4C24148B9424C40000000FAFC301F08904CA8B4424380FAFC301F8"
. "8944CA0483C1013B8C24C8000000894C24140F8DA60100008B44244883F8010F"
. "848001000083F8020F844606000083F8030F84CD07000083C701E9AEFEFFFF90"
. "83FF010F84E301000083FF020F84B60200008B4424740FB67C2474C1E8100FB6"
. "D08B4424748914240FB65424780FB6DC8B442478C1E8100FB6C88B4424780FB6"
. "F48B042429C8030C248944244889D829F001DE8B5C241C8944240489D089FA29"
. "C201F8890C2485DB8954241889742408894424240F8E5EFDFFFF8B442410896C"
. "244C8B6C2448C744240C00000000C744242C000000008D3C8500000000897C24"
. "34897C24448B4C241085C90F8E900000008B7C24148B8424800000008B54242C"
. "039424A400000001F8037C243403BC2480000000EB3D8D76008DBC2700000000"
. "391C247C3D394C24047F37394C24087C3189F10FB6F1397424180F9EC3397424"
. "240F9DC183C00483C20121D9884AFF39C7741E0FB658020FB648010FB63039DD"
. "7EBE31C983C00483C201884AFF39C775E28B7C2444017C24148B7C2410017C24"
. "2C8344240C018B7424208B44240C017424143944241C0F8549FFFFFF8B6C244C"
. "E973FCFFFF83C6013B7424080F8ECA04000083C7013B7C240C8B34247EEA8B44"
. "241483C45C5B5E5F5DC25C008B7C240CC7442414000000003B7C24048B34247C"
. "DD3B742408C7442448020000000F8E0CFDFFFF83EF01EBE0908DB42600000000"
. "8B3424C7442414000000003B7424088B7C24047FA93B7C240CC7442448030000"
. "000F8ED8FCFFFF83C601EBDF8B44247483C001C1E007894424748B44241C85C0"
. "0F8ED2FBFFFF8B442410896C24188B6C2474C7042400000000C7442404000000"
. "008D3C8500000000897C2408897C240C8B7C241085FF7E638B4424148B7C2408"
. "8B8C24800000008B5C2404039C24A400000001C703BC248000000001C18D7600"
. "0FB651020FB641010FB6316BC04B6BD22601C289F0C1E00429F001D039C50F97"
. "0383C10483C30139F975D58B7C240C017C24148B7C2410017C2404830424018B"
. "7424208B0424017424143944241C75808B6C2418E91FFBFFFF31EDC744242800"
. "000000E988F9FFFF8B44243883E801394424188904240F8C100100008B742430"
. "C744240C00000000896C243489F083E801894424208B04240FAF842484000000"
. "894424088B44241883C001894424148B4424248D780129F083C002894424188B"
. "442420394424240F8C9F0000008B0C248B5C24088B74240C035C242C2B742430"
. "039C2480000000C1E91F03B424A0000000894C2404EB5589F68DBC2700000000"
. "398424880000007E4C807C24040075458B0C24398C248C0000007E390FB64BFE"
. "83C3046BE9260FB64BF96BD14B8D4C15000FB66BF889EAC1E20429EA01CAC1FA"
. "078854060183C00139F8741889C2C1EA1F84D274ABC64406010083C00183C304"
. "39F875E88B7424180174240C830424018B8C24840000008B0424014C24083944"
. "24140F8537FFFFFF8B6C24348B4424108B74241C83C00285F6894424140F8ED5"
. "F9FFFF8B442414038424A0000000C744240801000000C744240C00000000896C"
. "2424894424048B44241C83C001894424188B44241083C004894424208B442478"
. "8B7C241085FF0F8E960000008B5424048B5C240C8B742420039C24A400000089"
. "D129F901D6890C24908DB426000000000FB642010FB62ABF0100000003442474"
. "39E8723C0FB66A0239E872348B0C240FB669FF39E872290FB66EFF39E872210F"
. "B669FE39E872190FB62939E872120FB66EFE39E873548D76008DBC2700000000"
. "89F98304240183C201880B83C60183C3018B3C24397C240475968B7424100174"
. "240C83442408018B4C24148B7C2408014C2404397C24180F8543FFFFFF8B6C24"
. "2489442478E9CEF8FFFF0FB63E39F80F92C189CFEBAA83EE01E982F9FFFF8B84"
. "24840000008B54243C0FAFC785D28D04B08944242C0F8E61FAFFFF8B8C24A800"
. "0000030189C18B8424AC0000008B00894424748B8424800000000FB614080FB6"
. "44247429C28B44244039D00F8C67FAFFFFF7D839D089C30F8F5BFAFFFFC74424"
. "2400000000EB448B9424A80000008B4424248B4C242C030C828B9424AC000000"
. "8B0482894424748B8424800000000FB65424740FB6040829D0394424400F8C15"
. "FAFFFF39D80F8C0DFAFFFF8B8424800000008B5424740FB64408010FB6D629D0"
. "394424400F8CEEF9FFFF39D80F8CE6F9FFFF8B8424800000000FB64408028B4C"
. "2474C1E9100FB6D129D0394424400F8CC4F9FFFF39D80F8CBCF9FFFF83442424"
. "018B4424243B44243C0F8558FFFFFFE968F9FFFF83C601E965FBFFFFC7442448"
. "01000000E976F8FFFF8B8424840000008B8C24800000000FAFC78D04B0894424"
. "2C034424740FB64C0102894C24248B8C24800000000FB64C0101894C24348B8C"
. "24800000000FB60401894424448B44243C85C00F8E03F9FFFF8B8424C0000000"
. "31D28974244C897C245089CB894424588B8424BC000000894424548B44244039"
. "5424287E6A8B8424A80000008B74242C0334900FB64433020FB64C33010FB634"
. "332B4C24342B74244489C7034424242B7C24240FAFC9897424408DB000040000"
. "C1E10B0FAFF70FAFF78B7C244001F1BEFE05000029C60FAFF70FAFF701CE3B74"
. "2478760B836C2454010F88AE00000039D57E668B8424AC0000008B74242C0334"
. "900FB64433020FB64C33010FB634332B4C24342B74244489C7034424242B7C24"
. "240FAFC9897424408DB000040000C1E10B0FAFF70FAFF78B7C244001F1BEFE05"
. "000029C60FAFF70FAFF701CE3B7424787707836C245801784483C2013B54243C"
. "0F8519FFFFFF894424408B74244C8B7C2450E9E5F7FFFF8B74242C8B7C2434E9"
. "14F8FFFF83C701E909FAFFFF8B7C2404C744241400000000E998F9FFFF894424"
. "408B74244C8B7C2450E9EAF7FFFF9090"
x64:=""
. "4157415641554154555756534883EC688B8424F80000004C8BAC242801000089"
. "54241C448944242C8B942400010000448B8424F000000044898C24C800000044"
. "01C23B9424E00000000F4F9424E00000004189D68954242031D24585C0440F48"
. "C24529C64489442428448B8424080100004101C0443B8424E8000000440F4F84"
. "24E800000085C00F49D083F9058954242444894424180F84980200008BB42440"
. "0100004531D24531FF85F60F8EB9000000448974240C488BB424200100004531"
. "E4448BB4243801000031FF31ED4531D24531FFC704240000000044895C241090"
. "4585F67E6348631424418D1C3E89F848039424300100004589E0EB1F0F1F4000"
. "83C0014D63DA4183C0044183C2014883C20139C347894C9D00742983F9034589"
. "C1440F45C8803A3175D683C0014D63DF4183C0044183C7014883C20139C34689"
. "0C9E75D74401342483C501037C240C4403A424D800000039AC24400100007580"
. "448B5C2410448B74240C31C04439BC2448010000440F4DF84439942450010000"
. "440F4DD04539D74489D0410F4DC783F903894424380F84A60100008B4424248B"
. "7C24188B74242829C70FAF8424D8000000897C240C8D04B08BB424D800000089"
. "4424304489F0F7D885C98D0486894424100F854D0300008B5C241C89DE4889D8"
. "440FB6E3C1EE100FB6C485FF400FB6F689C10F8E02010000428D04B500000000"
. "4C89AC2428010000448B6C242C44897C243CC7042400000000BDFE050000448B"
. "7C2430C74424180000000089CF894424204489542430662E0F1F840000000000"
. "4585F60F8E89000000488B9C24D00000004963C74531D24C8D4C030248635C24"
. "1848039C24180100000F1F8000000000450FB619410FB651FE410FB641FF4429"
. "E24489D94101F34189D0418D930004000029F129F80FAFD10FAFC00FAFD1C1E0"
. "0B8D040289EA4429DA410FAFD0410FAFD001D04139C5420F9304134983C20149"
. "83C1044539D67FA844037C242044017424188304240144037C24108B04243944"
. "240C0F8558FFFFFF448B7C243C448B5424304C8BAC24280100004489F02B8424"
. "38010000C644243000C644243C00C704240000000031EDC74424180100000089"
. "4424108B44240C2B8424400100008944240CEB4E8B44242C448B5C241C894424"
. "3883F9058B4424208B6C24280F9444243C83F9030F944424302B842438010000"
. "894424108B4424182B842440010000C7442418000000008944240C8B44242489"
. "04248B8424C800000083E80283F8020F87D009000083BC24C8000000020F84D3"
. "02000083BC24C8000000030F84EF0200008B5C24104531E439EB8B34240F8C9F"
. "0200003B74240CC744244C040000000F8FB4060000807C243C0089F00F85AF06"
. "0000807C2430000F85CC0700008B4C2438410FAFC685C9448D04180F8E8A0000"
. "004489642420895C244831C0448B8C24500100008BBC24480100004C8BA42418"
. "010000488B9C242001000044895C24404189CB4439F889C17D198B14834401C2"
. "4863D241803C1400750983EF010F88F70800004439D17D1C418B5485004401C2"
. "4863D241803C1400740A4183E9010F88D60800004883C0014139C37FB6448B64"
. "2420448B5C24408B5C24484585FF742F488B842420010000418D57FF4C8B8C24"
. "18010000488D4C90048B104883C0044401C24839C84863D241C604110075EA43"
. "8D04248B7C2418488B8C24580100004183C4014863D08B4424280FAFC701D889"
. "04918B4424240FAFC701F0443BA42460010000894491040F8D650100008B4424"
. "4C83F8010F844001000083F8020F849106000083F8030F844108000083C601E9"
. "9FFEFFFF83F9010F849801000083F9020F84A00200008B74241C89F0440FB6C6"
. "C1E8104489C30FB6F84889F08B74242C0FB6CC4189CC89F0440FB6CE4489E5C1"
. "E8104429CB0FB6D04889F0891C240FB6C489FE01D789C129C54489C84401C044"
. "8B44240C29D689C3428D04B5000000004101CC31D231C94585C0894424180F8E"
. "56FDFFFF44895C24204C89AC24280100004189D5448B5C2430448954243C4489"
. "7C24304189DF89CB0F1F8400000000004585F60F8ECF010000488B8C24D00000"
. "004963C34D63D531D24C03942418010000488D440102EB3C0F1F840000000000"
. "4439C77C4139CD7F3D4139CC7C3844390C24410F9EC04539CF0F9DC14421C141"
. "880C124883C2014883C0044139D60F8E6C010000440FB6000FB648FF440FB648"
. "FE4439C67EBA31C9EBD583C3013B5C24100F8E5505000083C6013B74240C89EB"
. "7EEB4489E04883C4685B5E5F5D415C415D415E415FC38B74240C4531E43B3424"
. "89EB7CDE3B5C2410C744244C020000000F8E3FFDFFFF83EE01EBE20F1F440000"
. "89EB4531E43B5C24108B34247FB43B74240CC744244C030000000F8E15FDFFFF"
. "83C301EBE08B54241C8B5C240C31F631FF428D2CB50000000083C201C1E20785"
. "DB8954241C0F8E0FFCFFFF44897C241844895424204C89AC2428010000448B64"
. "2430448B54240C8B5C241C4C8BBC24D0000000448B6C241044891C244585F67E"
. "584C63DF4C039C24180100004963C4498D4C07024531C0660F1F840000000000"
. "0FB6110FB641FF440FB649FE6BC04B6BD22601C24489C8C1E0044429C801D039"
. "C3430F9704034983C0014883C1044539C67FCD4101EC4401F783C6014501EC41"
. "39F27598448B1C24448B7C2418448B5424204C8BAC2428010000E95BFBFFFF90"
. "44035C24184501F583C30144035C2410395C240C0F8516FEFFFF448B5C242044"
. "8B7C2430448B54243C4C8BAC2428010000E924FBFFFF8B4424248D68FF396C24"
. "180F8C570100008B7424288B5C24188BBC24D8000000448954244C448B9424E0"
. "00000044897C244889F083C30144895C244083E801891C2431DB89442410C1E0"
. "0244897424508944241848984189DF48894424308B4424200FAFFD4C89AC2428"
. "010000448D600129F08BB424E800000083C0028944243C8B442410394424200F"
. "8CAA0000008B5C24184C8B7424304D63C74C63EF4C038424100100008D141F89"
. "EBC1EB1F4863D24989D14929D64C038C24D0000000EB56660F1F840000000000"
. "4139C27E5184DB754D39EE7E49410FB6490283C0014983C001446BD926410FB6"
. "49016BD14B418D0C134B8D140E4983C104460FB61C2A4489DAC1E2044429DA01"
. "CAC1FA07418850FF4139C4741D89C2C1EA1F84D274AA83C00141C600004983C1"
. "044983C0014139C475E344037C243C83C50103BC24D8000000392C240F8535FF"
. "FFFF448B5C2440448B7C2448448B54244C448B7424504C8BAC2428010000448B"
. "4C240C418D46024585C90F8EAAF9FFFF488BBC2410010000489844897C243048"
. "890424448B7C241CBD010000008B54242C448954243C4531E4488D7C07018B44"
. "240C4C89AC242801000044895C242083C001894424184963C6488D700348F7D0"
. "4889F34889C6418D46FF4989DA4989F54883C00148894424104585F60F8E8A00"
. "0000488B4424104963CC48038C24180100004D8D0C3A4D8D443D00488D343848"
. "89F80FB610440FB658FFBB010000004401FA4439DA723B440FB658014439DA72"
. "31450FB658FF4439DA7227450FB659FF4439DA721D450FB658FE4439DA721345"
. "0FB6184439DA720A450FB659FE4439DA734B4883C00188194983C1014883C101"
. "4983C0014839F075994501F483C50148033C24396C24180F855CFFFFFF448B5C"
. "2420448B7C2430448B54243C8954242C4C8BAC2428010000E97DF8FFFF450FB6"
. "194439DA0F92C3EBA983EB01E927F9FFFF0FAF8424D80000008B54243885D28D"
. "3C980F8E17FAFFFF488B842420010000488B9424D00000008B08418B450001F9"
. "4189C08944241C4863C10FB61402410FB6C029C24139D30F8C20FAFFFF4589D8"
. "41F7D84139D00F8F11FAFFFF8B442438895C24204531C98B5C241C83E80148C1"
. "E0024889442440EB6F4439C00F8C850000008D4102488B8C24D000000089DAC1"
. "EA1048980FB6D20FB6040129D04139C37C654439C07C604C3B4C24400F843C02"
. "0000488B842420010000488B9424D0000000438B5C0D04428B4C080401F94863"
. "C10FB604020FB6D329D04139C37C284983C1044439C07C1F488B9424D0000000"
. "8D410148980FB604020FB6D729D04139C30F8D72FFFFFF895C241C8B5C2420E9"
. "59F9FFFF83C301E9D8FAFFFFC744244C01000000E91CF8FFFF0FAF8424D80000"
. "00488BBC24D00000008D0498894424200344241C8D50024863D20FB63C178D50"
. "0148984863D289F9488BBC24D00000000FB63C17897C2440488BBC24D0000000"
. "0FB60407894424488B44243885C00F8EABF8FFFF8B842450010000895C245489"
. "CB488B8C24D000000031FF44896424508944245C8B8424480100008944245844"
. "39FF4189F97D76488B8424200100008B5424200314B88D42024898440FB61C01"
. "8D42014863D20FB6141148982B5424480FB604014589DC4101DB2B442440458D"
. "83000400004129DC450FAFC40FAFC0450FAFC4C1E00B4401C041B8FE05000045"
. "29D8440FAFC2410FAFD001C23B54242C760B836C2458010F88B30000004539D1"
. "7D6C8B542420410354BD008D42024898440FB61C018D42014863D20FB6141148"
. "982B5424480FB604014589D94101DB2B442440458D83000400004129D9450FAF"
. "C10FAFC0450FAFC1C1E00B4401C041B8FE0500004529D8440FAFC2410FAFD001"
. "C23B54242C7707836C245C0178424883C701397C24380F8F03FFFFFF448B6424"
. "508B5C2454E975F7FFFF448B642420448B5C24408B5C2448E9A0F7FFFF83C601"
. "E949F9FFFF8B34244531E4E9EAF8FFFF448B6424508B5C2454E97FF7FFFF895C"
. "241C8B5C2420E934F7FFFF9090909090"
this.MCode(MyFunc, A_PtrSize=8 ? x64:x32)
}
num:=info.MaxIndex(), j:=info[index]
, text:=j.1, w:=j.2, h:=j.3, mode:=j.8
, color:=j.9, n:=j.10, comment:=j.11
, e1:=(err1 and !j.12 ? Round(j.4*err1) : j.6)
, e0:=(err0 and !j.12 ? Round(j.5*err0) : j.7)
, sx:=in.sx, sy:=in.sy, sw:=in.sw, sh:=in.sh
, Scan0:=bits.Scan0, Stride:=bits.Stride
if (mode=3)
color:=(color//w)*Stride+Mod(color,w)*4
else if (mode=5)
{
r:=StrSplit(text,"/"), i:=0
Loop, % n
NumPut(r[3*i+2]*Stride+r[3*i+1]*4, s1, 4*i, "int")
, NumPut(r[3*i+3]&0xFFFFFF, s0, 4*i, "int"), i++
}
if (!JoinText or index=1)
x1:=sx, y1:=sy, x2:=sx+sw, y2:=sy+sh
else
{
x1:=x, y1:=Max(y-offsetY, sy)
, x2:=Min(x+offsetX+w, sx+sw)
, y2:=Min(y+offsetY+h, sy+sh)
}
ok:=!Scan0 ? 0:DllCall(&MyFunc
, "int",mode, "uint",color, "uint",n, "int",dir
, "Ptr",Scan0, "int",Stride, "int",in.zw, "int",in.zh
, "int",x1, "int",y1, "int",x2-x1, "int",y2-y1
, "Ptr",&gs, "Ptr",&ss, "Ptr",&s1, "Ptr",&s0
, "AStr",text, "int",w, "int",h, "int",e1, "int",e0
, "Ptr",&allpos, "int",allpos_max)
pos:=[]
Loop, % ok*2
pos[A_Index]:=NumGet(allpos, 4*(A_Index-1), "uint")
Loop, % ok
{
x:=pos[2*A_Index-1], y:=pos[2*A_Index]
if (!JoinText)
{
x1:=x+in.zx, y1:=y+in.zy
, arr.Push( {1:x1, 2:y1, 3:w, 4:h
, x:x1+w//2, y:y1+h//2, id:comment} )
}
else if (index=1)
{
in.x:=x+w, in.y:=y, in.minY:=y, in.maxY:=y+h
Loop, % num-1
if !this.PicFind(arr, in, info, A_Index+1, err1, err0, 3
, bits, in.x, in.y, offsetX, offsetY, gs, ss, s1, s0
, allpos, 1, FindAll, JoinText)
Continue, 2
x1:=x+in.zx, y1:=in.minY+in.zy
, w1:=in.x-x, h1:=in.maxY-in.minY
, arr.Push( {1:x1, 2:y1, 3:w1, 4:h1
, x:x1+w1//2, y:y1+h1//2, id:in.comment} )
}
else
{
in.x:=x+w, in.y:=y
, (y<in.minY && in.minY:=y)
, (y+h>in.maxY && in.maxY:=y+h)
return 1
}
if (!FindAll and arr.MaxIndex())
return
}
}
GetBitsFromScreen(ByRef x, ByRef y, ByRef w, ByRef h
, ScreenShot:=1, ByRef zx:="", ByRef zy:=""
, ByRef zw:="", ByRef zh:="")
{
local
static Ptr:="Ptr"
bits:=this.bits
if (!ScreenShot)
{
zx:=bits.zx, zy:=bits.zy, zw:=bits.zw, zh:=bits.zh
if IsByRef(x)
w:=Min(x+w,zx+zw), x:=Max(x,zx), w:=w-x
, h:=Min(y+h,zy+zh), y:=Max(y,zy), h:=h-y
return bits
}
bch:=A_BatchLines, cri:=A_IsCritical
Critical
if (id:=this.BindWindow(0,0,1))
{
WinGet, id, ID, ahk_id %id%
WinGetPos, zx, zy, zw, zh, ahk_id %id%
}
if (!id)
{
SysGet, zx, 76
SysGet, zy, 77
SysGet, zw, 78
SysGet, zh, 79
}
bits.zx:=zx, bits.zy:=zy, bits.zw:=zw, bits.zh:=zh
, w:=Min(x+w,zx+zw), x:=Max(x,zx), w:=w-x
, h:=Min(y+h,zy+zh), y:=Max(y,zy), h:=h-y
if (zw>bits.oldzw or zh>bits.oldzh or !bits.hBM)
{
if (bits.hBM)
DllCall("DeleteObject", Ptr,bits.hBM)
VarSetCapacity(bi, 40, 0), NumPut(40, bi, 0, "int")
NumPut(zw, bi, 4, "int"), NumPut(-zh, bi, 8, "int")
NumPut(1, bi, 12, "short"), NumPut(bpp:=32, bi, 14, "short")
bits.hBM:=DllCall("CreateDIBSection", Ptr,0, Ptr,&bi
, "int",0, "Ptr*",ppvBits:=0, Ptr,0, "int",0, Ptr)
bits.Scan0:=(!bits.hBM ? 0:ppvBits)
bits.Stride:=((zw*bpp+31)//32)*4
bits.oldzw:=zw, bits.oldzh:=zh
}
if (bits.hBM) and !(w<1 or h<1)
{
mDC:=DllCall("CreateCompatibleDC", Ptr,0, Ptr)
oBM:=DllCall("SelectObject", Ptr,mDC, Ptr,bits.hBM, Ptr)
if (id)
{
if (mode:=this.BindWindow(0,0,0,1))<2
{
hDC2:=DllCall("GetDCEx", Ptr,id, Ptr,0, "int",3, Ptr)
DllCall("BitBlt",Ptr,mDC,"int",x-zx,"int",y-zy,"int",w,"int",h
, Ptr,hDC2, "int",x-zx, "int",y-zy, "uint",0x00CC0020|0x40000000)
DllCall("ReleaseDC", Ptr,id, Ptr,hDC2)
}
else
{
VarSetCapacity(bi, 40, 0), NumPut(40, bi, 0, "int")
NumPut(zw, bi, 4, "int"), NumPut(-zh, bi, 8, "int")
NumPut(1, bi, 12, "short"), NumPut(32, bi, 14, "short")
hBM2:=DllCall("CreateDIBSection", Ptr,0, Ptr,&bi
, "int",0, "Ptr*",0, Ptr,0, "int",0, Ptr)
mDC2:=DllCall("CreateCompatibleDC", Ptr,0, Ptr)
oBM2:=DllCall("SelectObject", Ptr,mDC2, Ptr,hBM2, Ptr)
DllCall("PrintWindow", Ptr,id, Ptr,mDC2, "uint",(mode>3)*3)
DllCall("BitBlt",Ptr,mDC,"int",x-zx,"int",y-zy,"int",w,"int",h
, Ptr,mDC2, "int",x-zx, "int",y-zy, "uint",0x00CC0020|0x40000000)
DllCall("SelectObject", Ptr,mDC2, Ptr,oBM2)
DllCall("DeleteDC", Ptr,mDC2)
DllCall("DeleteObject", Ptr,hBM2)
}
}
else
{
win:=DllCall("GetDesktopWindow", Ptr)
hDC:=DllCall("GetWindowDC", Ptr,win, Ptr)
DllCall("BitBlt",Ptr,mDC,"int",x-zx,"int",y-zy,"int",w,"int",h
, Ptr,hDC, "int",x, "int",y, "uint",0x00CC0020|0x40000000)
DllCall("ReleaseDC", Ptr,win, Ptr,hDC)
}
DllCall("SelectObject", Ptr,mDC, Ptr,oBM)
DllCall("DeleteDC", Ptr,mDC)
}
Critical, %cri%
SetBatchLines, %bch%
return bits
}
PicInfo(text)
{
local
static info:=[]
if !InStr(text,"$")
return
if (info[text])
return info[text]
v:=text, comment:="", e1:=e0:=0, set_e1_e0:=0
; You Can Add Comment Text within The <>
if RegExMatch(v,"<([^>]*)>",r)
v:=StrReplace(v,r), comment:=Trim(r1)
; You can Add two fault-tolerant in the [], separated by commas
if RegExMatch(v,"\[([^\]]*)]",r)
{
v:=StrReplace(v,r), r:=StrSplit(r1, ",")
, e1:=r.1, e0:=r.2, set_e1_e0:=1
}
r:=StrSplit(v,"$"), color:=r.1, v:=r.2
mode:=InStr(color,"##") ? 5
: InStr(color,"-") ? 4 : InStr(color,"#") ? 3
: InStr(color,"**") ? 2 : InStr(color,"*") ? 1 : 0
color:=RegExReplace(color,"[*#]")
if (mode=5)
{
v:=StrReplace(RegExReplace(v,"\s"), ",", "/")
r:=StrSplit(Trim(v,"/"),"/"), n:=r.MaxIndex()//3
if (!n)
return
x1:=x2:=r.1, y1:=y2:=r.2, v:="", i:=1
Loop, % n
x:=r[3*A_Index-2], y:=r[3*A_Index-1]
, (x<x1 && x1:=x), (y<y1 && y1:=y)
, (x>x2 && x2:=x), (y>y2 && y2:=y)
Loop, % n
v.="/" (r[i++]-x1) "/" (r[i++]-y1) "/0x" r[i++]
v:=SubStr(v,2), w1:=x2-x1+1, h1:=y2-y1+1
}
else
{
r:=StrSplit(v,"."), w1:=r.1
, v:=this.base64tobit(r.2), h1:=StrLen(v)//w1
if (w1<1 or h1<1 or StrLen(v)!=w1*h1)
return
if (mode=4)
{
r:=StrSplit(StrReplace(color,"0x"),"-")
, color:=Round("0x" r.1), n:=Round("0x" r.2)
}
else
{
r:=StrSplit(color,"@")
, color:=r.1, n:=Round(r.2,2)+(!r.2)
, n:=Floor(512*9*255*255*(1-n)*(1-n))
}
StrReplace(v,"1","",len1), len0:=StrLen(v)-len1
, e1:=Round(len1*e1), e0:=Round(len0*e0)
}
return info[text]:=[v,w1,h1,len1,len0,e1,e0
, mode,color,n,comment,set_e1_e0]
}
; Bind the window so that it can find images when obscured
; by other windows, it's equivalent to always being
; at the front desk. Unbind Window using FindText.BindWindow(0)
BindWindow(bind_id:=0, bind_mode:=0, get_id:=0, get_mode:=0)
{
local
bind:=this.bind
if (get_id)
return bind.id
if (get_mode)
return bind.mode
if (bind_id)
{
bind.id:=bind_id, bind.mode:=bind_mode, bind.oldStyle:=0
if (bind_mode & 1)
{
WinGet, oldStyle, ExStyle, ahk_id %bind_id%
bind.oldStyle:=oldStyle
WinSet, Transparent, 255, ahk_id %bind_id%
Loop, 30
{
Sleep, 100
WinGet, i, Transparent, ahk_id %bind_id%
}
Until (i=255)
}
}
else
{
bind_id:=bind.id
if (bind.mode & 1)
WinSet, ExStyle, % bind.oldStyle, ahk_id %bind_id%
bind.id:=0, bind.mode:=0, bind.oldStyle:=0
}
}
MCode(ByRef code, hex)
{
local
ListLines, % (lls:=A_ListLines=0?"Off":"On")?"Off":"Off"
SetBatchLines, % (bch:=A_BatchLines)?"-1":"-1"
VarSetCapacity(code, len:=StrLen(hex)//2)
Loop, % len
NumPut("0x" SubStr(hex,2*A_Index-1,2),code,A_Index-1,"uchar")
DllCall("VirtualProtect","Ptr",&code,"Ptr",len,"uint",0x40,"Ptr*",0)
SetBatchLines, %bch%
ListLines, %lls%
}
base64tobit(s)
{
local
Chars:="0123456789+/ABCDEFGHIJKLMNOPQRSTUVWXYZ"
. "abcdefghijklmnopqrstuvwxyz"
ListLines, % (lls:=A_ListLines=0?"Off":"On")?"Off":"Off"
Loop, Parse, Chars
{
i:=A_Index-1, v:=(i>>5&1) . (i>>4&1)
. (i>>3&1) . (i>>2&1) . (i>>1&1) . (i&1)
s:=RegExReplace(s,"[" A_LoopField "]",StrReplace(v,"0x"))
}
ListLines, %lls%
return RegExReplace(RegExReplace(s,"10*$"),"[^01]+")
}
bit2base64(s)
{
local
s:=RegExReplace(s,"[^01]+")
s.=SubStr("100000",1,6-Mod(StrLen(s),6))
s:=RegExReplace(s,".{6}","|$0")
Chars:="0123456789+/ABCDEFGHIJKLMNOPQRSTUVWXYZ"
. "abcdefghijklmnopqrstuvwxyz"
ListLines, % (lls:=A_ListLines=0?"Off":"On")?"Off":"Off"
Loop, Parse, Chars
{
i:=A_Index-1, v:="|" . (i>>5&1) . (i>>4&1)
. (i>>3&1) . (i>>2&1) . (i>>1&1) . (i&1)
s:=StrReplace(s,StrReplace(v,"0x"),A_LoopField)
}
ListLines, %lls%
return s
}
xywh2xywh(x1,y1,w1,h1, ByRef x, ByRef y, ByRef w, ByRef h
, ByRef zx:="", ByRef zy:="", ByRef zw:="", ByRef zh:="")
{
local
SysGet, zx, 76
SysGet, zy, 77
SysGet, zw, 78
SysGet, zh, 79
w:=Min(x1+w1,zx+zw), x:=Max(x1,zx), w:=w-x
, h:=Min(y1+h1,zy+zh), y:=Max(y1,zy), h:=h-y
}
ASCII(s)
{
local
if RegExMatch(s,"\$(\d+)\.([\w+/]+)",r)
{
s:=RegExReplace(this.base64tobit(r2),".{" r1 "}","$0`n")
s:=StrReplace(StrReplace(s,"0","_"),"1","0")
}
else s=
return s
}
; You can put the text library at the beginning of the script,
; and Use FindText.PicLib(Text,1) to add the text library to PicLib()'s Lib,
; Use FindText.PicLib("comment1|comment2|...") to get text images from Lib
PicLib(comments, add_to_Lib:=0, index:=1)
{
local
Lib:=this.Lib
if (add_to_Lib)
{
re:="<([^>]*)>[^$]+\$\d+\.[\w+/]+"
Loop, Parse, comments, |
if RegExMatch(A_LoopField,re,r)
{
s1:=Trim(r1), s2:=""
Loop, Parse, s1
s2.="_" . Format("{:d}",Ord(A_LoopField))
Lib[index,s2]:=r
}
Lib[index,""]:=""
}
else
{
Text:=""
Loop, Parse, comments, |
{
s1:=Trim(A_LoopField), s2:=""
Loop, Parse, s1
s2.="_" . Format("{:d}",Ord(A_LoopField))
Text.="|" . Lib[index,s2]
}
return Text
}
}
; Decompose a string into individual characters and get their data
PicN(Number, index:=1)
{
return this.PicLib(RegExReplace(Number,".","|$0"), 0, index)
}
; Use FindText.PicX(Text) to automatically cut into multiple characters
; Can't be used in ColorPos mode, because it can cause position errors
PicX(Text)
{
local
if !RegExMatch(Text,"(<[^$]+)\$(\d+)\.([\w+/]+)",r)
return Text
v:=this.base64tobit(r3), Text:=""
c:=StrLen(StrReplace(v,"0"))<=StrLen(v)//2 ? "1":"0"
txt:=RegExReplace(v,".{" r2 "}","$0`n")
While InStr(txt,c)
{
While !(txt~="m`n)^" c)
txt:=RegExReplace(txt,"m`n)^.")
i:=0
While (txt~="m`n)^.{" i "}" c)
i:=Format("{:d}",i+1)
v:=RegExReplace(txt,"m`n)^(.{" i "}).*","$1")
txt:=RegExReplace(txt,"m`n)^.{" i "}")
if (v!="")
Text.="|" r1 "$" i "." this.bit2base64(v)
}
return Text
}
; Screenshot and retained as the last screenshot.
ScreenShot(x1:=0, y1:=0, x2:=0, y2:=0)
{
this.FindText(x1, y1, x2, y2)
}
; Get the RGB color of a point from the last screenshot.
; If the point to get the color is beyond the range of
; Screen, it will return White color (0xFFFFFF).
GetColor(x, y, fmt:=1)
{
local
bits:=this.GetBitsFromScreen(0,0,0,0,0,zx,zy,zw,zh)
, c:=(x<zx or x>=zx+zw or y<zy or y>=zy+zh or !bits.Scan0)
? 0xFFFFFF : NumGet(bits.Scan0+(y-zy)*bits.Stride+(x-zx)*4,"uint")
return (fmt ? Format("0x{:06X}",c&0xFFFFFF) : c)
}
; Identify a line of text or verification code
; based on the result returned by FindText().
; offsetX is the maximum interval between two texts,
; if it exceeds, a "*" sign will be inserted.
; offsetY is the maximum height difference between two texts.
; Return Association array {ocr:Text, x:X, y:Y, w:W, h:H}
Ocr(ok, offsetX:=20, offsetY:=20)
{
local
ocr_Text:=ocr_X:=ocr_Y:=min_X:=""
For k,v in ok
x:=v.1
, min_X:=(A_Index=1 or x<min_X ? x : min_X)
, max_X:=(A_Index=1 or x>max_X ? x : max_X)
While (min_X!="" and min_X<=max_X)
{
LeftX:=""
For k,v in ok
{
x:=v.1, y:=v.2
if (x<min_X) or Abs(y-ocr_Y)>offsetY
Continue
; Get the leftmost X coordinates
if (LeftX="" or x<LeftX)
LeftX:=x, LeftY:=y, LeftW:=v.3, LeftH:=v.4, LeftOCR:=v.id
}
if (LeftX="")
Break
if (ocr_X="")
ocr_X:=LeftX, min_Y:=LeftY, max_Y:=LeftY+LeftH
; If the interval exceeds the set value, add "*" to the result
ocr_Text.=(ocr_Text!="" and LeftX-min_X>offsetX ? "*":"") . LeftOCR
; Update for next search
min_X:=LeftX+LeftW, ocr_Y:=LeftY
, (LeftY<min_Y && min_Y:=LeftY)
, (LeftY+LeftH>max_Y && max_Y:=LeftY+LeftH)
}
return {ocr:ocr_Text, x:ocr_X, y:min_Y
, w: min_X-ocr_X, h: max_Y-min_Y}
}
; Sort the results returned by FindText() from left to right
; and top to bottom, ignore slight height difference
Sort(ok, dy:=10)
{
local
if !IsObject(ok)
return ok
ypos:=[]
For k,v in ok
{
x:=v.x, y:=v.y, add:=1
For k2,v2 in ypos
if Abs(y-v2)<=dy
{
y:=v2, add:=0
Break
}
if (add)
ypos.Push(y)
n:=(y*150000+x) "." k, s:=A_Index=1 ? n : s "-" n
}
Sort, s, N D-
ok2:=[]
Loop, Parse, s, -
ok2.Push( ok[(StrSplit(A_LoopField,".")[2])] )
return ok2
}
; Reordering according to the nearest distance
Sort2(ok, px, py)
{
local
if !IsObject(ok)
return ok
For k,v in ok
n:=((v.x-px)**2+(v.y-py)**2) "." k, s:=A_Index=1 ? n : s "-" n
Sort, s, N D-
ok2:=[]
Loop, Parse, s, -
ok2.Push( ok[(StrSplit(A_LoopField,".")[2])] )
return ok2
}
; Prompt mouse position in remote assistance
MouseTip(x:="", y:="", w:=10, h:=10, d:=4)
{
local
if (x="")
{
VarSetCapacity(pt,16,0), DllCall("GetCursorPos","ptr",&pt)
x:=NumGet(pt,0,"uint"), y:=NumGet(pt,4,"uint")
}
x:=Round(x-w-d), y:=Round(y-h-d), w:=(2*w+1)+2*d, h:=(2*h+1)+2*d
;-------------------------
Gui, _MouseTip_: +AlwaysOnTop -Caption +ToolWindow +Hwndmyid -DPIScale
Gui, _MouseTip_: Show, Hide w%w% h%h%
;-------------------------
DetectHiddenWindows, % (dhw:=A_DetectHiddenWindows)?"On":"On"
i:=w-d, j:=h-d
s=0-0 %w%-0 %w%-%h% 0-%h% 0-0 %d%-%d% %i%-%d% %i%-%j% %d%-%j% %d%-%d%
WinSet, Region, %s%, ahk_id %myid%
DetectHiddenWindows, %dhw%
;-------------------------
Gui, _MouseTip_: Show, NA x%x% y%y%
Loop, 4
{
Gui, _MouseTip_: Color, % A_Index & 1 ? "Red" : "Blue"
Sleep, 500
}
Gui, _MouseTip_: Destroy
}
; Quickly get the search data of screen image
GetTextFromScreen(x1, y1, x2, y2, Threshold:=""
, ScreenShot:=1, ByRef rx:="", ByRef ry:="")
{
local
SetBatchLines, % (bch:=A_BatchLines)?"-1":"-1"
x:=Min(x1,x2), y:=Min(y1,y2), w:=Abs(x2-x1)+1, h:=Abs(y2-y1)+1
this.GetBitsFromScreen(x,y,w,h,ScreenShot,zx,zy,zw,zh)
if (w<1 or h<1)
{
SetBatchLines, %bch%
return
}
ListLines, % (lls:=A_ListLines=0?"Off":"On")?"Off":"Off"
gs:=[], k:=0
Loop, %h%
{
j:=y+A_Index-1
Loop, %w%
i:=x+A_Index-1, c:=this.GetColor(i,j,0)
, gs[++k]:=(((c>>16)&0xFF)*38+((c>>8)&0xFF)*75+(c&0xFF)*15)>>7
}
if InStr(Threshold,"**")
{
Threshold:=StrReplace(Threshold,"*")
if (Threshold="")
Threshold:=50
s:="", sw:=w, w-=2, h-=2, x++, y++
Loop, %h%
{
y1:=A_Index
Loop, %w%
x1:=A_Index, i:=y1*sw+x1+1, j:=gs[i]+Threshold
, s.=( gs[i-1]>j || gs[i+1]>j
|| gs[i-sw]>j || gs[i+sw]>j
|| gs[i-sw-1]>j || gs[i-sw+1]>j
|| gs[i+sw-1]>j || gs[i+sw+1]>j ) ? "1":"0"
}
Threshold:="**" Threshold
}
else
{
Threshold:=StrReplace(Threshold,"*")
if (Threshold="")
{
pp:=[]
Loop, 256
pp[A_Index-1]:=0
Loop, % w*h
pp[gs[A_Index]]++
IP:=IS:=0
Loop, 256
k:=A_Index-1, IP+=k*pp[k], IS+=pp[k]
Threshold:=Floor(IP/IS)
Loop, 20
{
LastThreshold:=Threshold
IP1:=IS1:=0
Loop, % LastThreshold+1
k:=A_Index-1, IP1+=k*pp[k], IS1+=pp[k]
IP2:=IP-IP1, IS2:=IS-IS1
if (IS1!=0 and IS2!=0)
Threshold:=Floor((IP1/IS1+IP2/IS2)/2)
if (Threshold=LastThreshold)
Break
}
}
s:=""
Loop, % w*h
s.=gs[A_Index]<=Threshold ? "1":"0"
Threshold:="*" Threshold
}
;--------------------
w:=Format("{:d}",w), CutUp:=CutDown:=0
re1=(^0{%w%}|^1{%w%})
re2=(0{%w%}$|1{%w%}$)
While RegExMatch(s,re1)
s:=RegExReplace(s,re1), CutUp++
While RegExMatch(s,re2)
s:=RegExReplace(s,re2), CutDown++
rx:=x+w//2, ry:=y+CutUp+(h-CutUp-CutDown)//2
s:="|<>" Threshold "$" w "." this.bit2base64(s)
;--------------------
SetBatchLines, %bch%
ListLines, %lls%
return s
}
; Quickly save screen image to BMP file for debugging
SavePic(file, x1:=0, y1:=0, x2:=0, y2:=0, ScreenShot:=1)
{
local
static Ptr:="Ptr"
SetBatchLines, % (bch:=A_BatchLines)?"-1":"-1"
if (x1*x1+y1*y1+x2*x2+y2*y2)<=0
n:=150000, x:=y:=-n, w:=h:=2*n
else
x:=Min(x1,x2), y:=Min(y1,y2), w:=Abs(x2-x1)+1, h:=Abs(y2-y1)+1
bits:=this.GetBitsFromScreen(x,y,w,h,ScreenShot,zx,zy,zw,zh)
if (w<1 or h<1 or !bits.hBM)
{
SetBatchLines, %bch%
return
}
VarSetCapacity(bi, 40, 0), NumPut(40, bi, 0, "int")
NumPut(w, bi, 4, "int"), NumPut(h, bi, 8, "int")
NumPut(1, bi, 12, "short"), NumPut(bpp:=24, bi, 14, "short")
hBM:=DllCall("CreateDIBSection", Ptr,0, Ptr,&bi
, "int",0, "Ptr*",ppvBits:=0, Ptr,0, "int",0, Ptr)
mDC:=DllCall("CreateCompatibleDC", Ptr,0, Ptr)
oBM:=DllCall("SelectObject", Ptr,mDC, Ptr,hBM, Ptr)
;-------------------------
mDC2:=DllCall("CreateCompatibleDC", Ptr,0, Ptr)
oBM2:=DllCall("SelectObject", Ptr,mDC2, Ptr,bits.hBM, Ptr)
DllCall("BitBlt",Ptr,mDC,"int",0,"int",0,"int",w,"int",h
, Ptr,mDC2, "int",x-zx, "int",y-zy, "uint",0x00CC0020)
DllCall("SelectObject", Ptr,mDC2, Ptr,oBM2)
DllCall("DeleteDC", Ptr,mDC2)
;-------------------------
size:=((w*bpp+31)//32)*4*h
VarSetCapacity(bf, 14, 0), StrPut("BM", &bf, "CP0")
NumPut(54+size, bf, 2, "uint"), NumPut(54, bf, 10, "uint")
f:=FileOpen(file,"w"), f.RawWrite(bf,14), f.RawWrite(bi,40)
, f.RawWrite(ppvBits+0, size), f.Close()
;-------------------------
DllCall("SelectObject", Ptr,mDC, Ptr,oBM)
DllCall("DeleteDC", Ptr,mDC)
DllCall("DeleteObject", Ptr,hBM)
SetBatchLines, %bch%
}
; Show the last screen shot
ShowScreenShot(onoff:=1)
{
local
static Ptr:="Ptr"
Gui, FindText_Screen: Destroy
bits:=this.GetBitsFromScreen(0,0,0,0,0,zx,zy,zw,zh)
if (!onoff or !bits.hBM or zw<1 or zh<1)
return
mDC:=DllCall("CreateCompatibleDC", Ptr,0, Ptr)
oBM:=DllCall("SelectObject", Ptr,mDC, Ptr,bits.hBM, Ptr)
hBrush:=DllCall("CreateSolidBrush", "uint",0xFFFFFF, Ptr)
oBrush:=DllCall("SelectObject", Ptr,mDC, Ptr,hBrush, Ptr)
DllCall("BitBlt", Ptr,mDC, "int",0, "int",0, "int",zw, "int",zh
, Ptr,mDC, "int",0, "int",0, "uint",0xC000CA) ; MERGECOPY
DllCall("SelectObject", Ptr,mDC, Ptr,oBrush)
DllCall("DeleteObject", Ptr,hBrush)
DllCall("SelectObject", Ptr,mDC, Ptr,oBM)
DllCall("DeleteDC", Ptr,mDC)
;---------------------
Gui, FindText_Screen: +AlwaysOnTop -Caption +ToolWindow -DPIScale +E0x08000000
Gui, FindText_Screen: Margin, 0, 0
Gui, FindText_Screen: Add, Picture, x0 y0 w%zw% h%zh% +Hwndid +0xE
SendMessage, 0x172, 0, bits.hBM,, ahk_id %id%
Gui, FindText_Screen: Show, NA x%zx% y%zy% w%zw% h%zh%, Show ScreenShot
}
; Running AHK code dynamically with new threads
Class Thread
{
__New(args*)
{
this.pid:=this.Exec(args*)
}
__Delete()
{
Process, Close, % this.pid
}
Exec(s, Ahk:="", args:="")
{
local
Ahk:=Ahk ? Ahk:A_IsCompiled ? A_ScriptDir "\AutoHotkey.exe":A_AhkPath
s:="DllCall(""SetWindowText"",""Ptr"",A_ScriptHwnd,""Str"",""<AHK>"")`n"
. StrReplace(s,"`r"), pid:=""
Try
{
shell:=ComObjCreate("WScript.Shell")
oExec:=shell.Exec("""" Ahk """ /f * " args)
oExec.StdIn.Write(s)
oExec.StdIn.Close(), pid:=oExec.ProcessID
}
Catch
{
f:=A_Temp "\~ahk.tmp"
s:="`n FileDelete, " f "`n" s
FileDelete, %f%
FileAppend, %s%, %f%
r:=ObjBindMethod(this, "Clear")
SetTimer, %r%, -3000
Run, "%Ahk%" /f "%f%" %args%,, UseErrorLevel, pid
}
return pid
}
Clear()
{
FileDelete, % A_Temp "\~ahk.tmp"
SetTimer,, Off
}
}
WindowToScreen(ByRef x, ByRef y, id:="")
{
WinGetPos, winx, winy,,, % id ? "ahk_id " id : "A"
x+=Floor(winx), y+=Floor(winy)
}
ScreenToWindow(ByRef x, ByRef y, id:="")
{
this.WindowToScreen(dx:=0, dy:=0, id), x-=dx, y-=dy
}
ClientToScreen(ByRef x, ByRef y, id:="")
{
if (!id)
WinGet, id, ID, A
VarSetCapacity(pt,8,0), NumPut(0,pt,"int64")
, DllCall("ClientToScreen","Ptr",id,"Ptr",&pt)
, x+=NumGet(pt,"int"), y+=NumGet(pt,4,"int")
}
ScreenToClient(ByRef x, ByRef y, id:="")
{
this.ClientToScreen(dx:=0, dy:=0, id), x-=dx, y-=dy
}
/***** C source code of machine code *****
int __attribute__((__stdcall__)) PicFind(
int mode, unsigned int c, unsigned int n, int dir
, unsigned char * Bmp, int Stride, int zw, int zh
, int sx, int sy, int sw, int sh
, unsigned char * gs, char * ss, int * s1, int * s0
, char * text, int w, int h, int err1, int err0
, unsigned int * allpos, int allpos_max )
{
int ok=0, o, i, j, k, v, r, g, b, rr, gg, bb;
int x, y, x1, y1, x2, y2, len1, len0, e1, e0, max;
int r_min, r_max, g_min, g_max, b_min, b_max;
//----------------------
x2=(sx+sw>zw) ? zw : sx+sw; if (sx<0) sx=0; sw=x2-sx;
y2=(sy+sh>zh) ? zh : sy+sh; if (sy<0) sy=0; sh=y2-sy;
//----------------------
// MultiColor Mode
if (mode==5) { max=n; v=c; goto StartLookUp; }
//----------------------
// Generate Lookup Table
o=0; len1=0; len0=0;
for (y=0; y<h; y++)
{
for (x=0; x<w; x++)
{
i=(mode==3) ? y*Stride+x*4 : y*sw+x;
if (text[o++]=='1')
s1[len1++]=i;
else
s0[len0++]=i;
}
}
if (err1>=len1) len1=0;
if (err0>=len0) len0=0;
max=(len1>len0) ? len1 : len0;
//----------------------
// Color Position Mode
// only used to recognize multicolored Verification Code
if (mode==3) goto StartLookUp;
//----------------------
// Generate Two Value Image
o=sy*Stride+sx*4; j=Stride-sw*4; i=0;
if (mode==0) // Color Mode
{
rr=(c>>16)&0xFF; gg=(c>>8)&0xFF; bb=c&0xFF;
for (y=0; y<sh; y++, o+=j)
for (x=0; x<sw; x++, o+=4, i++)
{
r=Bmp[2+o]-rr; g=Bmp[1+o]-gg; b=Bmp[o]-bb; v=r+rr+rr;
ss[i]=((1024+v)*r*r+2048*g*g+(1534-v)*b*b<=n) ? 1:0;
}
}
else if (mode==1) // Gray Threshold Mode
{
c=(c+1)<<7;
for (y=0; y<sh; y++, o+=j)
for (x=0; x<sw; x++, o+=4, i++)
ss[i]=(Bmp[2+o]*38+Bmp[1+o]*75+Bmp[o]*15<c) ? 1:0;
}
else if (mode==2) // Gray Difference Mode
{
x2=sx+sw; y2=sy+sh;
for (y=sy-1; y<=y2; y++)
{
for (x=sx-1; x<=x2; x++, i++)
if (x<0 || x>=zw || y<0 || y>=zh)
gs[i]=0;
else
{
o=y*Stride+x*4;
gs[i]=(Bmp[2+o]*38+Bmp[1+o]*75+Bmp[o]*15)>>7;
}
}
k=sw+2; i=0;
for (y=1; y<=sh; y++)
for (x=1; x<=sw; x++, i++)
{
o=y*k+x; n=gs[o]+c;
ss[i]=(gs[o-1]>n || gs[o+1]>n
|| gs[o-k]>n || gs[o+k]>n
|| gs[o-k-1]>n || gs[o-k+1]>n
|| gs[o+k-1]>n || gs[o+k+1]>n) ? 1:0;
}
}
else // (mode==4) Color Difference Mode
{
r=(c>>16)&0xFF; g=(c>>8)&0xFF; b=c&0xFF;
rr=(n>>16)&0xFF; gg=(n>>8)&0xFF; bb=n&0xFF;
r_min=r-rr; g_min=g-gg; b_min=b-bb;
r_max=r+rr; g_max=g+gg; b_max=b+bb;
for (y=0; y<sh; y++, o+=j)
for (x=0; x<sw; x++, o+=4, i++)
{
r=Bmp[2+o]; g=Bmp[1+o]; b=Bmp[o];
ss[i]=(r>=r_min && r<=r_max
&& g>=g_min && g<=g_max
&& b>=b_min && b<=b_max) ? 1:0;
}
}
//----------------------
StartLookUp:
if (mode==5 || mode==3)
{ x1=sx; y1=sy; x2=sx+sw-w; y2=sy+sh-h; k=0; }
else
{ x1=0; y1=0; x2=sw-w; y2=sh-h; k=1; }
if (dir<1 || dir>4) dir=1;
if (dir==1) // From top to bottom
{
for (y=y1; y<=y2; y++)
{
for (x=x1; x<=x2; x++)
{
goto GoSub;
GoBack1:
continue;
}
}
}
else if (dir==2) // From bottom to top
{
for (y=y2; y>=y1; y--)
{
for (x=x1; x<=x2; x++)
{
goto GoSub;
GoBack2:
continue;
}
}
}
else if (dir==3) // From left to right
{
for (x=x1; x<=x2; x++)
{
for (y=y1; y<=y2; y++)
{
goto GoSub;
GoBack3:
continue;
}
}
}
else // (dir==4) From right to left
{
for (x=x2; x>=x1; x--)
{
for (y=y1; y<=y2; y++)
{
goto GoSub;
GoBack4:
continue;
}
}
}
goto Return1;
//----------------------
GoSub:
if (mode==5)
{
o=y*Stride+x*4;
for (i=0; i<max; i++)
{
j=o+s1[i]; c=s0[i];
b=Bmp[j]-(c&0xFF); if (b>v || b<-v) goto NoMatch;
g=Bmp[1+j]-((c>>8)&0xFF); if (g>v || g<-v) goto NoMatch;
r=Bmp[2+j]-((c>>16)&0xFF); if (r>v || r<-v) goto NoMatch;
}
}
else if (mode==3)
{
o=y*Stride+x*4; e1=err1; e0=err0;
j=o+c; rr=Bmp[2+j]; gg=Bmp[1+j]; bb=Bmp[j];
for (i=0; i<max; i++)
{
if (i<len1)
{
j=o+s1[i]; r=Bmp[2+j]-rr; g=Bmp[1+j]-gg; b=Bmp[j]-bb; v=r+rr+rr;
if ((1024+v)*r*r+2048*g*g+(1534-v)*b*b>n && (--e1)<0)
goto NoMatch;
}
if (i<len0)
{
j=o+s0[i]; r=Bmp[2+j]-rr; g=Bmp[1+j]-gg; b=Bmp[j]-bb; v=r+rr+rr;
if ((1024+v)*r*r+2048*g*g+(1534-v)*b*b<=n && (--e0)<0)
goto NoMatch;
}
}
}
else
{
o=y*sw+x; e1=err1; e0=err0;
for (i=0; i<max; i++)
{
if (i<len1 && ss[o+s1[i]]==0 && (--e1)<0) goto NoMatch;
if (i<len0 && ss[o+s0[i]]!=0 && (--e0)<0) goto NoMatch;
}
// Clear the image that has been found
for (i=0; i<len1; i++)
ss[o+s1[i]]=0;
}
allpos[ok*2]=k*sx+x; allpos[ok*2+1]=k*sy+y;
if (++ok>=allpos_max)
goto Return1;
NoMatch:
if (dir==1) goto GoBack1;
if (dir==2) goto GoBack2;
if (dir==3) goto GoBack3;
goto GoBack4;
//----------------------
Return1:
return ok;
}
*/
;==== Optional GUI interface ====
Gui(cmd, arg1:="")
{
local
static
global FindText
local lls, bch, cri
ListLines, % InStr("|KeyDown|LButtonDown|MouseMove|"
, "|" cmd "|") ? "Off" : A_ListLines
static init:=0
if (!init)
{
init:=1
Gui_:=ObjBindMethod(FindText,"Gui")
Gui_G:=ObjBindMethod(FindText,"Gui","G")
Gui_Run:=ObjBindMethod(FindText,"Gui","Run")
Gui_Off:=ObjBindMethod(FindText,"Gui","Off")
Gui_Show:=ObjBindMethod(FindText,"Gui","Show")
Gui_KeyDown:=ObjBindMethod(FindText,"Gui","KeyDown")
Gui_LButtonDown:=ObjBindMethod(FindText,"Gui","LButtonDown")
Gui_MouseMove:=ObjBindMethod(FindText,"Gui","MouseMove")
Gui_ScreenShot:=ObjBindMethod(FindText,"Gui","ScreenShot")
Gui_ShowPic:=ObjBindMethod(FindText,"Gui","ShowPic")
Gui_ToolTip:=ObjBindMethod(FindText,"Gui","ToolTip")
Gui_ToolTipOff:=ObjBindMethod(FindText,"Gui","ToolTipOff")
bch:=A_BatchLines, cri:=A_IsCritical
Critical
#NoEnv
%Gui_%("Load_Language_Text")
%Gui_%("MakeCaptureWindow")
%Gui_%("MakeMainWindow")
OnMessage(0x100, Gui_KeyDown)
OnMessage(0x201, Gui_LButtonDown)
OnMessage(0x200, Gui_MouseMove)
Menu, Tray, Add
Menu, Tray, Add, % Lang["1"], %Gui_Show%
if (!A_IsCompiled and A_LineFile=A_ScriptFullPath)
{
Menu, Tray, Default, % Lang["1"]
Menu, Tray, Click, 1
Menu, Tray, Icon, Shell32.dll, 23
}
Critical, %cri%
SetBatchLines, %bch%
}
Switch cmd
{
Case "Off":
return
Case "G":
GuiControl, +g, %id%, %Gui_Run%
return
Case "Run":
Critical
%Gui_%(A_GuiControl)
return
Case "Show":
Gui, FindText_Main: Default
Gui, Show, Center
GuiControl, Focus, scr
return
Case "MakeCaptureWindow":
ww:=35, hh:=12, WindowColor:="0xDDEEFF"
Gui, FindText_Capture: New
Gui, +AlwaysOnTop -DPIScale +HwndCapture_ID
Gui, Margin, 15, 15
Gui, Color, %WindowColor%
Gui, Font, s12, Verdana
Gui, -Theme
nW:=71, nH:=25, w:=12, C_:=[], Cid_:=[]
Loop, % nW*(nH+1)
{
i:=A_Index, j:=i=1 ? "" : Mod(i,nW)=1 ? "xm y+1":"x+1"
j.=i>nW*nH ? " cRed BackgroundFFFFAA" : ""
Gui, Add, Progress, w%w% h%w% %j% Hwndid
Control, ExStyle, -0x20000,, ahk_id %id%
C_[i]:=id, Cid_[id]:=i
}
Gui, +Theme
GuiControlGet, p, Pos, %id%
w:=pX+pW-15, h:=pY+pH-15
Gui, Add, Slider, xm w%w% vMySlider1 Hwndid Disabled
+Center Page20 Line10 NoTicks AltSubmit
%Gui_G%()
Gui, Add, Slider, ym h%h% vMySlider2 Hwndid Disabled
+Center Page20 Line10 NoTicks AltSubmit +Vertical
%Gui_G%()
GuiControlGet, p, Pos, %id%
k:=pX+pW, MySlider1:=MySlider2:=dx:=dy:=0
;--------------
Gui, Add, Button, xm Hwndid Hidden Section, % Lang["Auto"]
GuiControlGet, p, Pos, %id%
w:=Round(pW*0.75), i:=Round(w*3+15+pW*0.5-w*1.5)
Gui, Add, Button, xm+%i% yp w%w% hp -Wrap vRepU Hwndid, % Lang["RepU"]
%Gui_G%()
Gui, Add, Button, x+0 wp hp -Wrap vCutU Hwndid, % Lang["CutU"]
%Gui_G%()
Gui, Add, Button, x+0 wp hp -Wrap vCutU3 Hwndid, % Lang["CutU3"]
%Gui_G%()
Gui, Add, Button, xm wp hp -Wrap vRepL Hwndid, % Lang["RepL"]
%Gui_G%()
Gui, Add, Button, x+0 wp hp -Wrap vCutL Hwndid, % Lang["CutL"]
%Gui_G%()
Gui, Add, Button, x+0 wp hp -Wrap vCutL3 Hwndid, % Lang["CutL3"]
%Gui_G%()
Gui, Add, Button, x+15 w%pW% hp -Wrap vAuto Hwndid, % Lang["Auto"]
%Gui_G%()
Gui, Add, Button, x+15 w%w% hp -Wrap vRepR Hwndid, % Lang["RepR"]
%Gui_G%()
Gui, Add, Button, x+0 wp hp -Wrap vCutR Hwndid, % Lang["CutR"]
%Gui_G%()
Gui, Add, Button, x+0 wp hp -Wrap vCutR3 Hwndid, % Lang["CutR3"]
%Gui_G%()
Gui, Add, Button, xm+%i% wp hp -Wrap vRepD Hwndid, % Lang["RepD"]
%Gui_G%()
Gui, Add, Button, x+0 wp hp -Wrap vCutD Hwndid, % Lang["CutD"]
%Gui_G%()
Gui, Add, Button, x+0 wp hp -Wrap vCutD3 Hwndid, % Lang["CutD3"]
%Gui_G%()
;--------------
Gui, Add, Text, x+80 ys+3 Section, % Lang["SelGray"]
Gui, Add, Edit, x+3 yp-3 w60 vSelGray ReadOnly
Gui, Add, Text, x+15 ys, % Lang["SelColor"]
Gui, Add, Edit, x+3 yp-3 w120 vSelColor ReadOnly
Gui, Add, Text, x+15 ys, % Lang["SelR"]
Gui, Add, Edit, x+3 yp-3 w60 vSelR ReadOnly
Gui, Add, Text, x+5 ys, % Lang["SelG"]
Gui, Add, Edit, x+3 yp-3 w60 vSelG ReadOnly
Gui, Add, Text, x+5 ys, % Lang["SelB"]
Gui, Add, Edit, x+3 yp-3 w60 vSelB ReadOnly
;--------------
x:=w*6+pW+15*4, w:=k-x
Gui, Add, Tab3, x%x% y+15 w%w% -Wrap, % Lang["2"]
Gui, Tab, 1
Gui, Add, Text, x+15 y+15, % Lang["Threshold"]
Gui, Add, Edit, x+15 w100 vThreshold
Gui, Add, Button, x+15 yp-3 vGray2Two Hwndid, % Lang["Gray2Two"]
%Gui_G%()
Gui, Tab, 2
Gui, Add, Text, x+15 y+15, % Lang["GrayDiff"]
Gui, Add, Edit, x+15 w100 vGrayDiff, 50
Gui, Add, Button, x+15 yp-3 vGrayDiff2Two Hwndid, % Lang["GrayDiff2Two"]
%Gui_G%()
Gui, Tab, 3
Gui, Add, Text, x+15 y+15, % Lang["Similar1"] " 0"
Gui, Add, Slider, x+0 w120 vSimilar1 Hwndid
+Center Page1 NoTicks ToolTip, 100
%Gui_G%()
Gui, Add, Text, x+0, 100
Gui, Add, Button, x+15 yp-3 vColor2Two Hwndid, % Lang["Color2Two"]
%Gui_G%()
Gui, Tab, 4
Gui, Add, Text, x+15 y+15, % Lang["Similar2"] " 0"
Gui, Add, Slider, x+0 w120 vSimilar2 Hwndid
+Center Page1 NoTicks ToolTip, 100
%Gui_G%()
Gui, Add, Text, x+0, 100
Gui, Add, Button, x+15 yp-3 vColorPos2Two Hwndid, % Lang["ColorPos2Two"]
%Gui_G%()
Gui, Tab, 5
Gui, Add, Text, x+10 y+15, % Lang["DiffR"]
Gui, Add, Edit, x+5 w80 vDiffR Limit3
Gui, Add, UpDown, vdR Range0-255 Wrap
Gui, Add, Text, x+5, % Lang["DiffG"]
Gui, Add, Edit, x+5 w80 vDiffG Limit3
Gui, Add, UpDown, vdG Range0-255 Wrap
Gui, Add, Text, x+5, % Lang["DiffB"]
Gui, Add, Edit, x+5 w80 vDiffB Limit3
Gui, Add, UpDown, vdB Range0-255 Wrap
Gui, Add, Button, x+15 yp-3 vColorDiff2Two Hwndid, % Lang["ColorDiff2Two"]
%Gui_G%()
Gui, Tab, 6
Gui, Add, Text, x+10 y+15, % Lang["DiffRGB"]
Gui, Add, Edit, x+5 w80 vDiffRGB Limit3
Gui, Add, UpDown, vdRGB Range0-255 Wrap
Gui, Add, Checkbox, x+15 yp+5 vMultiColor Hwndid, % Lang["MultiColor"]
%Gui_G%()
Gui, Add, Button, x+15 yp-5 vUndo Hwndid, % Lang["Undo"]
%Gui_G%()
Gui, Tab
;--------------
Gui, Add, Button, xm vReset Hwndid, % Lang["Reset"]
%Gui_G%()
Gui, Add, Checkbox, x+15 yp+5 vModify Hwndid, % Lang["Modify"]
%Gui_G%()
Gui, Add, Text, x+30, % Lang["Comment"]
Gui, Add, Edit, x+5 yp-2 w150 vComment
Gui, Add, Button, x+30 yp-3 vSplitAdd Hwndid, % Lang["SplitAdd"]
%Gui_G%()
Gui, Add, Button, x+10 vAllAdd Hwndid, % Lang["AllAdd"]
%Gui_G%()
Gui, Add, Button, x+10 wp vButtonOK Hwndid, % Lang["ButtonOK"]
%Gui_G%()
Gui, Add, Button, x+10 wp vClose gCancel, % Lang["Close"]
Gui, Add, Button, xm vBind0 Hwndid, % Lang["Bind0"]
%Gui_G%()
Gui, Add, Button, x+15 vBind1 Hwndid, % Lang["Bind1"]
%Gui_G%()
Gui, Add, Button, x+15 vBind2 Hwndid, % Lang["Bind2"]
%Gui_G%()
Gui, Add, Button, x+15 vBind3 Hwndid, % Lang["Bind3"]
%Gui_G%()
Gui, Add, Button, x+15 vBind4 Hwndid, % Lang["Bind4"]
%Gui_G%()
Gui, Show, Hide, % Lang["3"]
return
Case "MakeMainWindow":
Gui, FindText_Main: New
Gui, +AlwaysOnTop -DPIScale
Gui, Margin, 15, 15
Gui, Color, %WindowColor%
Gui, Font, s12, Verdana
Gui, Add, Text, xm, % Lang["NowHotkey"]
Gui, Add, Edit, x+5 w200 vNowHotkey ReadOnly
Gui, Add, Hotkey, x+5 w200 vSetHotkey1
Gui, Add, DDL, x+5 w180 vSetHotkey2
, % "||F1|F2|F3|F4|F5|F6|F7|F8|F9|F10|F11|F12|MButton"
. "|ScrollLock|CapsLock|Ins|Esc|BS|Del|Tab|Home|End|PgUp|PgDn"
. "|NumpadDot|NumpadSub|NumpadAdd|NumpadDiv|NumpadMult"
Gui, Add, GroupBox, xm y+0 w280 h55 vMyGroup cBlack
Gui, Add, Text, xp+15 yp+20 Section, % Lang["Myww"] ": "
Gui, Add, Text, x+0 w60, %ww%
Gui, Add, UpDown, vMyww Range1-50, %ww%
Gui, Add, Text, x+15 ys, % Lang["Myhh"] ": "
Gui, Add, Text, x+0 w60, %hh%
Gui, Add, UpDown, vMyhh Hwndid Range1-50, %hh%
GuiControlGet, p, Pos, %id%
GuiControl, Move, MyGroup, % "w" (pX+pW) " h" (pH+30)
x:=pX+pW+15*2
Gui, Add, Button, x%x% ys-8 w150 vApply Hwndid, % Lang["Apply"]
%Gui_G%()
Gui, Add, Checkbox, x+30 ys Checked vAddFunc, % Lang["AddFunc"] " FindText()"
Gui, Add, Button, xm y+18 w144 vCutL2 Hwndid, % Lang["CutL2"]
%Gui_G%()
Gui, Add, Button, x+0 wp vCutR2 Hwndid, % Lang["CutR2"]
%Gui_G%()
Gui, Add, Button, x+0 wp vCutU2 Hwndid, % Lang["CutU2"]
%Gui_G%()
Gui, Add, Button, x+0 wp vCutD2 Hwndid, % Lang["CutD2"]
%Gui_G%()
Gui, Add, Button, x+0 wp vUpdate Hwndid, % Lang["Update"]
%Gui_G%()
Gui, Font, s6 bold, Verdana
Gui, Add, Edit, xm y+10 w720 r20 vMyPic -Wrap
Gui, Font, s12 norm, Verdana
Gui, Add, Button, xm w240 vCapture Hwndid, % Lang["Capture"]
%Gui_G%()
Gui, Add, Button, x+0 wp vTest Hwndid, % Lang["Test"]
%Gui_G%()
Gui, Add, Button, x+0 wp vCopy Hwndid, % Lang["Copy"]
%Gui_G%()
Gui, Add, Button, xm y+0 wp vCaptureS Hwndid, % Lang["CaptureS"]
%Gui_G%()
Gui, Add, Button, x+0 wp vGetRange Hwndid, % Lang["GetRange"]
%Gui_G%()
Gui, Add, Button, x+0 wp vTestClip Hwndid, % Lang["TestClip"]
%Gui_G%()
Gui, Font, s12 cBlue, Verdana
Gui, Add, Edit, xm w720 h350 vscr Hwndhscr -Wrap HScroll
Gui, Show, Hide, % Lang["4"]
return
Case "Capture","CaptureS":
Critical
Gui, FindText_Main: +Hwndid
if (show_gui:=(WinExist()=id))
{
Gui, FindText_Main: Default
Gui, +LastFound
WinMinimize
Gui, Hide
}
ShowScreenShot:=InStr(cmd,"CaptureS")
if (ShowScreenShot)
FindText.ShowScreenShot(1)
;----------------------
Gui, FindText_HotkeyIf: New, -Caption +ToolWindow +E0x80000
Gui, Show, NA x0 y0 w0 h0, FindText_HotkeyIf
Hotkey, IfWinExist, FindText_HotkeyIf
Hotkey, *RButton, %Gui_Off%, On UseErrorLevel
ListLines, % (lls:=A_ListLines=0?"Off":"On")?"Off":"Off"
CoordMode, Mouse
KeyWait, RButton
KeyWait, Ctrl
w:=ww, h:=hh, oldx:=oldy:="", r:=StrSplit(Lang["5"],"|")
if (!show_gui)
w:=20, h:=8
Loop
{
Sleep, 50
MouseGetPos, x, y, Bind_ID
if (!show_gui)
{
w:=x<=1 ? w-1 : x>=A_ScreenWidth-2 ? w+1:w
h:=y<=1 ? h-1 : y>=A_ScreenHeight-2 ? h+1:h
w:=(w<1 ? 1:w), h:=(h<1 ? 1:h)
}
%Gui_%("Mini_Show")
if (oldx=x and oldy=y)
Continue
oldx:=x, oldy:=y
ToolTip, % r.1 " : " x "," y "`n" r.2
}
Until GetKeyState("RButton","P") or GetKeyState("Ctrl","P")
KeyWait, RButton
KeyWait, Ctrl
px:=x, py:=y, oldx:=oldy:=""
Loop
{
Sleep, 50
%Gui_%("Mini_Show")
MouseGetPos, x1, y1
if (oldx=x1 and oldy=y1)
Continue
oldx:=x1, oldy:=y1
ToolTip, % r.1 " : " x "," y "`n" r.2
}
Until GetKeyState("RButton","P") or GetKeyState("Ctrl","P")
KeyWait, RButton
KeyWait, Ctrl
ToolTip
%Gui_%("Mini_Hide")
ListLines, %lls%
Hotkey, *RButton, %Gui_Off%, Off UseErrorLevel
Hotkey, IfWinExist
Gui, FindText_HotkeyIf: Destroy
if (ShowScreenShot)
FindText.ShowScreenShot(0)
if (!show_gui)
return [px-w, py-h, px+w, py+h]
;-----------------------
%Gui_%("getcors", !ShowScreenShot)
%Gui_%("Reset")
Gui, FindText_Capture: Default
Loop, 71
GuiControl,, % C_[71*25+A_Index], 0
Loop, 6
GuiControl,, Edit%A_Index%
GuiControl,, Modify, % Modify:=0
GuiControl,, MultiColor, % MultiColor:=0
GuiControl,, GrayDiff, 50
GuiControl, Focus, Gray2Two
GuiControl, +Default, Gray2Two
Gui, Show, Center
Event:=Result:=""
DetectHiddenWindows, Off
Critical, Off
WinWaitClose, ahk_id %Capture_ID%
Critical
ToolTip
Gui, FindText_Main: Default
;--------------------------------
if (cors.bind!="")
{
WinGetTitle, tt, ahk_id %Bind_ID%
WinGetClass, tc, ahk_id %Bind_ID%
tt:=Trim(SubStr(tt,1,30) (tc ? " ahk_class " tc:""))
tt:=StrReplace(RegExReplace(tt,"[;``]","``$0"),"""","""""")
Result:="`nSetTitleMatchMode, 2`nid:=WinExist(""" tt """)"
. "`nFindText.BindWindow(id" (cors.bind=0 ? "":"," cors.bind)
. ") `; " Lang["6"] " FindText.BindWindow(0)`n`n" Result
}
if (Event="ButtonOK")
{
if (!A_IsCompiled)
{
FileRead, s, %A_LineFile%
s:=SubStr(s, s~="i)\n[;=]+ Copy The")
}
else s:=""
GuiControl,, scr, % Result "`n" s
if !InStr(Result,"##")
GuiControl,, MyPic, % Trim(FindText.ASCII(Result),"`n")
Result:=s:=""
}
else if (Event="SplitAdd") or (Event="AllAdd")
{
GuiControlGet, s,, scr
i:=j:=0, r:="<[^>\n]*>[^$\n]+\$[\w+/,.\-]+"
While j:=RegExMatch(s,r,"",j+1)
i:=InStr(s,"`n",0,j)
GuiControl,, scr, % SubStr(s,1,i) . Result . SubStr(s,i+1)
if !InStr(Result,"##")
GuiControl,, MyPic, % Trim(FindText.ASCII(Result),"`n")
Result:=s:=""
}
;----------------------
Gui, Show
GuiControl, Focus, scr
return
Case "Mini_Show":
Gui, FindText_Mini_4: +LastFoundExist
IfWinNotExist
{
Loop, 4
{
i:=A_Index
Gui, FindText_Mini_%i%: +AlwaysOnTop -Caption +ToolWindow -DPIScale +E0x08000000
Gui, FindText_Mini_%i%: Show, Hide, Mini
}
}
d:=2, w:=w<0 ? 0:w, h:=h<0 ? 0:h, c:=A_MSec<500 ? "Red":"Blue"
Loop, 4
{
i:=A_Index
x1:=Floor(i=3 ? x+w+1 : x-w-d)
y1:=Floor(i=4 ? y+h+1 : y-h-d)
w1:=Floor(i=1 or i=3 ? d : 2*(w+d)+1)
h1:=Floor(i=2 or i=4 ? d : 2*(h+d)+1)
Gui, FindText_Mini_%i%: Color, %c%
Gui, FindText_Mini_%i%: Show, NA x%x1% y%y1% w%w1% h%h1%
}
return
Case "Mini_Hide":
Gui, FindText_Mini_4: +Hwndid
Loop, 4
Gui, FindText_Mini_%A_Index%: Destroy
WinWaitClose, ahk_id %id%,, 3
return
Case "getcors":
FindText.xywh2xywh(px-ww,py-hh,2*ww+1,2*hh+1,x,y,w,h)
if (w<1 or h<1)
return
SetBatchLines, % (bch:=A_BatchLines)?"-1":"-1"
if (arg1) or (!FindText.GetBitsFromScreen(0,0,0,0,0).hBM)
FindText.ScreenShot()
cors:=[], gray:=[], k:=0
ListLines, % (lls:=A_ListLines=0?"Off":"On")?"Off":"Off"
Loop, %nH%
{
j:=py-hh+A_Index-1, i:=px-ww
Loop, %nW%
cors[++k]:=c:=FindText.GetColor(i++,j,0)
, gray[k]:=(((c>>16)&0xFF)*38+((c>>8)&0xFF)*75+(c&0xFF)*15)>>7
}
ListLines, %lls%
cors.CutLeft:=Abs(px-ww-x)
cors.CutRight:=Abs(px+ww-(x+w-1))
cors.CutUp:=Abs(py-hh-y)
cors.CutDown:=Abs(py+hh-(y+h-1))
SetBatchLines, %bch%
return
Case "GetRange":
Critical
Gui, FindText_Main: +Hwndid
if (show_gui:=(WinExist()=id))
Gui, FindText_Main: Hide
;---------------------
Gui, FindText_GetRange: New
Gui, +LastFound +AlWaysOnTop +ToolWindow -Caption -DPIScale +E0x08000000
Gui, Color, White
WinSet, Transparent, 10
FindText.xywh2xywh(0,0,0,0,0,0,0,0,x,y,w,h)
Gui, Show, NA x%x% y%y% w%w% h%h%, GetRange
;---------------------
Gui, FindText_HotkeyIf: New, -Caption +ToolWindow +E0x80000
Gui, Show, NA x0 y0 w0 h0, FindText_HotkeyIf
Hotkey, IfWinExist, FindText_HotkeyIf
Hotkey, *LButton, %Gui_Off%, On UseErrorLevel
ListLines, % (lls:=A_ListLines=0?"Off":"On")?"Off":"Off"
CoordMode, Mouse
KeyWait, LButton
KeyWait, Ctrl
oldx:=oldy:="", r:=Lang["7"]
Loop
{
Sleep, 50
MouseGetPos, x, y
if (oldx=x and oldy=y)
Continue
oldx:=x, oldy:=y
ToolTip, %r%
}
Until GetKeyState("LButton","P") or GetKeyState("Ctrl","P")
px:=x, py:=y, oldx:=oldy:=""
Loop
{
Sleep, 50
MouseGetPos, x, y
w:=Abs(px-x)//2, h:=Abs(py-y)//2, x:=(px+x)//2, y:=(py+y)//2
%Gui_%("Mini_Show")
if (oldx=x and oldy=y)
Continue
oldx:=x, oldy:=y
ToolTip, %r%
}
Until !(GetKeyState("LButton","P") or GetKeyState("Ctrl","P"))
ToolTip
%Gui_%("Mini_Hide")
ListLines, %lls%
Hotkey, *LButton, %Gui_Off%, Off UseErrorLevel
Hotkey, IfWinExist
Gui, FindText_HotkeyIf: Destroy
Gui, FindText_GetRange: Destroy
Clipboard:=p:=(x-w) ", " (y-h) ", " (x+w) ", " (y+h)
if (!show_gui)
return StrSplit(p, ",", " ")
;---------------------
Gui, FindText_Main: Default
GuiControlGet, s,, scr
if RegExMatch(s, "i)(=\s*FindText\()([^,]*,){4}", r)
{
s:=StrReplace(s, r, r1 . p ",", 0, 1)
GuiControl,, scr, %s%
}
Gui, Show
return
Case "Test","TestClip":
Gui, FindText_Main: Default
Gui, +LastFound
WinMinimize
Gui, Hide
DetectHiddenWindows, Off
WinWaitClose, % "ahk_id " WinExist()
Sleep, 100
;----------------------
if (cmd="Test")
GuiControlGet, s,, scr
else
s:=Clipboard
if (!A_IsCompiled) and InStr(s,"MCode(") and (cmd="Test")
{
s:="`n#NoEnv`nMenu, Tray, Click, 1`n" s "`nExitApp`n"
Thread:= new FindText.Thread(s)
DetectHiddenWindows, On
WinWait, % "ahk_class AutoHotkey ahk_pid " Thread.pid,, 3
if (!ErrorLevel)
WinWaitClose,,, 30
Thread:="" ; kill the Thread
}
else
{
Gui, +OwnDialogs
t:=A_TickCount, n:=150000
, RegExMatch(s,"<[^>\n]*>[^$\n]+\$[\w+/,.\-]+",v)
, ok:=FindText.FindText(-n, -n, n, n, 0, 0, v)
, X:=ok.1.x, Y:=ok.1.y, Comment:=ok.1.id
r:=StrSplit(Lang["8"],"|")
MsgBox, 4096, Tip, % r.1 ":`t" Round(ok.MaxIndex()) "`n`n"
. r.2 ":`t" (A_TickCount-t) " " r.3 "`n`n"
. r.4 ":`t" X ", " Y "`n`n"
. r.5 ":`t" (ok ? r.6 " ! " Comment : r.7 " !"), 3
for i,v in ok
if (i<=2)
FindText.MouseTip(ok[i].x, ok[i].y)
ok:=""
}
;----------------------
Gui, Show
GuiControl, Focus, scr
return
Case "Copy":
Gui, FindText_Main: Default
ControlGet, s, Selected,,, ahk_id %hscr%
if (s="")
{
GuiControlGet, s,, scr
GuiControlGet, r,, AddFunc
if (r != 1)
s:=RegExReplace(s,"\n\K[\s;=]+ Copy The[\s\S]*")
}
Clipboard:=RegExReplace(s,"\R","`r`n")
;----------------------
Gui, Hide
Sleep, 100
Gui, Show
GuiControl, Focus, scr
return
Case "Apply":
Gui, FindText_Main: Default
GuiControlGet, NowHotkey
GuiControlGet, SetHotkey1
GuiControlGet, SetHotkey2
if (NowHotkey!="")
Hotkey, *%NowHotkey%,, Off UseErrorLevel
k:=SetHotkey1!="" ? SetHotkey1 : SetHotkey2
if (k!="")
Hotkey, *%k%, %Gui_ScreenShot%, On UseErrorLevel
GuiControl,, NowHotkey, %k%
GuiControl,, SetHotkey1
GuiControl, Choose, SetHotkey2, 0
;------------------------
GuiControlGet, Myww
GuiControlGet, Myhh
if (Myww!=ww or Myhh!=hh)
{
nW:=71, dx:=dy:=0
Loop, % 71*25
k:=A_Index, c:=WindowColor, %Gui_%("SetColor")
ww:=Myww, hh:=Myhh, nW:=2*ww+1, nH:=2*hh+1
i:=nW>71, j:=nH>25
Gui, FindText_Capture: Default
GuiControl, Enable%i%, MySlider1
GuiControl, Enable%j%, MySlider2
GuiControl,, MySlider1, % MySlider1:=0
GuiControl,, MySlider2, % MySlider2:=0
}
return
Case "ScreenShot":
Critical
FindText.ScreenShot()
Gui, FindText_Tip: New
; WS_EX_NOACTIVATE:=0x08000000, WS_EX_TRANSPARENT:=0x20
Gui, +LastFound +AlwaysOnTop +ToolWindow -Caption -DPIScale +E0x08000020
Gui, Color, Yellow
Gui, Font, cRed s48 bold
Gui, Add, Text,, % Lang["9"]
WinSet, Transparent, 200
Gui, Show, NA y0, ScreenShot Tip
Sleep, 1000
Gui, Destroy
return
Case "Bind0","Bind1","Bind2","Bind3","Bind4":
Critical
FindText.BindWindow(Bind_ID, bind_mode:=SubStr(cmd,0))
Gui, FindText_HotkeyIf: New, -Caption +ToolWindow +E0x80000
Gui, Show, NA x0 y0 w0 h0, FindText_HotkeyIf
Hotkey, IfWinExist, FindText_HotkeyIf
Hotkey, *RButton, %Gui_Off%, On UseErrorLevel
ListLines, % (lls:=A_ListLines=0?"Off":"On")?"Off":"Off"
CoordMode, Mouse
KeyWait, RButton
KeyWait, Ctrl
oldx:=oldy:=""
Loop
{
Sleep, 50
MouseGetPos, x, y
if (oldx=x and oldy=y)
Continue
oldx:=x, oldy:=y
;---------------
px:=x, py:=y, %Gui_%("getcors",1)
%Gui_%("Reset"), r:=StrSplit(Lang["10"],"|")
ToolTip, % r.1 " : " x "," y "`n" r.2
}
Until GetKeyState("RButton","P") or GetKeyState("Ctrl","P")
KeyWait, RButton
KeyWait, Ctrl
ToolTip
ListLines, %lls%
Hotkey, *RButton, %Gui_Off%, Off UseErrorLevel
Hotkey, IfWinExist
Gui, FindText_HotkeyIf: Destroy
FindText.BindWindow(0), cors.bind:=bind_mode
return
Case "MySlider1","MySlider2":
Thread, Priority, 10
Critical, Off
dx:=nW>71 ? Round((nW-71)*MySlider1/100) : 0
dy:=nH>25 ? Round((nH-25)*MySlider2/100) : 0
if (oldx=dx and oldy=dy)
return
oldx:=dx, oldy:=dy, k:=0
Loop, % nW*nH
c:=(!show[++k] ? WindowColor
: bg="" ? cors[k] : ascii[k]
? "Black":"White"), %Gui_%("SetColor")
if (cmd="MySlider2")
return
Loop, 71
GuiControl,, % C_[71*25+A_Index], 0
Loop, % nW
{
i:=A_Index-dx
if (i>=1 && i<=71 && show[nW*nH+A_Index])
GuiControl,, % C_[71*25+i], 100
}
return
Case "Reset":
show:=[], ascii:=[], bg:=""
CutLeft:=CutRight:=CutUp:=CutDown:=k:=0
Loop, % nW*nH
show[++k]:=1, c:=cors[k], %Gui_%("SetColor")
Loop, % cors.CutLeft
%Gui_%("CutL")
Loop, % cors.CutRight
%Gui_%("CutR")
Loop, % cors.CutUp
%Gui_%("CutU")
Loop, % cors.CutDown
%Gui_%("CutD")
return
Case "SetColor":
if (nW=71 && nH=25)
tk:=k
else
{
tx:=Mod(k-1,nW)-dx, ty:=(k-1)//nW-dy
if (tx<0 || tx>=71 || ty<0 || ty>=25)
return
tk:=ty*71+tx+1
}
c:=c="Black" ? 0x000000 : c="White" ? 0xFFFFFF
: ((c&0xFF)<<16)|(c&0xFF00)|((c&0xFF0000)>>16)
SendMessage, 0x2001, 0, c,, % "ahk_id " . C_[tk]
return
Case "RepColor":
show[k]:=1, c:=(bg="" ? cors[k] : ascii[k]
? "Black":"White"), %Gui_%("SetColor")
return
Case "CutColor":
show[k]:=0, c:=WindowColor, %Gui_%("SetColor")
return
Case "RepL":
if (CutLeft<=cors.CutLeft)
or (bg!="" and InStr(color,"**")
and CutLeft=cors.CutLeft+1)
return
k:=CutLeft-nW, CutLeft--
Loop, %nH%
k+=nW, (A_Index>CutUp and A_Index<nH+1-CutDown
? %Gui_%("RepColor") : "")
return
Case "CutL":
if (CutLeft+CutRight>=nW)
return
CutLeft++, k:=CutLeft-nW
Loop, %nH%
k+=nW, (A_Index>CutUp and A_Index<nH+1-CutDown
? %Gui_%("CutColor") : "")
return
Case "CutL3":
Loop, 3
%Gui_%("CutL")
return
Case "RepR":
if (CutRight<=cors.CutRight)
or (bg!="" and InStr(color,"**")
and CutRight=cors.CutRight+1)
return
k:=1-CutRight, CutRight--
Loop, %nH%
k+=nW, (A_Index>CutUp and A_Index<nH+1-CutDown
? %Gui_%("RepColor") : "")
return
Case "CutR":
if (CutLeft+CutRight>=nW)
return
CutRight++, k:=1-CutRight
Loop, %nH%
k+=nW, (A_Index>CutUp and A_Index<nH+1-CutDown
? %Gui_%("CutColor") : "")
return
Case "CutR3":
Loop, 3
%Gui_%("CutR")
return
Case "RepU":
if (CutUp<=cors.CutUp)
or (bg!="" and InStr(color,"**")
and CutUp=cors.CutUp+1)
return
k:=(CutUp-1)*nW, CutUp--
Loop, %nW%
k++, (A_Index>CutLeft and A_Index<nW+1-CutRight
? %Gui_%("RepColor") : "")
return
Case "CutU":
if (CutUp+CutDown>=nH)
return
CutUp++, k:=(CutUp-1)*nW
Loop, %nW%
k++, (A_Index>CutLeft and A_Index<nW+1-CutRight
? %Gui_%("CutColor") : "")
return
Case "CutU3":
Loop, 3
%Gui_%("CutU")
return
Case "RepD":
if (CutDown<=cors.CutDown)
or (bg!="" and InStr(color,"**")
and CutDown=cors.CutDown+1)
return
k:=(nH-CutDown)*nW, CutDown--
Loop, %nW%
k++, (A_Index>CutLeft and A_Index<nW+1-CutRight
? %Gui_%("RepColor") : "")
return
Case "CutD":
if (CutUp+CutDown>=nH)
return
CutDown++, k:=(nH-CutDown)*nW
Loop, %nW%
k++, (A_Index>CutLeft and A_Index<nW+1-CutRight
? %Gui_%("CutColor") : "")
return
Case "CutD3":
Loop, 3
%Gui_%("CutD")
return
Case "Gray2Two":
Gui, FindText_Capture: Default
GuiControl, Focus, Threshold
GuiControlGet, Threshold
if (Threshold="")
{
pp:=[]
Loop, 256
pp[A_Index-1]:=0
Loop, % nW*nH
if (show[A_Index])
pp[gray[A_Index]]++
IP:=IS:=0
Loop, 256
k:=A_Index-1, IP+=k*pp[k], IS+=pp[k]
Threshold:=Floor(IP/IS)
Loop, 20
{
LastThreshold:=Threshold
IP1:=IS1:=0
Loop, % LastThreshold+1
k:=A_Index-1, IP1+=k*pp[k], IS1+=pp[k]
IP2:=IP-IP1, IS2:=IS-IS1
if (IS1!=0 and IS2!=0)
Threshold:=Floor((IP1/IS1+IP2/IS2)/2)
if (Threshold=LastThreshold)
Break
}
GuiControl,, Threshold, %Threshold%
}
Threshold:=Round(Threshold)
color:="*" Threshold, k:=i:=0
Loop, % nW*nH
{
ascii[++k]:=v:=(gray[k]<=Threshold)
if (show[k])
i:=(v?i+1:i-1), c:=(v?"Black":"White"), %Gui_%("SetColor")
}
bg:=i>0 ? "1":"0"
return
Case "GrayDiff2Two":
Gui, FindText_Capture: Default
GuiControlGet, GrayDiff
if (GrayDiff="")
{
Gui, +OwnDialogs
MsgBox, 4096, Tip, % "`n" Lang["11"] " !`n", 1
return
}
if (CutLeft=cors.CutLeft)
%Gui_%("CutL")
if (CutRight=cors.CutRight)
%Gui_%("CutR")
if (CutUp=cors.CutUp)
%Gui_%("CutU")
if (CutDown=cors.CutDown)
%Gui_%("CutD")
GrayDiff:=Round(GrayDiff)
color:="**" GrayDiff, k:=i:=0
Loop, % nW*nH
{
j:=gray[++k]+GrayDiff
, ascii[k]:=v:=( gray[k-1]>j or gray[k+1]>j
or gray[k-nW]>j or gray[k+nW]>j
or gray[k-nW-1]>j or gray[k-nW+1]>j
or gray[k+nW-1]>j or gray[k+nW+1]>j )
if (show[k])
i:=(v?i+1:i-1), c:=(v?"Black":"White"), %Gui_%("SetColor")
}
bg:=i>0 ? "1":"0"
return
Case "Color2Two","ColorPos2Two":
Gui, FindText_Capture: Default
GuiControlGet, c,, SelColor
if (c="")
{
Gui, +OwnDialogs
MsgBox, 4096, Tip, % "`n" Lang["12"] " !`n", 1
return
}
UsePos:=(cmd="ColorPos2Two") ? 1:0
GuiControlGet, n,, Similar1
n:=Round(n/100,2), color:=c "@" n
, n:=Floor(512*9*255*255*(1-n)*(1-n)), k:=i:=0
, rr:=(c>>16)&0xFF, gg:=(c>>8)&0xFF, bb:=c&0xFF
Loop, % nW*nH
{
c:=cors[++k], r:=((c>>16)&0xFF)-rr
, g:=((c>>8)&0xFF)-gg, b:=(c&0xFF)-bb, j:=r+rr+rr
, ascii[k]:=v:=((1024+j)*r*r+2048*g*g+(1534-j)*b*b<=n)
if (show[k])
i:=(v?i+1:i-1), c:=(v?"Black":"White"), %Gui_%("SetColor")
}
bg:=i>0 ? "1":"0"
return
Case "ColorDiff2Two":
Gui, FindText_Capture: Default
GuiControlGet, c,, SelColor
if (c="")
{
Gui, +OwnDialogs
MsgBox, 4096, Tip, % "`n" Lang["12"] " !`n", 1
return
}
GuiControlGet, dR
GuiControlGet, dG
GuiControlGet, dB
rr:=(c>>16)&0xFF, gg:=(c>>8)&0xFF, bb:=c&0xFF
, n:=Format("{:06X}",(dR<<16)|(dG<<8)|dB)
, color:=StrReplace(c "-" n,"0x"), k:=i:=0
Loop, % nW*nH
{
c:=cors[++k], r:=(c>>16)&0xFF, g:=(c>>8)&0xFF
, b:=c&0xFF, ascii[k]:=v:=(Abs(r-rr)<=dR
and Abs(g-gg)<=dG and Abs(b-bb)<=dB)
if (show[k])
i:=(v?i+1:i-1), c:=(v?"Black":"White"), %Gui_%("SetColor")
}
bg:=i>0 ? "1":"0"
return
Case "Modify":
GuiControlGet, Modify
return
Case "MultiColor":
GuiControlGet, MultiColor
Result:=""
ToolTip
return
Case "Undo":
Result:=RegExReplace(Result,",[^/]+/[^/]+/[^/]+$")
ToolTip, % Trim(Result,"/,")
return
Case "Similar1":
GuiControl, FindText_Capture:, Similar2, %Similar1%
return
Case "Similar2":
GuiControl, FindText_Capture:, Similar1, %Similar2%
return
Case "GetTxt":
txt:=""
if (bg="")
return
ListLines, % (lls:=A_ListLines=0?"Off":"On")?"Off":"Off"
k:=0
Loop, %nH%
{
v:=""
Loop, %nW%
v.=!show[++k] ? "" : ascii[k] ? "1":"0"
txt.=v="" ? "" : v "`n"
}
ListLines, %lls%
return
Case "Auto":
%Gui_%("GetTxt")
if (txt="")
{
Gui, FindText_Capture: +OwnDialogs
MsgBox, 4096, Tip, % "`n" Lang["13"] " !`n", 1
return
}
While InStr(txt,bg)
{
if (txt~="^" bg "+\n")
txt:=RegExReplace(txt,"^" bg "+\n"), %Gui_%("CutU")
else if !(txt~="m`n)[^\n" bg "]$")
txt:=RegExReplace(txt,"m`n)" bg "$"), %Gui_%("CutR")
else if (txt~="\n" bg "+\n$")
txt:=RegExReplace(txt,"\n\K" bg "+\n$"), %Gui_%("CutD")
else if !(txt~="m`n)^[^\n" bg "]")
txt:=RegExReplace(txt,"m`n)^" bg), %Gui_%("CutL")
else Break
}
txt:=""
return
Case "ButtonOK","SplitAdd","AllAdd":
Gui, FindText_Capture: Default
Gui, +OwnDialogs
%Gui_%("GetTxt")
if (txt="") and (!MultiColor)
{
MsgBox, 4096, Tip, % "`n" Lang["13"] " !`n", 1
return
}
if InStr(color,"@") and (UsePos) and (!MultiColor)
{
r:=StrSplit(color,"@")
k:=i:=j:=0
Loop, % nW*nH
{
if (!show[++k])
Continue
i++
if (k=cors.SelPos)
{
j:=i
Break
}
}
if (j=0)
{
MsgBox, 4096, Tip, % "`n" Lang["12"] " !`n", 1
return
}
color:="#" (j-1) "@" r.2
}
GuiControlGet, Comment
if (cmd="SplitAdd") and (!MultiColor)
{
if InStr(color,"#")
{
MsgBox, 4096, Tip, % Lang["14"], 3
return
}
bg:=StrLen(StrReplace(txt,"0"))
> StrLen(StrReplace(txt,"1")) ? "1":"0"
s:="", i:=0, k:=nW*nH+1+CutLeft
Loop, % w:=nW-CutLeft-CutRight
{
i++
if (!show[k++] and A_Index<w)
Continue
i:=Format("{:d}",i)
v:=RegExReplace(txt,"m`n)^(.{" i "}).*","$1")
txt:=RegExReplace(txt,"m`n)^.{" i "}"), i:=0
While InStr(v,bg)
{
if (v~="^" bg "+\n")
v:=RegExReplace(v,"^" bg "+\n")
else if !(v~="m`n)[^\n" bg "]$")
v:=RegExReplace(v,"m`n)" bg "$")
else if (v~="\n" bg "+\n$")
v:=RegExReplace(v,"\n\K" bg "+\n$")
else if !(v~="m`n)^[^\n" bg "]")
v:=RegExReplace(v,"m`n)^" bg)
else Break
}
if (v!="")
{
v:=Format("{:d}",InStr(v,"`n")-1) "." FindText.bit2base64(v)
s.="`nText.=""|<" SubStr(Comment,1,1) ">" color "$" v """`n"
Comment:=SubStr(Comment, 2)
}
}
Event:=cmd, Result:=s
Gui, Hide
return
}
if (!MultiColor)
txt:=Format("{:d}",InStr(txt,"`n")-1) "." FindText.bit2base64(txt)
else
{
GuiControlGet, dRGB
r:=StrSplit(Trim(StrReplace(Result,",","/"),"/"),"/")
, x:=r.1, y:=r.2, s:="", i:=1
Loop, % r.MaxIndex()//3
s.="," (r[i++]-x) "/" (r[i++]-y) "/" r[i++]
txt:=SubStr(s,2), color:="##" dRGB
}
s:="`nText.=""|<" Comment ">" color "$" txt """`n"
if (cmd="AllAdd")
{
Event:=cmd, Result:=s
Gui, Hide
return
}
x:=px-ww+CutLeft+(nW-CutLeft-CutRight)//2
y:=py-hh+CutUp+(nH-CutUp-CutDown)//2
s:=StrReplace(s, "Text.=", "Text:="), r:=StrSplit(Lang["8"],"|")
s:="`; #Include <FindText>`n"
. "`n t1:=A_TickCount, X:=Y:=""""`n" s
. "`n if (ok:=FindText(" x "-150000, " y "-150000, " x "+150000, " y "+150000, 0, 0, Text))"
. "`n {"
. "`n CoordMode, Mouse"
. "`n X:=ok.1.x, Y:=ok.1.y, Comment:=ok.1.id"
. "`n `; Click, `%X`%, `%Y`%"
. "`n }`n"
. "`n MsgBox, 4096, Tip, `% """ r.1 ":``t"" Round(ok.MaxIndex())"
. "`n . ""``n``n" r.2 ":``t"" (A_TickCount-t1) "" " r.3 """"
. "`n . ""``n``n" r.4 ":``t"" X "", "" Y"
. "`n . ""``n``n" r.5 ":``t"" (ok ? """ r.6 " !"" : """ r.7 " !"")`n"
. "`n for i,v in ok"
. "`n if (i<=2)"
. "`n FindText.MouseTip(ok[i].x, ok[i].y)`n"
Event:=cmd, Result:=s
Gui, Hide
return
Case "KeyDown":
Critical
if (A_Gui="FindText_Main" && A_GuiControl="scr")
SetTimer, %Gui_ShowPic%, -150
return
Case "ShowPic":
ControlGet, i, CurrentLine,,, ahk_id %hscr%
ControlGet, s, Line, %i%,, ahk_id %hscr%
GuiControl, FindText_Main:, MyPic, % Trim(FindText.ASCII(s),"`n")
return
Case "LButtonDown":
Critical
if (A_Gui!="FindText_Capture")
return %Gui_%("KeyDown")
MouseGetPos,,,, k2, 2
if (k1:=Round(Cid_[k2]))<1
return
Gui, FindText_Capture: Default
if (k1>71*25)
{
GuiControlGet, k3,, %k2%
GuiControl,, %k2%, % k3 ? 0:100
show[nW*nH+(k1-71*25)+dx]:=(!k3)
return
}
k2:=Mod(k1-1,71)+dx, k3:=(k1-1)//71+dy
if (k2>=nW || k3>=nH)
return
k1:=k, k:=k3*nW+k2+1, k2:=c
if (MultiColor and show[k])
{
c:="," Mod(k-1,nW) "/" k3 "/"
. Format("{:06X}",cors[k]&0xFFFFFF)
, Result.=InStr(Result,c) ? "":c
ToolTip, % Trim(Result,"/,")
}
else if (Modify and bg!="" and show[k])
{
c:=((ascii[k]:=!ascii[k]) ? "Black":"White")
, %Gui_%("SetColor")
}
else
{
c:=cors[k], cors.SelPos:=k
GuiControl,, SelGray, % gray[k]
GuiControl,, SelColor, % Format("0x{:06X}",c&0xFFFFFF)
GuiControl,, SelR, % (c>>16)&0xFF
GuiControl,, SelG, % (c>>8)&0xFF
GuiControl,, SelB, % c&0xFF
}
k:=k1, c:=k2
return
Case "MouseMove":
static PrevControl:=""
if (PrevControl!=A_GuiControl)
{
PrevControl:=A_GuiControl
SetTimer, %Gui_ToolTip%, % PrevControl ? -500 : "Off"
SetTimer, %Gui_ToolTipOff%, % PrevControl ? -5500 : "Off"
ToolTip
}
return
Case "ToolTip":
MouseGetPos,,, _TT
IfWinExist, ahk_id %_TT% ahk_class AutoHotkeyGUI
ToolTip, % Tip_Text[PrevControl ""]
return
Case "ToolTipOff":
ToolTip
return
Case "CutL2","CutR2","CutU2","CutD2":
Gui, FindText_Main: Default
GuiControlGet, s,, MyPic
s:=Trim(s,"`n") . "`n", v:=SubStr(cmd,4,1)
if (v="U")
s:=RegExReplace(s,"^[^\n]+\n")
else if (v="D")
s:=RegExReplace(s,"[^\n]+\n$")
else if (v="L")
s:=RegExReplace(s,"m`n)^[^\n]")
else if (v="R")
s:=RegExReplace(s,"m`n)[^\n]$")
GuiControl,, MyPic, % Trim(s,"`n")
return
Case "Update":
Gui, FindText_Main: Default
GuiControl, Focus, scr
ControlGet, i, CurrentLine,,, ahk_id %hscr%
ControlGet, s, Line, %i%,, ahk_id %hscr%
if !RegExMatch(s,"(<[^>]*>[^$]+\$)\d+\.[\w+/]+",r)
return
GuiControlGet, v,, MyPic
v:=Trim(v,"`n") . "`n", w:=Format("{:d}",InStr(v,"`n")-1)
v:=StrReplace(StrReplace(v,"0","1"),"_","0")
s:=StrReplace(s,r,r1 . w "." FindText.bit2base64(v))
v:="{End}{Shift Down}{Home}{Shift Up}{Del}"
ControlSend,, %v%, ahk_id %hscr%
Control, EditPaste, %s%,, ahk_id %hscr%
ControlSend,, {Home}, ahk_id %hscr%
return
Case "Load_Language_Text":
s=
(
Myww = Width = Adjust the width of the capture range
Myhh = Height = Adjust the height of the capture range
AddFunc = Add = Additional FindText() in Copy
NowHotkey = Hotkey = Current screenshot hotkey
SetHotkey1 = = First sequence Screenshot hotkey
SetHotkey2 = = Second sequence Screenshot hotkey
Apply = Apply = Apply new screenshot hotkey and adjusted capture range values
CutU2 = CutU = Cut the Upper Edge of the text in the edit box below
CutL2 = CutL = Cut the Left Edge of the text in the edit box below
CutR2 = CutR = Cut the Right Edge of the text in the edit box below
CutD2 = CutD = Cut the Lower Edge of the text in the edit box below
Update = Update = Update the text in the edit box below to the line of code
GetRange = GetRange = Get screen range to clipboard and replace the range in the code
TestClip = TestClipboard = Test the Text data in the clipboard for searching images
Capture = Capture = Initiate Image Capture Sequence
CaptureS = CaptureS = Restore the last screenshot and then start capturing
Test = Test = Test Results of Code
Copy = Copy = Copy Code to Clipboard
Reset = Reset = Reset to Original Captured Image
SplitAdd = SplitAdd = Using Markup Segmentation to Generate Text Library
AllAdd = AllAdd = Append Another FindText Search Text into Previously Generated Code
ButtonOK = OK = Create New FindText Code for Testing
Close = Close = Close the Window Don't Do Anything
Gray2Two = Gray2Two = Converts Image Pixels from Gray Threshold to Black or White
GrayDiff2Two = GrayDiff2Two = Converts Image Pixels from Gray Difference to Black or White
Color2Two = Color2Two = Converts Image Pixels from Color Similar to Black or White
ColorPos2Two = ColorPos2Two = Converts Image Pixels from Color Position to Black or White
ColorDiff2Two = ColorDiff2Two = Converts Image Pixels from Color Difference to Black or White
SelGray = Gray = Gray value of the selected color
SelColor = Color = The selected color
SelR = R = Red component of the selected color
SelG = G = Green component of the selected color
SelB = B = Blue component of the selected color
RepU = -U = Undo Cut the Upper Edge by 1
CutU = U = Cut the Upper Edge by 1
CutU3 = U3 = Cut the Upper Edge by 3
RepL = -L = Undo Cut the Left Edge by 1
CutL = L = Cut the Left Edge by 1
CutL3 = L3 = Cut the Left Edge by 3
Auto = Auto = Automatic Cut Edge after image has been converted to black and white
RepR = -R = Undo Cut the Right Edge by 1
CutR = R = Cut the Right Edge by 1
CutR3 = R3 = Cut the Right Edge by 3
RepD = -D = Undo Cut the Lower Edge by 1
CutD = D = Cut the Lower Edge by 1
CutD3 = D3 = Cut the Lower Edge by 3
Modify = Modify = Allows Modify the Black and White Image
MultiColor = FindMultiColor = Click multiple colors with the mouse, then Click OK button
Undo = Undo = Undo the last selected color
Comment = Comment = Optional Comment used to Label Code ( Within <> )
Threshold = Gray Threshold = Gray Threshold which Determines Black or White Pixel Conversion (0-255)
GrayDiff = Gray Difference = Gray Difference which Determines Black or White Pixel Conversion (0-255)
Similar1 = Similarity = Adjust color similarity as Equivalent to The Selected Color
Similar2 = Similarity = Adjust color similarity as Equivalent to The Selected Color
DiffR = R = Red Difference which Determines Black or White Pixel Conversion (0-255)
DiffG = G = Green Difference which Determines Black or White Pixel Conversion (0-255)
DiffB = B = Blue Difference which Determines Black or White Pixel Conversion (0-255)
DiffRGB = R/G/B = Determine the allowed R/G/B Error (0-255) when Find MultiColor
Bind0 = BindWindow1 = Bind the window and Use GetDCEx() to get the image of background window
Bind1 = BindWindow1+ = Bind the window Use GetDCEx() and Modify the window to support transparency
Bind2 = BindWindow2 = Bind the window and Use PrintWindow() to get the image of background window
Bind3 = BindWindow2+ = Bind the window Use PrintWindow() and Modify the window to support transparency
Bind4 = BindWindow3 = Bind the window and Use PrintWindow(,,3) to get the image of background window
1 = FindText
2 = Gray|GrayDiff|Color|ColorPos|ColorDiff|MultiColor
3 = Capture Image To Text
4 = Capture Image To Text And Find Text Tool
5 = Position|First click RButton\nMove the mouse away\nSecond click RButton
6 = Unbind Window using
7 = Please drag a range with the LButton\nCoordinates are copied to clipboard
8 = Found|Time|ms|Pos|Result|Success|Failed
9 = Success
10 = The Capture Position|Perspective binding window\nRight click to finish capture
11 = Please Set Gray Difference First
12 = Please select the core color first
13 = Please convert the image to black or white first
14 = Can't be used in ColorPos mode, because it can cause position errors
)
Lang:=[], Tip_Text:=[]
Loop, Parse, s, `n, `r
if InStr(v:=A_LoopField, "=")
r:=StrSplit(StrReplace(v,"\n","`n"), "=", "`t ")
, Lang[r.1 ""]:=r.2, Tip_Text[r.1 ""]:=r.3
return
}
}
} ;// Class End
;================= The End =================
;
