Variable in Array suchen und Position ausgeben Topic is solved

[Wick3d]

Hallo Leute,

Ich bin mir sicher, mein Problem ist ganz leicht. Dennoch finde ich nach langer Suche nirgendwo eine schöne Lösung.
Ich möchte anhand einer Variable herausfinden, ob das Wort, welches in der Variable ist, im Array enthalten ist und wenn ja die Position ausgeben.

Ungefähr so sollte es dann aussehen

Code: Select all

arr := ["a", "ll", "", "d"]
var := "ll"
MsgBox % arr[var] ; gibt 2 wieder

Ich bin eigentlich der Meinung, dass ich sowas schon gemacht habe. Aber irgendwie finde ich es nicht mehr

Danke für eure Hilfe.

Gruß
Alex

[Ragnar]

Code: Select all

obj := {"a": 1, "ll": 2, "": 3, "d": 4}
var := "ll"
MsgBox % obj[var] ; gibt 2 wieder

[Wick3d]

Oh man, ich wusste ich bin nah dran. Danke.

[BoBo]

Code: Select all

arr := ["a", "ll", "", "d"], var := "ll"
Loop 
	{ pos := A_Index
	} Until var = arr[pos]
MsgBox % pos

Geht auch mit nicht-assoziativem Array.

[effel]

Danke BoBo das kann ich brauchen.

Code: Select all

arr := ["a", "ll", "https://www.autohotkey.com/boards/viewtopic.php?p=358377", "d"]

var := "https://www.autohotkey.com/boards/viewtopic.php?p=358377"

Loop
{pos := A_Index 
}Until var = arr[pos]

MsgBox % "Position:`n" pos "`n`nWert:`n" arr[pos]

Code: Select all

arr := ["a", "ll", "https://www.autohotkey.com/boards/viewtopic.php?p=358377", "d"]

var := "https://www.autohotkey.com/boards/viewtopic.php?p=358377"

MsgBox % FindString(Arr, Var)

FindString(Arr, Var){
Loop
{pos := A_Index 
}Until Var = Arr[pos]
Return "Position:`n" pos "`n`nWert:`n" arr[pos]
}

Hier finde ich jedoch nur das erste Vorkommen:

Code: Select all

arr := ["a", "ll", "https://www.autohotkey.com/boards/viewtopic.php?p=358377", "d"]

var := "autohotkey"

MsgBox % FindTeilString(Arr, Var)

FindTeilString(Arr, Var){
Loop
{pos := A_Index 
}Until InStr(Arr[pos],Var)
Return "Position:`n" pos "`n`nWert:`n" arr[pos]
}

Das funktioniert dann doch nicht wie gewünscht auch hier wird nur der erste Fund angezeigt

Code: Select all

arr := ["autohotkey", "ll", "https://www.autohotkey.com/boards/viewtopic.php?p=358377", "d"]

var := "autohotkey"

MsgBox % FindString(Arr, Var)

FindString(Arr, Var){
Loop
{pos := A_Index 
}Until InStr(Arr[pos],Var)
NeedLes .= "Position:`n" pos "`n`nWert:`n" arr[pos]
Return NeedLes
}

[just me]

Böse Falle!

Code: Select all

arr := ["a", "ll", "", "d"]
var := "Gibbetnich!"
Loop 
	{ pos := A_Index
	} Until var = arr[pos]
MsgBox % pos

[haichen]

Die böse Falle hatte ich auch nicht gesehen..
Das hier geht:

Code: Select all

arr := ["a", "ll", "", "d"]
var := "Gibbetnich!"
Loop {
 } Until pos:=A_Index*((var = arr[A_Index] ) or (A_Index = arr.MaxIndex()))
MsgBox % pos

[effel]

Code: Select all

arr := ["a", "ll", "d"]
maxIndex := arr.Push("endOfFile")
var := "d "
Loop {
 } Until pos:=A_Index*((var = arr[A_Index] ) or (A_Index = arr.MaxIndex()))
NeedLes := "Position:`n" pos "`n`nWert:`n" arr[pos]
if InStr(NeedLes,"endOfFile")
MsgBox % --maxIndex " Werte durchsucht. Gibbetnich!"
else
MsgBox % NeedLes 

[BoBo]

<See below>

[Wick3d]

Hi Bobo,

falschen Thread erwischt? Ich mein die Inhalte vom Code ähneln einem anderen Thread von mir. Ich erkläre den Sinn gerne erneut
https://www.autohotkey.com/boards/viewtopic.php?f=9&t=82186

[just me]

Moin, noch zwei:

Code: Select all

Arr := ["a", "ll", "d"]
Var := "d "
FoundPos := 0
; 1. --------------------------------------------------
Loop, % Arr.Length() {
} Until (Var = Arr[A_Index]) && (Foundpos := A_Index)
; 2. --------------------------------------------------
For I, V In Arr {
} Until (Var = V) && (FoundPos := I)
; -----------------------------------------------------
If (FoundPos = 0)
   MsgBox % Arr.Length() " Werte durchsucht. Gibbetnich!"
Else
   MsgBox % "Position:`n" FoundPos "`n`nWert:`n" Arr[FoundPos]

Die Until Prüfung enthält einen 'schmutzigen' oder auch 'genialen' Trick. (FoundPos := I) wird als zweite Bedingung nur dann ausgeführt und geprüft, wenn (Var = V) wahr ist.

Edit: 2020-10-21 Skript korrigiert!

[Rohwedder]

Hallo,
ist meinem Autohotkey zu schmutzig, obwohl es meinen Kode gewohnt ist.
Error: Unexpected "{"
---> 011: For I,V in Arr {If (FoundPos = 0)
War es so gemeint?:

Code: Select all

Arr := ["a", "ll", "d"]
Var := "d "
FoundPos := 0
; 1. --------------------------------------------------
Loop, % Arr.Length() {
} Until (Var = Arr[A_Index]) && (Foundpos := A_Index)
; 2. --------------------------------------------------
For I, V In Arr {
} Until (Var = V) && (FoundPos := I)
; -----------------------------------------------------
For I, V In Arr {
} If (FoundPos = 0)
   MsgBox % Arr.Length() " Werte durchsucht. Gibbetnich!"
Else
   MsgBox % "Position:`n" FoundPos "`n`nWert:`n" Arr[FoundPos]

[effel]

Eines der wenigen laufenden Scripte bei mir

2020-10-20 at 17.22.17.jpeg

(86.63 KiB) Downloaded 37 times

[just me]

Nöh, die letzte For-Schleife war ein schlichter Kopierfehler. Bei mir läuft das aber trotzdem. Ich habe das Skript oben korrigiert.