Буфер обмена

Помощь в написании скриптов
maker22811
Posts: 8
Joined: 05 Dec 2020, 13:43

Буфер обмена

Post by maker22811 » 05 Dec 2020, 14:06

Нужно крч чтобы смотрело буфер обмена и если в буфере любой текст кроме "Вам это недоступно", то продолжало скрипт, а если там текст "Вам это недоступно", то останавливало/шел другой сценарий.

User avatar
mikeyww
Posts: 5351
Joined: 09 Sep 2014, 18:38

Re: Буфер обмена

Post by mikeyww » 05 Dec 2020, 14:13

Code: Select all

#Persistent
watchText = Вам это недоступно
SetTimer, Watch, 300
Watch:
SoundBeep, 1500, 20
If !Instr(Clipboard, watchText)
 Return
MsgBox, 64, Success, Found it! Exiting.
ExitApp

maker22811
Posts: 8
Joined: 05 Dec 2020, 13:43

Re: Буфер обмена

Post by maker22811 » 05 Dec 2020, 14:21

Спасибо, это почти что нужно.
Задача:
Копируется текст, если это: "Это вам недоступно", то выполняется одно действие, если текст другой, то выполняется другое действие.

User avatar
mikeyww
Posts: 5351
Joined: 09 Sep 2014, 18:38

Re: Буфер обмена

Post by mikeyww » 05 Dec 2020, 14:37

Code: Select all

#Persistent
Global watchText := "Это вам недоступно"
OnClipboardChange("ClipChanged")

ClipChanged(Type) {
 If Instr(Clipboard, watchText) {
  MsgBox, 64, Success, Found!
 } Else {
  MsgBox, 48, Failure, Not found!
 }
}

maker22811
Posts: 8
Joined: 05 Dec 2020, 13:43

Re: Буфер обмена

Post by maker22811 » 05 Dec 2020, 14:44

Спасибо, ты лучший!!!

garry
Posts: 2629
Joined: 22 Dec 2013, 12:50

Re: Буфер обмена

Post by garry » 06 Dec 2020, 13:12

@mikeyww
" Kilroy mikeyww was here "
Thank you mikeyww for big help everywhere

User avatar
mikeyww
Posts: 5351
Joined: 09 Sep 2014, 18:38

Re: Буфер обмена

Post by mikeyww » 06 Dec 2020, 13:32

That's funny!

Thank you for the kind feedback. :)

maker22811
Posts: 8
Joined: 05 Dec 2020, 13:43

Re: Буфер обмена

Post by maker22811 » 23 Dec 2020, 09:36

Скрипт действительно хорошо показывает себя в работе. Но теперь необходимо 2 фразы.
Пример:
Копируется: "Это вам недоступно" - идёт один сценарий.
Копируется: "Пусто" - идёт другой сценарий.
И если копируется другой текст, то идёт ещё сценарий.

User avatar
mikeyww
Posts: 5351
Joined: 09 Sep 2014, 18:38

Re: Буфер обмена

Post by mikeyww » 23 Dec 2020, 09:49

Code: Select all

#Persistent
OnClipboardChange("ClipChanged")

ClipChanged(Type) {
 Static watchText := "Это вам недоступно,Пусто"
 If Clipboard contains %watchText%
      MsgBox, 64, Success, Found!
 Else MsgBox, 48, Failure, Not found!
}

maker22811
Posts: 8
Joined: 05 Dec 2020, 13:43

Re: Буфер обмена

Post by maker22811 » 23 Dec 2020, 09:49

Спасибо большое!

maker22811
Posts: 8
Joined: 05 Dec 2020, 13:43

Re: Буфер обмена

Post by maker22811 » 23 Dec 2020, 09:53

Ой, стоп, извините за мою требовательность. Но возможно я не так сформулировал вопрос.
Нужен разный сценарий при "Это вам недоступно" и "Пусто" и любым другим текстом

User avatar
mikeyww
Posts: 5351
Joined: 09 Sep 2014, 18:38

Re: Буфер обмена

Post by mikeyww » 23 Dec 2020, 10:02

Code: Select all

#Persistent
OnClipboardChange("ClipChanged")
Return

Routine1:
MsgBox, Found Это вам недоступно
Return

Routine2:
MsgBox, Found Пусто
Return

ClipChanged(Type) {
 For index, thisText in ["Это вам недоступно", "Пусто"]
  Try Gosub, % Instr(Clipboard, thisText) ? "Routine" index : ""
}

maker22811
Posts: 8
Joined: 05 Dec 2020, 13:43

Re: Буфер обмена

Post by maker22811 » 23 Dec 2020, 10:10

Спасибо, в какой строчке вписывать действия, когда был скопирован обычный текст?

User avatar
mikeyww
Posts: 5351
Joined: 09 Sep 2014, 18:38

Re: Буфер обмена

Post by mikeyww » 23 Dec 2020, 10:24

Code: Select all

#Persistent
OnClipboardChange("ClipChanged")
Return

Routine1:
MsgBox, Found Это вам недоступно
Return

Routine2:
MsgBox, Found Пусто
Return

NotFound:
MsgBox, Ничего не найдено!
Return

ClipChanged(Type) {
 found := False
 For index, thisText in ["Это вам недоступно", "Пусто"]
  If Instr(Clipboard, thisText) {
   found := True
   Gosub, Routine%index%
  }
 If !found
  Gosub, NotFound
}
Last edited by mikeyww on 23 Dec 2020, 10:26, edited 1 time in total.

maker22811
Posts: 8
Joined: 05 Dec 2020, 13:43

Re: Буфер обмена

Post by maker22811 » 23 Dec 2020, 10:26

Спасибо большое.
Вы очень упростили мне жизнь этим скриптом.
Вы мастер своего дела)

Post Reply

Return to “Помощь”