ClipSend() - Send text quickly with clipboard

william_ahk · Post by **william_ahk** » 25 Mar 2022, 07:36

Function:

ClipSend(Text, PS := "") {
    ClipSave := ClipboardAll
    Clipboard := Text
    Send ^v
    while DllCall("GetOpenClipboardWindow")
        sleep -1
    Clipboard := ClipSave
    if PS
        Send % PS
}

There were previous libraries of the same functionality but they all used SetTimer to restore the clipboard, which causes Ctrl+V to send the saved clipboard content on occasion. Recently I discovered that one can use GetOpenClipboardWindow to determine whether the system clipboard is currently being used. So I adopted the function to block clipboard restoration before pasting is finished.

Example usage:

Code: Select all

!l::ClipSend("a very loooooooooooooooooooooooooooooooong text")

Code: Select all

; You can also specify words or keys to press right after the content is pasted as the second argument for convenience.
:X:dqs::ClipSend("document.querySelector("""")", "{Left 2}")
:X:cslg::ClipSend("console.log()", "{Left 1}")

Code: Select all

html_boilerplate =
(
<!DOCTYPE html>
<html>
<head>
<meta charset="utf-8">
<title></title>
<meta name="viewport" content="width=device-width, initial-scale=1">
</head>
<body>

</body>
</html>
)

:X:htmlbp::ClipSend(html_boilerplate, "{Up 2}")

guest3456 · Post by **guest3456** » 25 Mar 2022, 10:34

here's another for some more inspiration:

https://www.autohotkey.com/board/topic/111817-robust-copy-and-paste-routine-function/

gibbons6546 · Post by **gibbons6546** » 26 Mar 2022, 16:27

Thanks. Will try to implement this.

AutoHotkey Community

ClipSend() - Send text quickly with clipboard

ClipSend() - Send text quickly with clipboard

Re: ClipSend() - Send text quickly with clipboard

Re: ClipSend() - Send text quickly with clipboard