V2....128 ... TestGui Topic is solved

[HugoM]

Moin,
I try to transfer some Guis to be started with Hotkeys from V1x to V2...128. The example from docs works. But when I uncomment the Hotkey ^b nothing happens when I press ctrl+b. Same with other hotkeys. e.g. !g. What am i doing wrong?
Stay healthy

Code: Select all

; ^b::
{
	MyGui := Gui(, "Simple Input Example")
	MyGui.Add("Text",, "First name:")
	MyGui.Add("Text",, "Last name:")
	MyGui.Add("Edit", "vFirstName ym")  ; The ym option starts a new column of controls.
	MyGui.Add("Edit", "vLastName")
	MyGui.Add("Button", "default", "OK").OnEvent("Click", (*) => ProcessUserInput(MyGui))
	MyGui.OnEvent("Close", ProcessUserInput)
	MyGui.Show()

	ProcessUserInput(thisGui, *)
	{
		Saved := thisGui.Submit()  ; Save the contents of named controls into an object.
		MsgBox("You entered '" Saved.FirstName " " Saved.LastName "'.")
	}
}

[swagfag]

unnamed hotkeys with closures in them are kinda buggy right now, see https://www.autohotkey.com/boards/viewtopic.php?f=14&t=87863
to fix:

• name ur hotkey, eg:

  Code: Select all

  ^b::
  control_b(ThisHotkey) {
  ...
  ...

• dont create closures in them:

  Code: Select all

  ^b::
  {
  	MyGui := Gui(, "Simple Input Example")
  	MyGui.Add("Text",, "First name:")
  	MyGui.Add("Text",, "Last name:")
  	MyGui.Add("Edit", "vFirstName ym")  ; The ym option starts a new column of controls.
  	MyGui.Add("Edit", "vLastName")
  	MyGui.Add("Button", "default", "OK").OnEvent("Click", ProcessUserInput.Bind(MyGui))
  	MyGui.OnEvent("Close", ProcessUserInput)
  	MyGui.Show()
  
  	ProcessUserInput(thisGui, *)
  	{
  		Saved := thisGui.Submit()  ; Save the contents of named controls into an object.
  		MsgBox("You entered '" Saved.FirstName " " Saved.LastName "'.")
  	}
  }

  or

  Code: Select all

  #Requires AutoHotkey v2.0-a128-f63b0eb4
  ^b::
  {
  	MyGui := Gui(, "Simple Input Example")
  	MyGui.Add("Text",, "First name:")
  	MyGui.Add("Text",, "Last name:")
  	MyGui.Add("Edit", "vFirstName ym")  ; The ym option starts a new column of controls.
  	MyGui.Add("Edit", "vLastName")
  	MyGui.Add("Button", "default", "OK").OnEvent("Click", ProcessUserInput)
  	MyGui.OnEvent("Close", ProcessUserInput)
  	MyGui.Show()
  
  	ProcessUserInput(this, *)
  	{
  		if (this is Gui.Control) ; if the Button(or any other Control) was passed in
  			this := this.Gui ; get the Gui object, the control belongs to, instead
  
  		Saved := this.Submit()  ; Save the contents of named controls into an object.
  		MsgBox("You entered '" Saved.FirstName " " Saved.LastName "'.")
  	}
  }

[HugoM]

Great, thank you.
I think I will (what I unfortunately forgot, but knew) name my hotkeys and use the code for 128.
Stay healthy and turn the key here.

[lexikos]

Fixed by v2.0-a129.