Url download produces chinese characters Topic is solved

[braunbaer]

Hi, I use the following funtion with code that I found here in the forum, and that normally works:

Code: Select all

UrlDownload(Url) {
    whr := ComObjCreate("WinHttp.WinHttpRequest.5.1")
    whr.Open("GET", Url, true)
    whr.Send()
    ; Using 'true' above and the call below allows the script to remain responsive.
    whr.WaitForResponse()
    return whr.ResponseText
    }

When I try to download the page from https://myip.is I get a variable filled with a lot of chinese characters (or maybe japanese, or the like...)

Code: Select all

#+i::
MyIp(){
   page:=urldownload("https://myip.is/")
   msgbox %page%
   }

[mikeyww]

Just an alternative here.

Code: Select all

MsgBox, 64, IP address, % ip()

ip() { ; Get IP address
 Try whr := ComObjCreate("WinHttp.WinHttpRequest.5.1"), whr.Open("GET", "https://api.ipify.org/"), whr.Send()
 Catch
  Return
 Return whr.ResponseText
}

[teadrinker]

Code: Select all

UrlDownload(Url) {
    whr := ComObjCreate("WinHttp.WinHttpRequest.5.1")
    whr.Open("GET", Url, true)
    whr.Send()
    ; Using 'true' above and the call below allows the script to remain responsive.
    whr.WaitForResponse()
    Arr := whr.responseBody
    pData := NumGet(ComObjValue(Arr) + 8 + A_PtrSize)
    length := Arr.MaxIndex() + 1
    Return StrGet(pData, length, "UTF-8")
    }

msgbox % page := urldownload("https://myip.is/")

MsgBox, % RegExReplace(page, ".+title=""copy ip address"">([^<]+).+", "$1")

[braunbaer]

Thank you both!

Both ways work fine.
As myip.is shows the IP address and in addition the host name, I will use teadrinkers function.