Me gustaría mover el mouse con el teclado Topic is solved

Esta sección es para preguntas sobre programación/scripting usando AutoHotkey.

Moderator: Flipeador

Ronaldlugo23
Posts: 3
Joined: 18 Jul 2019, 13:29

Me gustaría mover el mouse con el teclado

Post by Ronaldlugo23 » 18 Jul 2019, 13:39

Hola me gustaría un script que haga que al presionar dicha tecla el mouse se mueva a una dirección especifica es decir J (El cursor se mueve a la izquierda). I (El cursor se mueve para arriba). L (El cursor se mueve para la derecha) K (El cursor se mueve para abajo) si no es mucho pedir.

User avatar
Flipeador
Posts: 1204
Joined: 15 Nov 2014, 21:31
Location: Argentina
Contact:

Re: Me gustaría mover el mouse con el teclado  Topic is solved

Post by Flipeador » 18 Jul 2019, 19:14

Hola;
Opción #1:

Code: Select all

#NoEnv
#SingleInstance Force

SetBatchLines -1
CoordMode Mouse, Screen


Count := 5

i:: Move(0, -Count)
j:: Move(-Count, 0)
k:: Move(0, Count)
l:: Move(Count, 0)

Move(X, Y)
{
    local
    MouseGetPos CX, CY
    MouseMove % CX+X, CY+Y
}

Opción #2:

Code: Select all

#NoEnv
#SingleInstance Force

SetBatchLines -1
CoordMode Mouse, Screen


Count := 5

i:: MouseEvent(0, -Count)
j:: MouseEvent(-Count, 0)
k:: MouseEvent(0, Count)
l:: MouseEvent(Count, 0)

MouseEvent(X, Y)
{
    DllCall("User32.dll\mouse_event", "UInt", 1, "Int", X, "Int", Y, "UInt", 0, "Ptr", 0, "Int")
    tickcount := A_TickCount
}

Puedes aumentar o disminuir el valor 5 en Count := 5.

Ronaldlugo23
Posts: 3
Joined: 18 Jul 2019, 13:29

Re: Me gustaría mover el mouse con el teclado

Post by Ronaldlugo23 » 21 Jul 2019, 17:33

Muchas gracias pero no funciona en los juegos:(

User avatar
Flipeador
Posts: 1204
Joined: 15 Nov 2014, 21:31
Location: Argentina
Contact:

Re: Me gustaría mover el mouse con el teclado

Post by Flipeador » 21 Jul 2019, 19:10

La opción 2 debería funcionar, debes ejecutar el script como Administrador.

Ronaldlugo23
Posts: 3
Joined: 18 Jul 2019, 13:29

Re: Me gustaría mover el mouse con el teclado

Post by Ronaldlugo23 » 21 Jul 2019, 22:54

Si funciona mucha gracias de verdad :D :D

Guest

Re: Me gustaría mover el mouse con el teclado

Post by Guest » 25 Apr 2022, 08:40

Muy interesante el scrip.

Por cierto si cambiamos las letras por las flechas del cursor ¿que habría que poner?

Voy a ver si lo puedo probar.

Y si además incluimos el botón izquierdo con la tecla Alt o la que sea y botón derecho con la tecla creo o la que sea

Gracias

User avatar
ositoMalvado
Posts: 180
Joined: 24 Dec 2019, 12:02
Contact:

Re: Me gustaría mover el mouse con el teclado

Post by ositoMalvado » 16 Aug 2022, 19:13

Hola amigos, les presento mi solución, cualquier consulta me preguntan! Prueben, ejecuten como admin

Code: Select all

;OPTIMIZACIONES - NO CAMBIAR
#NoEnv
#MaxHotkeysPerInterval 99000000
#HotkeyInterval 99000000
#KeyHistory 0
ListLines Off
Process, Priority, , A
SetBatchLines, -1
SetKeyDelay, -1, -1
SetMouseDelay, -1
SetDefaultMouseSpeed, 0
SetWinDelay, -1
SetControlDelay, -1
SendMode Input
CoordMode, mouse, screen
;OPTIMIZACIONES - NO CAMBIAR

;INICIAMOS GLOBALES - NO CAMBIAR
MouseGetPos, mx, my
global MOUSE_X:=mx ;GUARDAREMOS LA POSICIÓN X DEL MOUSE
global MOUSE_Y:=my ;GUARDAREMOS LA POSICIÓN Y DEL MOUSE
;INICIAMOS GLOBALES - NO CAMBIAR
;/////////////////////////////
;
;        CONFIGURACIONES - CONFIGURABLE
;
;;/////////////////////////////
    global VELOCIDAD := 0.03 ;CUANTOS PIXELES SE MOVERA POR MOVIMIENTO. POSITIVO PARA QUE AVANCE, 0 PARA QUE NO FUNCIONE Y NEGATIVO PARA INVERTIR DIRECCIONES
    global BUCLE := true ;REPETIR AL MANTENER PRESIONADO. DEBE SER "true" o "false"
    global DELAY := 0 ;TIEMPO DE ESPERA PARA EL BUCLE. DEBE SER 0 O MAYOR
;/////////////////////////////
;NO CONFIGURABLE
    mm(x,y){
        if(BUCLE)
            while getkeystate(A_ThisHotKey,"p"){
                MOUSE_X+=x
                MOUSE_Y+=y
                MouseMove, % MOUSE_X, % MOUSE_Y, 0
                sleep, % DELAY
            }
        else{
            MouseMove, % MOUSE_X, % MOUSE_Y, 0
            sleep, % DELAY
        }
        
    }
    a::mm(-VELOCIDAD,0)
    d::mm(VELOCIDAD,0)
    s::mm(0,VELOCIDAD)
    w::mm(0,-VELOCIDAD)
;NO CONFIGURABLE
;/////////////////////////////
My WEB some useful stuff

Post Reply

Return to “Pedir Ayuda”