Trying AHK2 for the first time Topic is solved

[WalkerOfTheDay]

So I decided to finally try out AHK v2 after using v1 for years.
I tried to convert an existing script, and am getting the following error:

Error: This variable has not been assigned a value.

Specifically: local Monitor (same name as a global)

011: If GetKeyState("Control")
012: {
▶ 013: If (Monitor = "gaming")
014: {
015: run("c:\controlmymonitor\ControlMyMonitor.exe /SetValue Primary 60 17")


I noticed by adding Global above the line: if GetKeyState("Control"), it executes
the script, but the [else] is never executed. Any ideas why ??

Code: Select all

#Requires AutoHotkey v2
#MaxThreadsPerHotkey 2
Persistent
Monitor := "gaming"

^g::
~LButton & RButton::
{
    if GetKeyState("Control")
        {
            if (Monitor = "gaming")
                {
                    run "c:\controlmymonitor\ControlMyMonitor.exe /SetValue Primary 60 17"	; switch to work pc
                    Monitor := "work"
                }
        }
        else
            {
                run "c:\controlmymonitor\ControlMyMonitor.exe /SetValue Primary 60  1"		; switch to gaming pc
                Monitor := "gaming"   
            }
    return
}

[boiler]

Hotkey routines are functions in v2, so you need to be concerned with variable scope. If you want to refer to the global variable, you need to declare it as global. Otherwise, it thinks you mean to use it as a local variable, in which case you should initialize its value, but that’s not what you’re trying to do here. If you only were referring to the variable and not assigning it a value in your function, it probably would have automatically determined you were referring to the global variable, but not since you are assigning it a value.

See Local and Global Variables for further explanation.

[mikeyww]

Also: instead of Run, display a MsgBox for each condition. You can just display the value of the condition itself. If the Else condition is not met, then the If condition is met. You can then backtrack & determine why.

[WalkerOfTheDay]

@boiler Thanks ! That makes sense.
@mikeyww Thanks, the run was not for troubleshooting though, otherwise I would have added the MsgBox for sure, thanks.

[WalkerOfTheDay]

Okay, with another script I'm getting a similar error. What is the correct way in AHKv2 to send a variable ?
The last line

Code: Select all

SendRaw Artno

is throwing below error, even though I have assigned a value to the variable afaik

Error:
Warning: This variable appears to never be assigned a value.

Specifically: local SendRaw

025: Sleep(4000)
026: Send("^f")
▶ 027: SendRaw(Artno)
028: }
029: Exit

For more details, read the documentation for #Warn.

Code: Select all

#Requires Autohotkey v2.0

^1::
{
    A_Clipboard := ""                                                                   ; empty clipboard
    WinActivate("Cadiz + 2.5% - Excel")
    Sleep(1000)
    Send "^c"                                                                           ; copy articlenumber
    Sleep(1000)
    ClipWait
    Artno := StrReplace(A_Clipboard, "`r`n")
    A_Clipboard := ""                                                                   ; empty clipboard
    Send "{Right 5}"
    Sleep(1000)
    Send "^c"                                                                           ; copy listprice
    ClipWait
    Sleep (1000)
    ListPrice := StrReplace(A_Clipboard, "`r`n")
    ToolTip(Artno . " " . ListPrice)
    WinActivate("Session - c19708up.cloudiax.com - Verbinding met extern bureaublad")
    Sleep(1000)
    Send "!na"
    Sleep(4000)
    Send "{F6}"                                                                         ; open article data
    Sleep(4000)
    Send "^f"                                                                           ; find
    SendRaw Artno
}

[mikeyww]

Hello,

SendRaw is not a v2 function.

Explained: Raw mode

[boiler]

And note for the next time you encounter something similar: The error message tells you that it’s SendRaw that it has an issue with, not Artno.

[WalkerOfTheDay]

Hello,

SendRaw is not a v2 function.

Explained: Raw mode

Ah, my bad

I guess it's gonna take some time for me to adapt to the new version

[boiler]

It would help to get familiar with the v2 Function List, or at least reference it often.

[WalkerOfTheDay]

It would help to get familiar with the v2 Function List, or at least reference it often.

Thanks @boiler

[RaptorX]

If you already know v1, I would definitely suggest reading the Changes from v1.1 to v2.0
section of the help file, it will save you hours of frustration.

[WalkerOfTheDay]

I'm not sure if I should open a new topic for this, but I guess I could also post it here.
It's a question regarding ImageSearch, specifically the variations option.

I have this working piece of an imagesearch:

Code: Select all

if ImageSearch(&OVarX, &OVarY, 0, 0, A_ScreenWidth, A_ScreenHeight, "*5 C:\AHK-Studio-master\Projects\AHKv2\Bol_Images\selecteer.png")

This works fine, but I would rather not use the full path, so I tried:

Code: Select all

if ImageSearch(&OVarX, &OVarY, 0, 0, A_ScreenWidth, A_ScreenHeight, "*5" A_WorkingDir "\Bol_Images\selecteer.png")

This throws an error about parameter 7 being invalid.

I tried it without the quotes around *5, but that also doesn't work.

If I remove the "*5" al together it works, but I really would keep the variations option in there.

What is the correct syntax ?

Full script:

Code: Select all

#Requires Autohotkey v2.0
SetWorkingDir "C:\AHK-Studio-master\Projects\AHKv2\"
^1::
{
    CoordMode "Pixel"
    ;if ImageSearch(&OVarX, &OVarY, 0, 0, A_ScreenWidth, A_ScreenHeight, "*5 C:\AHK-Studio-master\Projects\AHKv2\Bol_Images\selecteer.png")
    if ImageSearch(&OVarX, &OVarY, 0, 0, A_ScreenWidth, A_ScreenHeight, "*5" A_WorkingDir "\Bol_Images\selecteer.png")
    {
        Click OVarX, OVarY
        Sleep("250")
        MouseClick "Left", 0, 160, 1, 10,, "R"
        
    }
    else
        MsgBox "Icon could not be found on the screen."
}

ESC::ExitApp

[gregster]

I would guess: put a space behind "*5": "*5 " - that means, actually include it in the expression.

Options: Zero or more of the following strings may be also be present immediately before the name of the file. Separate each option from the next with a single space or tab.

And yes, I would suggest to create a separate topic, next time - or if you have more questions about this.

[WalkerOfTheDay]

@gregster Yes ! That's it. That simple... Like I said before, it's gonna take some time getting used to v2

[gregster]

Sure, but expressions worked the same in v1 (so there are similarities to discover). Of course, they are the default now.

[boiler]

To that point, just envision (or use a MsgBox to display) exactly what your concatenated string should look like, and then you would see that the *5 would have been butted up right against your file path. As gregster pointed out, this is exactly the same as if you use an expression to build a parameter string in v1.

[WalkerOfTheDay]

Fair enough,

But in my defense, in AHKv1 the *5 wouldn't have quotation marks around it, would it? So I wouldn't have placed it right against the path in the first place

Disclaimer:
(I don't have access to a pc right now so I can't test if what I'm claiming is actually true.)

[mikeyww]

If you were using a forced expression, the result would have been the same. Game over!

[boiler]

But in my defense, in AHKv1 the *5 wouldn't have quotation marks around it, would it?

Yes, it would have. You’re missing the point of what gregster and I and also mikeyww pointed out. Expressions are the same in both v1 and v2, and you can use them in both.

…this is exactly the same as if you use an expression to build a parameter string in v1.

[WalkerOfTheDay]

Okay, I'm back at it again. This time I thought I try to create a gui in AHKv2, and again failing at it
I'm trying to do a simple click on a button and then fire a MsgBox

Sorry for my ignorance in advance.

In V1, I would have just created used a gLabel, but that doesn't work anymore.

Code: Select all

#Requires Autohotkey v2.0

; MyGui := Gui([Options, Title, EventObj])

AHKV2Gui := Gui("AlwaysOnTop", "my title")
AHKV2Gui.Add("Button", "vMyButton", "ButtonText")
AHKV2Gui.OnEvent("Click", AHKV2Gui_Click)
AHKV2Gui_Click {
    MsgBox("blabla")
}
AHKV2Gui.Show("w400 h300")

/* example from manual
myGui := Gui()
myGui.AddText("", "Press Alt+F4 or the X button in the title bar.")
myGui.OnEvent("Close", myGui_Close)
myGui_Close(thisGui) {  ; Declaring this parameter is optional.
    if MsgBox("Are you sure you want to close the GUI?",, "y/n") = "No"
        return true  ; true = 1
}
myGui.Show
*/

Edit

I seem to have found something in the docs that works

Code: Select all

#Requires Autohotkey v2.0
AHKV2Gui := Gui("AlwaysOnTop", "my title")
AHKV2Gui.Add("Button", "vMyButton", "ButtonText").OnEvent("Click", ClickTheButton)
AHKV2Gui.Show("w400 h300")

ClickTheButton(*)
{
    MsgBox
}