Looking for a timer/beep reminder Topic is solved

[gyrosav]

Can someone help me create a simple autohotkey that shows 3 green dots in the middle of my screen every 5 seconds? If it could also give a little beep, that would be lovely.

If you could make the timer adjustable as well as the size of the green dots, that would be much appreciated!

[mikeyww]

Code: Select all

#Persistent
freq   = 5000 ; Milliseconds between displays
width  =   50 ; Width of dot
dist   =  300 ; Distance between dots (left to left)
show   = 1000 ; Milliseconds to display
; -----------------------------------------------
image  = %A_ScriptDir%\greenDot.png
SysGet, mon, MonitorWorkArea
trans  = EEAA99
y     := monTop + (monBottom - monTop - width)  / 2
Loop, 3 {
 Gui, %A_Index%:New, +LastFound +AlwaysOnTop +Owner
 Gui, Add, Picture, w%width% h-1, %image%
 Gui, Color, %trans%
 WinSet, TransColor, %trans%
 Gui -Caption
}
SetTimer, Show, %freq%
Show:
Loop, 3 {
 x := monLeft + (monRight  - monLeft - width) / 2 + dist * (A_Index - 2)
 Gui, %A_Index%:Show, x%x% y%y% NoActivate
}
SoundBeep, 1500
Sleep, show
Loop, 3
 Gui, %A_Index%: Hide
Return

[gyrosav]

@mikeyww

This is amazing. thank you for saving me. just one last request. The dots do not show over my game. can the dots be made to be shown on top of everything? Thank you!

[mikeyww]

It's already set to on-top. Your game may be preventing this type of behavior. You may need to test various ideas: set to on top again, WinActivate, run as admin, or others.