Making game with AHK

[Hajin]

I want to know:

- The way to put scrolling effects in large images like in platform games
- Resize images automatically with size of the window resized in middle of script's operation

This guy made those things but i think he not made his game with external images:
https://autohotkey.com/board/topic/7838 ... platformer

I think i will make an game with external images like in this script for example:

Code: Select all

;(o)image movement, sound, file path, text, save/load
;( )scrolling, auto resize images with window

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
#Persistent
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.

IniRead, x, Filename, a, x , 20
IniRead, y, Filename, a, y , 100

Gui, +Resize
Gui, Add, Picture, vpic
Gui, Add, Picture, vpic2
GuiControl,, pic,%A_WorkingDir%\background.png
GuiControl,, pic2,%A_WorkingDir%\character.gif
Gui, Show, w1000 h700 xCenter y0,
GuiControl, Move, Pic2, % "x" x "y" y
loop
{
	if GetKeyState("right", "P")
	{
		x += 20
		GuiControl, Move, Pic2, % "x" x "y" y
		SoundPlay, %A_WorkingDir%\sound.mp3
		SoundPlay *-1
		Sleep, 50
	}
	if GetKeyState("q", "P")
	{
		break		
	}
	if GetKeyState("w", "P")
	{	
		IniWrite, %x%, Filename, a, x	
		IniWrite, %y%, Filename, a, y
	}
}
return
GuiClose:
ExitApp

[TheDewd]

I worked on a game in AHK once... I have since abandoned the project, but you may be able to get inspiration from it...

https://autohotkey.com/boards/viewtopic.php?t=7348

[Hajin]

Interesting ... "downloaded times +1"

[Helgef]

I want to know:

- The way to put scrolling effects in large images like in platform games

I made you and example game, it scrolls a background and moves a player, use left and right arrows.
Put all files in same folder and run, Esc::ExitApp

Code:

Spoiler

Code: Select all

;
;	Author: Helgef.
;	Date: 2016-07-24
;	Scrolling game example.
;	Move Mushy with Left and right arrows. Don't move the game window while Mushy is moving.
; 	Save platform.png and mushy4.png in script folder.
;	Escape exits at any time.
;

#NoEnv  						; Recommended for performance and compatibility with future AutoHotkey releases.
SendMode Input  				; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  	; Ensures a consistent starting directory.

; Settings
SetWinDelay,-1
moveSpeed:=5	; Movement speed of mushy/scroll, in pixels.

;	Constants
iW:=3392	 	; Image dimensions
iH:=448
sW:=800			; Screen dimensions
sH:=238

; Variables
bgX:=0			; Variable position of the background image
bgY:=0 			; Constant in this example



mdX:=10			; Initial displacement of mushy, reltaive to gameScreen
mdY:=189
mX:=mdX			; Variable position of the mushroom
mY:=mdY
mRel:=0			; The displacement of Mushy reltative his starting position, x-wise.


; Game screen gui.
Gui, gameScreen: new
Gui, gameScreen: +ToolWindow  +HWNDgameScreen
Gui, gameScreen: Add, Picture, HWNDbg, platform.png
Gui, gameScreen: Show, w%sW% h%sH%, Mushy
WinWait, Mushy
WinGetPos,gX,gY,,,ahk_id %gameScreen%

; Mushy gui
Gui, mushy: new
Gui, mushy: +ToolWindow -Caption +HWNDmushyWin +AlwaysOnTop
Gui, mushy: Color, ABCDEF
Gui, mushy: Add, Picture, AltSubmit BackgroundTrans w32 h-1,mushy4.gif
Gui, mushy: Show, % "x" . gX+mX . " y" . gY+mY
WinSet, TransColor, ABCDEF, ahk_id %mushyWin% 				; Make mushy background transparent

; Activate the gameScreen
WinActivate, ahk_id %gameScreen%

; Pin mushy to gameScreen, please dont move screen while scrolling/moving, will mess up the game. 				<-Fix this.
OnMessage(0x03, "WM_MOVE")

; Hotkeys

; Gameplay
Hotkey, IfWinActive, ahk_id %gameScreen%
Hotkey, Left, scrollLeft, on
Hotkey, Right, scrollRight, on
Hotkey, IfWinActive

; Quit
Hotkey, Esc, QuitRoutine, on

return ; End autoexec.

; Gameplay routines
scrollLeft:
	WinGetPos, mX,mY,,,ahk_id %mushyWin%
	WinGetPos,gX,gY,,,ahk_id %gameScreen%
	Loop
	{
		
		if (mX!=gX && (mX<gX+sW/2 || abs(bgX)<sW/2))		; If mushy is at the begining or end
		{		
			WinMove,ahk_id %mushyWin%,, mX-=moveSpeed
			mRel-=moveSpeed
		}
		else if bgX<4										; Mushy is is centered at screen. The number 4 stops mushy from peeking outside of the background image.
		{
			GuiControl, Move, %bg%, % "x" bgX+=moveSpeed
		}
		Sleep,1												
	} until !GetKeyState(A_ThisHotkey, "P")

return

scrollRight:
	WinGetPos, mX,mY,,,ahk_id %mushyWin%
	WinGetPos,gX,gY,,,ahk_id %gameScreen%
	
	Loop
	{
		if (mX=gX+sW-160)			; End of level.
		{		
			msgbox, You won!
			ExitApp
		}
		if (mX<gX+sW/2 || abs(bgX)>iW-sW)						; If mushy is at the begining or end
		{
			WinMove,ahk_id %mushyWin%,, mX+=moveSpeed
			mRel+=moveSpeed
		}
		else
		{														; Mushy is is centered at screen.
			GuiControl, Move, %bg%, % "x" bgX-=moveSpeed
		}
		Sleep,1
	} until !GetKeyState(A_ThisHotkey, "P")
return

; Other labels

gameScreenGuiClose:
	ExitApp
return


QuitRoutine:
	ExitApp
return

; Functions
WM_MOVE(wParam,lParam,msg,hwnd)
{
	; Pins mushyWin to gameScreen.
	global mRel, gameScreen, mushyWin, mdX, mdY
	if (hwnd=gameScreen)
	{
		WinGetPos,gX,gY,,,ahk_id %gameScreen%
		WinGetPos,mX,mY,,,ahk_id %mushyWin%
		WinMove,ahk_id %mushyWin%,,mdX+gX+mRel,mdY+gY
	}
}

Please verify that platform.png is 3382x448 pixels and mushy4.gif is 64x64. Other wise I need to find an alternate upload.

mushy.rar

mushy.ahk, mushy4.gif, platform.png

(10.63 KiB) Downloaded 184 times

Edit: Fixed attachments, now in rar because images were scaled.

[Hajin]

Looks good, after some things i will test this script...
I'm making a game with other system, currently.
I still have interest in make game with AHK...
AHK is very interesting.