Screen clipping

[rommmcek]

@one1tick: Basically you have to replace original Gdip_BitmapFromScreen() with the edited one including ScaleDim().

Note: The new functions are stubs¹ so you have to adjust hardcoded static values (for both functions) according to your configurations!
__________
¹stub

[anhnha]

Hello,
I changed the function Gdip_BitmapFromScreen to this. You'll need to change screen heights, widths, and scales to your values.
EDIT: I didn't see rommmcek's post above. That was what I used.

Code: Select all

; Function				Gdip_BitmapFromScreen
; Description			Gets a gdi+ bitmap from the screen
;
; Screen				0 = All screens
;						Any numerical value = Just that screen
;						x|y|w|h = Take specific coordinates with a width and height
; Raster				raster operation code
;
; return      			If the function succeeds, the return value is a pointer to a gdi+ bitmap
;						-1:		one or more of x,y,w,h not passed properly
;
; notes					If no raster operation is specified, then SRCCOPY is used to the returned bitmap

;  firstMonScale := 150
;  secondMonScale:= 100
;  firstMonWidth := 3480
;  firstMonHight := 2160 
;  secondMonWidth:= 1080
;  secondMonHight:= 1920
Gdip_BitmapFromScreen(Screen=0, Raster="") {
 static firstMonWidth := 3480, firstMonHight := 2160
 if (Screen = 0)
 {
  Sysget, x, 76
  Sysget, y, 77 
  Sysget, w, 78
  Sysget, h, 79
  ws:= w, hs:= h
 }
 else if (Screen&1 != "")
 {
  Sysget, M, Monitor, %Screen%
  x:= MLeft, y:= MTop, w:=ws:= MRight-MLeft, h:=hs:= MBottom-MTop
 }
 else
 {
  StringSplit, S, Screen, |
  x:= S1, y:= S2, w:=ws:= S3, h:=hs:= S4
 }

 if (x = "") || (y = "") || (w = "") || (h = "")
  return -1

 if (x>firstMonWidth)
    x:= ScaleDim(x-firstMonWidth)+firstMonWidth, y:= ScaleDim(y), w:= ScaleDim(w), h:= ScaleDim(h)
 if (x<0 || y<0)
    x:= ScaleDim(x), y:= ScaleDim(y), w:= ScaleDim(w), h:= ScaleDim(h)
 if (y>firstMonHight)
    x:= ScaleDim(x), y:= ScaleDim(y-firstMonHight)+firstMonHight, w:= ScaleDim(w), h:= ScaleDim(h)

 chdc := CreateCompatibleDC(), hbm := CreateDIBSection(ws, hs, chdc), obm := SelectObject(chdc, hbm), hhdc := GetDC()
 StretchBlt(chdc, 0, 0, ws, hs, hhdc, x, y, w, h, Raster)
 ReleaseDC(hhdc)
 
 pBitmap := Gdip_CreateBitmapFromHBITMAP(hbm)
 SelectObject(hhdc, obm), DeleteObject(hbm), DeleteDC(hhdc), DeleteDC(chdc)
 return pBitmap
}

ScaleDim(val) {
    static firstMonScale := 150, SecondMonScale:= 100
    Return round(val/(firstMonScale/secondMonScale))
}

[ajnasaboobacker]

Can i have this complete script to start with, may be somewhere i can download

[SpeedMaster]

... cleaned up a lot of the code and made it more modular

Hello,
Thank you for this version. As it is very difficult to publish new features without altering the main script.
I managed to split the different modules to offer an easier script to extend with #Include Lib\newfeature.ahk.
I didn't manage to integrate the whole script but the mains parts are there.


how to install the different parts ?
Create a \Lib folder next to the RUN_ScreenCLip.ahk file and put all the new libraries or plugins there as well as the file gdip_all.ahk (by Marius ?ucan).
https://github.com/marius-sucan/AHK-GDIp-Library-Compilation/archive/refs/heads/master.zip

FG Screen Clipper (Plugin Edition)
You can try to unzip this starting package V1.7 :

ScreenClipperStartingPackage_V1.7.zip

(119.93 KiB) Downloaded 154 times

or install the files manually (see below)
main script: Run_ScreenClip.ahk
files in Lib folder: Gdip_all.ahk, FG_Header.ahk, FG_ScreenClip.ahk, FG_Context_Clip_Menu.ahk

File Name : RUN_ScreenCLip.ahk

Code: Select all

; File Name: RUN_ScreenCLip.ahk
; version : 1.7
; Main Run file
; autors : Fanatic Guru, Speedmaster

#Requires AutoHotkey v1.1.1+

; INITIALIZATION - ENVIROMENT
; -------------------------------------------------------------------------------------
#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.
#SingleInstance force  ; Ensures that only the last executed instance of script is running
; #NoTrayIcon  ; if you want no tray icon
Menu, tray, icon, %A_WinDir%\system32\mmcndmgr.dll,106  ; camera tray icon
; --------------------------------------------------------------------------------------
OnExit("ExitFGClipper")   ; clear the cache folder before exiting

;exit procedure
ExitFGClipper(){
global
loop 99
FileDelete, % CacheFolder "\" a_index ".png"         ; clear the cache folder
exitapp
}


; INCLUDE SECTION
; --------------------------------------------------------------------------------------
; -------------------- headers plugins
#Include lib\
#Include gdip_all.ahk               ; graphic library
#Include ImagePut.ahk               ; (for v1) graphic library
#Include FG_Header.ahk              ; change the default settings in this script.
#Include FG_ScreenClip.ahk          ; main script library
#Include FG_Context_Clip_Menu.ahk   ; there are 2 context menu in this file (full and basic)
;#Include JL_Shrink.ahk             ; double click to shrink or restore window size

; ------------------- footers plugins
;#Include SM_Borders.ahk            ; Press B to hide or show borders (toggle)
;#Include SM_RotateFlip.ahk			; Press R or Ctrl R to rotate current selected clip 90° or 180°
;#Include SM_Vis2.ahk               ; Press T to OCR (with tesseract.exe) (by iseahound)
;#Include SM_HideShowAll.ahk        ; Press F12 to Hide / Show all clip images
;#Include SM_Duplicate.ahk          ; Press D to duplicate selected clip image
;#Include SM_AlwaysOnBottom.ahk     ; Press PageDown / PageUp to make selected clip always on bottom or restore always on top
;#Include SM_Resizer.ahk            ; Press Crtl + Mouse wheel or Numpad Add/Sub to resize
;#Include GK_OCR.ahk				; Press Y to use internal Windows 10 OCR   (win 10+ only)
;#Include SM_Grayscale.ahk			; Press G to toggle grayscale
;#Include SM_MoveClip.ahk			; Press arrow or ctrl arrow keys to move clip by 10 or 1 pixel
;#Include SM_Trans.ahk			    ; Press Shift + Mouse wheel to make clip image transparent. Not compatible with other plugins. Use plugin duplicate to restore.
;#Include SM_DrawShape.ahk			; Press P to activate drawing mode. Use Shift Ctrl and Alt + mouse to draw shapes. Press Ctrl + P to abort.
; ---------------------------------------------------------------------------------------


; HOTKEYS GLOBAL SECTION
; -----------------------------------------------
;
#Lbutton::		;	<-- Clip Image Only
	SCW_ScreenClip2Win(SetClipboard:=false)
return

#^Lbutton::	;	<-- Clip Image and Copy to Clipboard
	SCW_ScreenClip2Win(SetClipboard:=true)
return

#!Lbutton::		;	<-- Clip Image and Save to File
	Hwnd := SCW_ScreenClip2Win(SetClipboard:=false)
	SCW_Win2File(Settings_SavePath,Hwnd)
return

#^!Lbutton::	;	<-- Clip Image, Copy to Clipboard, and Save to File
	Hwnd := SCW_ScreenClip2Win(SetClipboard:=true)
	SCW_Win2File(Settings_SavePath,Hwnd)
return

; HOTKEYS IF_WIN_ACTIVE SECTION
; ---------------------------------------------------------------------------------------
#IfWinActive, ScreenClipperWindow ahk_class AutoHotkeyGUI

; REMOVE (DESTROY) SELECTED CLIP IMAGE
; ---------------------------------------------------------------------------------------
Esc::
WinGet, Hwnd, ID, A
MaxGuis := SCW_Reg("MaxGuis"), i := SCW_Reg("StartAfter")
   	Loop % MaxGuis {
        if (SCW_Reg("G" ++i "#HWND") = hwnd) {
	        currentgui := i
			break
		}}
	gui %currentgui%: destroy
	FileDelete, % CacheFolder "\" currentgui ".png"          ; also remove cached image (if there is one)
return

; RIGHT CLICK CONTEXT MENU
; ---------------------------------------------------------------------------------------
Rbutton:: Menu, FG_Context_Clip_2, Show

^c::				;	<-- (Screen Clipper) : Copy Active Clip to Clipboard  (true = remove borders)
	SCW_Win2Clipboard(true)
return
+^c::			;	<-- (Screen Clipper) : Copy Active Clip to Clipboard with Border (false = with borders)
	SCW_Win2Clipboard(false)
return
^s::				;	<-- (Screen Clipper) : Save Active Clip to File
	SCW_Win2File(Settings_SavePath)
return
+^s::			;	<-- (Screen Clipper) : Save Active Clip to File with Border
	SCW_Win2File(Settings_SavePath,,0)
return
#e::				;	<-- (Screen Clipper) : Save Active Clip to File and Email
	File := SCW_Win2File(Settings_SavePath)
	Email_AttachFile(File)
return

#IfWinActive
; -----------------------------------------------------------------------------------------------------------

-------------------------------------------------------

Files to put in the Lib folder:

File Name : FG_Header.ahk

Spoiler

Code: Select all

; file name: FG_Header.ahk
; version : 1.7
; FG_ScreenClip settings Header
; autors : Fanatic Guru, Speedmaster
;
; Requierd:
; Include in this order:
;          Lib\FG_Header.ahk
;          Lib\FG_ScreenClip.ahk
;		   Lib\FG_Context_Clip_Menu.ahk
;
; --------------- HELP for SCW_SetUp() --------------------------------------------
;	StartAfter - module will start to consume GUIs for screen clipping windows after specified GUI number. Default: 80
;	MaxGuis - maximum number of screen clipping windows. Default: 6
;	BorderAColor - Default: ff6666ff (ARGB format)
;	BorderBColor - Default: ffffffff (ARGB format)
;	DrawCloseButton - on/off draw "Close Button" on screen clipping windows. Default: 0 (off)
;	AutoMonitorWM_LBUTTONDOWN - on/off automatic monitoring of WM_LBUTTONDOWN message. Default: 1 (on)
;	SelColor - selection color. Default: Yellow
;	SelTrans - selection transparency. Default: 80
; -------------------------------------------------------------------------------

; ------------------- force running in 32 bit instead of 64 bit ---------------------------

if((A_PtrSize=8&&A_IsCompiled="")||!A_IsUnicode){ ;32 bit=4  ;64 bit=8
    SplitPath,A_AhkPath,,dir
    if(!FileExist(correct:=dir "\AutoHotkeyU32.exe")){
	    MsgBox error
	    ExitApp
    }
    Run,"%correct%" "%A_ScriptName%",%A_ScriptDir%
    ExitApp
    return
}

; ------------------- Change the default settings for the screen clipper here -------------

SCW_SetUp("MaxGuis.15 StartAfter.50 BorderAColor.ff6666ff BorderBColor.ffffffff DrawCloseButton.0 AutoMonitorWM_LBUTTONDOWN.1 SelColor.Yellow SelTrans.80")

; INITIALIZATION - VARIABLES
;Obtain IMGUR API token value here: https://imgur.com/account/settings
global GuiNum  ;  to know the name (number) of the created gui this internal variable function name is made global.
Settings_Imgur_Client := "xxxxxxxxxxxxxxx"
Settings_SavePath := ".\Images - Screen Clipper\"					; the place where the images will be saved
RelativePath(Settings_SavePath)
Settings_SavePathPDF := ".\PDF - Screen Clipper\"                   ; the place where the pdfs will be saved
RelativePath(Settings_SavePathPDF)
Settings_Ini := A_ScriptFullPath ": Screen Clipper.ini"             ; Ini File in Script's Alternate Data Stream (requires NTFS)
Settings_Ini := A_ScriptDir "\Screen Clipper.ini"                   ; Normal Ini File
CacheFolder:= A_ScriptDir "\temp"                                   ; folder where temporary images are stored (please, do not put the last "\")
SCW_Reg("CacheFolder", Cachefolder)

; -------------------- Read Settings from Ini File ----------------------------------------
if FileExist(Settings_Ini)
{
	IniRead, Settings_Imgur_Client, %Settings_Ini%, Settings, Settings_Imgur_Client, %Settings_Imgur_Client%
	IniRead, Settings_SavePath, %Settings_Ini%, Settings, Settings_SavePath, %Settings_SavePath%
}

; ------------------- clear the cache folder ---------------------------------------------
zlist:={}
loop 99 {
	FileDelete, % SCW_Reg("cachefolder") "\" a_index ".png"
}

File Name : FG_ScreenClip.ahk

Spoiler

Code: Select all

; file name: FG_ScreenClip.ahk
; Screen Clipper
; Fanatic Guru
; Version 1.7  2023 04 23

;[module/script] ScreenClip2Win
;Author:      Learning one
;Thanks:      Tic, HotKeyIt

; FUNCTIONS
;{-----------------------------------------------
;
;{vvvvv SCW Functions vvvvv
/*
[module/script] ScreenClip2Win
Author:      Learning one
Thanks:      Tic, HotKeyIt

Creates always on top layered windows from screen clippings. Click in upper right corner to close win. Click and drag to move it.
Uses Gdip.ahk by Tic.

#Include ScreenClip2Win.ahk    						; by Learning one
;=== Short documentation ===
SCW_ScreenClip2Win(SetClipboard:=0) 		; creates always on top window from screen clipping. Click and drag to select area.
SCW_DestroyAllClipWins()								; destroys all screen clipping windows.
SCW_Win2Clipboard(DeleteBorders:=1)			; copies window to clipboard. By default, removes borders. To keep borders, specify "SCW_Win2Clipboard(0)"
SCW_SetUp(Options="")		; you can change some default options in Auto-execute part of script. Syntax: "<option>.<value>"
	StartAfter - module will start to consume GUIs for screen clipping windows after specified GUI number. Default: 80
	MaxGuis - maximum number of screen clipping windows. Default: 6
	BorderAColor - Default: ff6666ff (ARGB format)
	BorderBColor - Default: ffffffff (ARGB format)
	DrawCloseButton - on/off draw "Close Button" on screen clipping windows. Default: 0 (off)
	AutoMonitorWM_LBUTTONDOWN - on/off automatic monitoring of WM_LBUTTONDOWN message. Default: 1 (on)
	SelColor - selection color. Default: Yellow
	SelTrans - selection transparency. Default: 80

	Example:   SCW_SetUp("MaxGuis.30 StartAfter.50 BorderAColor.ff000000 BorderBColor.ffffff00")

;=== Avoid OnMessage(0x201, "WM_LBUTTONDOWN") collision example===
Gui, Show, w200 h200
SCW_SetUp("AutoMonitorWM_LBUTTONDOWN.0")   ; turn off auto monitoring WM_LBUTTONDOWN
OnMessage(0x201, "WM_LBUTTONDOWN")   ; manualy monitor WM_LBUTTONDOWN
Return

^Lbutton::SCW_ScreenClip2Win()   ; click & drag
Esc::ExitApp

#Include Gdip.ahk      ; by Tic
#Include ScreenClip2Win.ahk      ; by Learning one
WM_LBUTTONDOWN() {
	if SCW_LBUTTONDOWN()   ; LBUTTONDOWN on module's screen clipping windows - isolate - it's module's buissines
		return
	else   ; LBUTTONDOWN on other windows created by script
		MsgBox,,, You clicked on script's window not created by this module,1
}
*/

SCW_Version()
{
	return 1.03
}

SCW_DestroyAllClipWins()
{
	MaxGuis := SCW_Reg("MaxGuis"), StartAfter := SCW_Reg("StartAfter")
	Loop, %MaxGuis%
	{
		StartAfter++
		Gui %StartAfter%: Destroy
	}
}

SCW_SetUp(Options="")
{
   if !(Options = "")
	{
		Loop, Parse, Options, %A_Space%
		{
			Field := A_LoopField
			DotPos := InStr(Field, ".")
			if (DotPos = 0)
				Continue
			var := SubStr(Field, 1, DotPos-1)
			val := SubStr(Field, DotPos+1)
			if var in StartAfter,MaxGuis,AutoMonitorWM_LBUTTONDOWN,DrawCloseButton,BorderAColor,BorderBColor,SelColor,SelTrans
				%var% := val
		}
	}

	SCW_Default(StartAfter,80), SCW_Default(MaxGuis,6)
	SCW_Default(AutoMonitorWM_LBUTTONDOWN,1), SCW_Default(DrawCloseButton,0)
	SCW_Default(BorderAColor,"ff6666ff"), SCW_Default(BorderBColor,"ffffffff")
	SCW_Default(SelColor,"Yellow"), SCW_Default(SelTrans,80)
	SCW_Reg("MaxGuis", MaxGuis), SCW_Reg("StartAfter", StartAfter), SCW_Reg("DrawCloseButton", DrawCloseButton)
	SCW_Reg("BorderAColor", BorderAColor), SCW_Reg("BorderBColor", BorderBColor)          ; <---- for thin border dasactivate this line and activate the line below
	; SCW_Reg("BorderBColor", BorderBColor)                                               ; <---- for thick border desactivate this line and activate the line above
	SCW_Reg("SelColor", SelColor), SCW_Reg("SelTrans",SelTrans)
	SCW_Reg("WasSetUp", 1)
	if AutoMonitorWM_LBUTTONDOWN
		OnMessage(0x201, "SCW_LBUTTONDOWN")
}

SCW_ScreenClip2Win(SetClipboard:=0)
{
	static c
	if !(SCW_Reg("WasSetUp"))
		SCW_SetUp()
	StartAfter := SCW_Reg("StartAfter"), MaxGuis := SCW_Reg("MaxGuis"), SelColor := SCW_Reg("SelColor"), SelTrans := SCW_Reg("SelTrans")
	c++
	if (c > MaxGuis)
		c := 1
	GuiNum := StartAfter + c
	; remove cached image
	FileDelete, % SCW_Reg("CacheFolder") "\" GuiNum ".png"
	Area := SCW_SelectAreaMod("g" GuiNum " c" SelColor " t" SelTrans)
	StringSplit, v, Area, |
	if (v3 < 10 and v4 < 10)   ; too small area
		return
	pToken := Gdip_Startup()
	if pToken =
	{
		MsgBox, 64, GDI+ error, GDI+ failed to start. Please ensure you have GDI+ on your system.
		return
	}
	Sleep, 100
	pBitmap := Gdip_BitmapFromScreen(Area)
	if (SetClipboard=1)
		Gdip_SetBitmapToClipboard(pBitmap)
	hwnd := SCW_CreateLayeredWinMod(GuiNum,pBitmap,v1,v2, SCW_Reg("DrawCloseButton"))
	Gdip_DisposeImage(pBitmap)
	Gdip_Shutdown(pToken)
	return hwnd
}

SCW_SelectAreaMod(Options="")
{
	CoordMode, Mouse, Screen
	MouseGetPos, MX, MY
	loop, parse, Options, %A_Space%
	{
		Field := A_LoopField
		FirstChar := SubStr(Field,1,1)
		if FirstChar contains c,t,g,m
		{
			StringTrimLeft, Field, Field, 1
			%FirstChar% := Field
		}
	}
	c := (c = "") ? "Blue" : c, t := (t = "") ? "50" : t, g := (g = "") ? "99" : g
	Gui %g%: Destroy
	Gui %g%: +AlwaysOnTop -caption +Border +ToolWindow +LastFound
	WinSet, Transparent, %t%
	Gui %g%: Color, %c%
	Hotkey := RegExReplace(A_ThisHotkey,"^(\w* & |\W*)")
	While, (GetKeyState(Hotkey, "p"))
	{
		Sleep, 10
		MouseGetPos, MXend, MYend
		w := abs(MX - MXend), h := abs(MY - MYend)
		X := (MX < MXend) ? MX : MXend
		Y := (MY < MYend) ? MY : MYend
		Gui %g%: Show, x%X% y%Y% w%w% h%h% NA
	}
	Gui %g%: Destroy
	MouseGetPos, MXend, MYend
	If ( MX > MXend )
		temp := MX, MX := MXend, MXend := temp
	If ( MY > MYend )
		temp := MY, MY := MYend, MYend := temp
	Return MX "|" MY "|" w "|" h
}

SCW_CreateLayeredWinMod(GuiNum,pBitmap,x,y,DrawCloseButton=0)
{
	static CloseButton := 16
	BorderAColor := SCW_Reg("BorderAColor"), BorderBColor := SCW_Reg("BorderBColor")

	Gui %GuiNum%: -Caption +E0x80000 +LastFound +ToolWindow +AlwaysOnTop +OwnDialogs
	Gui %GuiNum%: Show, Na, ScreenClipperWindow
	hwnd := WinExist()

	Width := Gdip_GetImageWidth(pBitmap), Height := Gdip_GetImageHeight(pBitmap)
	hbm := CreateDIBSection(Width+6, Height+6), hdc := CreateCompatibleDC(), obm := SelectObject(hdc, hbm)
	G := Gdip_GraphicsFromHDC(hdc), Gdip_SetSmoothingMode(G, 4), Gdip_SetInterpolationMode(G, 7)

	Gdip_DrawImage(G, pBitmap, 3, 3, Width, Height)
	Gdip_DisposeImage(pBitmap)

	pPen1 := Gdip_CreatePen("0x" BorderAColor, 3), pPen2 := Gdip_CreatePen("0x" BorderBColor, 1)
	if DrawCloseButton
	{
		Gdip_DrawRectangle(G, pPen1, 1+Width-CloseButton+3, 1, CloseButton, CloseButton)
		Gdip_DrawRectangle(G, pPen2, 1+Width-CloseButton+3, 1, CloseButton, CloseButton)
	}
	Gdip_DrawRectangle(G, pPen1, 1, 1, Width+3, Height+3)
	Gdip_DrawRectangle(G, pPen2, 1, 1, Width+3, Height+3)
	Gdip_DeletePen(pPen1), Gdip_DeletePen(pPen2)

	UpdateLayeredWindow(hwnd, hdc, x-3, y-3, Width+6, Height+6)
	SelectObject(hdc, obm), DeleteObject(hbm), DeleteDC(hdc), Gdip_DeleteGraphics(G)
	SCW_Reg("G" GuiNum "#HWND", hwnd)
	SCW_Reg("G" GuiNum "#XClose", Width+6-CloseButton)
	SCW_Reg("G" GuiNum "#YClose", CloseButton)
	Return hwnd
}

SCW_LBUTTONDOWN()
{
	MouseGetPos,,, WinUMID
	WinGetTitle, Title, ahk_id %WinUMID%
	if Title = ScreenClipperWindow
	{
		PostMessage, 0xA1, 2,,, ahk_id %WinUMID%
		KeyWait, Lbutton
		CoordMode, mouse, Relative
		MouseGetPos, x,y
		XClose := SCW_Reg("G" A_Gui "#XClose"), YClose := SCW_Reg("G" A_Gui "#YClose")
		if (x > XClose and y < YClose){
			Gui %A_Gui%: Destroy
			; remove cached image
			FileDelete, % SCW_Reg("CacheFolder") "\" A_Gui ".png"
		}
		return 1   ; confirm that click was on module's screen clipping windows
	}
}

SCW_Reg(variable, value="")
{
	static
	if (value = "")
		return kxucfp%variable%pqzmdk
	else
		kxucfp%variable%pqzmdk = %value%
}

SCW_Default(ByRef Variable,DefaultValue)
{
	if (Variable="")
		Variable := DefaultValue
}

SCW_Win2Clipboard(DeleteBorders:=1, Hwnd := "")
{
	/*   ;   does not work for layered windows
	ActiveWinID := WinExist("A")
	pBitmap := Gdip_BitmapFromHWND(ActiveWinID)
	Gdip_SetBitmapToClipboard(pBitmap)
	*/
	if !Hwnd
		WinGet, Hwnd, ID, A
	WinGetPos, X, Y, W, H,  ahk_id %Hwnd%
	if DeleteBorders
		X+=3, Y+=3, W-=6, H-=6
	pToken := Gdip_Startup()
	pBitmap := Gdip_BitmapFromScreen(X "|" Y "|" W "|" H)
	Gdip_SetBitmapToClipboard(pBitmap)
	Gdip_Shutdown(pToken)
}

SCW_Win2File(SavePath,Hwnd := "",DeleteBorders:=1)
{
	IfNotExist, %SavePath%
		FileCreateDir, %SavePath%
	if !Hwnd
		WinGet, Hwnd, ID, A
	WinGetPos, X, Y, W, H,  ahk_id %Hwnd%
	if DeleteBorders
		X+=3, Y+=3, W-=6, H-=6
	pToken := Gdip_Startup()
	pBitmap := Gdip_BitmapFromScreen(X "|" Y "|" W "|" H)
	FormatTime, TimeStamp ,, yyyy_MM_dd @ HH_mm_ss
	FileName := TimeStamp " (" w "x" h  ").PNG"
	Gdip_SaveBitmapToFile(pBitmap, SavePath FileName)
	Gdip_DisposeImage(pBitmap)
	Gdip_Shutdown(pToken)
	return SavePath FileName
}
;}^^^^^ SCW Functions ^^^^^

Email_AttachFile(File, URL:="")
{
	try
		IsObject(MailItem := ComObjActive("Outlook.Application").CreateItem(olMailItem:=0)) ; Get the Outlook application object if Outlook is open
	catch
		MailItem  := ComObjCreate("Outlook.Application").CreateItem(olMailItem:=0) ; Create if Outlook is not open
	MailItem.BodyFormat := (olFormatHTML:=2)
	;~ MailItem.TO :="[email protected]"
	;~ MailItem.CC :="[email protected]"
	FormatTime, TimeStamp , % RegExReplace(File, "^.*\\|[_ @]|\(.*$"), dddd MMMM d, yyyy h:mm:ss tt
	MailItem.Subject :="Screen shot taken : " (TimeStamp) ; Subject line of email
	HTMLBody := "
		<H2 style='BACKGROUND-COLOR: red'><br></H2>
		<HTML>Please find attached the screenshot taken on " TimeStamp "<br><br>"
	if URL
		HTMLBody .= "
			<span style='color:black'>The image can also be accessd here: <a href=""" (URL) """>" (URL) "</a>  <br><br></span>"
	HTMLBody .= "</HTML>"
	MailItem.HTMLBody := HTMLBody
	MailItem.Attachments.Add(File)
	MailItem.Display
}

Imgur_Post(File, Client)
{
	Http := ComObjCreate("WinHttp.WinHttpRequest.5.1")
	Img := ComObjCreate("WIA.ImageFile")
	Img.LoadFile(File)
	/* 	; Converts Image to JPG
	IP := ComObjCreate("WIA.ImageProcess")
	IP.Filters.Add(IP.FilterInfos("Crop").FilterID)
	IP.Filters.Add(IP.FilterInfos("Convert").FilterID)
	IP.Filters(2).Properties("FormatID").Value:="{B96B3CAE-0728-11D3-9D7B-0000F81EF32E}"
	IP.Filters(2).Properties("Quality").Value:=85
	Img := IP.Apply(Img)
	*/
	Data := Img.FileData.BinaryData
	Http.Open("POST","https://api.imgur.com/3/upload")
	Http.SetRequestHeader("Authorization","Client-ID " Client)
	Http.SetRequestHeader("Content-Length",size)
	Http.Send(Data)
	Codes:=Http.ResponseText
	split=":"
	RegExMatch(Codes, "U)link" split "(.*)" Chr(34), Match)
	URL:=RegExReplace(Match1, "\\")
	Return URL
}

Clipboard2Acrobat(SavePathPDF:="")		; Adobe Acrobat must be installed
{
	App := ComObjCreate("AcroExch.App")
	App.Show()
	App.MenuItemExecute("ImageConversion:Clipboard")
	if SavePathPDF
	{
		IfNotExist, %SavePathPDF%
			FileCreateDir, %SavePathPDF%
		FormatTime, TimeStamp ,, yyyy_MM_dd @ HH_mm_ss
		FileName := TimeStamp ".PDF"
		AVDoc := App.GetActiveDoc()
		PVDoc := AVDoc.GetPDDoc()
		PDSaveIncremental		:= 0x0000   ;/* write changes only */
		PDSaveFull						:= 0x0001   ;/* write entire file */
		PDSaveCopy					:= 0x0002   ;/* write copy w/o affecting current state */
		PDSaveLinearized			:= 0x0004   ;/* write the file linearized for */
		PDSaveBinaryOK			:= 0x0010   ;/* OK to store binary in file */
		PDSaveCollectGarbage	:= 0x0020   ;/* perform garbage collection on */
		PVDoc.save(PDSaveFull|PDSaveLinearized, SavePathPDF FileName)
	}
}

RelativePath(ByRef Path)
{
	RegExMatch(Path,"^(\.*)\\",M), R := StrLen(M1)
	if (R=1)
		Path := A_ScriptDir SubStr(Path,R+1)
	else if (R>1)
		Path := SubStr(A_ScriptDir,1,InStr(A_ScriptDir,"\",,0,R-1)) SubStr(Path,R+2)
	return Path
}

GuiDefaultFont() { ; by SKAN (modified by just me)
   VarSetCapacity(LF, szLF := 28 + (A_IsUnicode ? 64 : 32), 0) ; LOGFONT structure
   If DllCall("GetObject", "Ptr", DllCall("GetStockObject", "Int", 17, "Ptr"), "Int", szLF, "Ptr", &LF)
      Return {Name: StrGet(&LF + 28, 32), Size: Round(Abs(NumGet(LF, 0, "Int")) * (72 / A_ScreenDPI), 1)
            , Weight: NumGet(LF, 16, "Int"), Quality: NumGet(LF, 26, "UChar")}
   Return False
}

WaitReleaseAllModifiers()
{
   List := "LWin|RWin|LAlt|RAlt|LControl|RControl|LShift|RShift"
   while !Done
	{
		Done := true
		Loop Parse, list, |
			if (GetKeyState(A_LoopField))
				Done := false
	Sleep 50
	}
}

[Plugin] File Name: FG_Context_Clip_Menu.ahk

Spoiler

Code: Select all

/* ;--------------------------------------------------------------------------------------------------------------------
[Plugin] FG Context Clip Menu  (by Speedmaster)
File Name : FG_Context_Clip_Menu.ahk
version: 1.5.01
topic: https://www.autohotkey.com/boards/viewtopic.php?p=506077#p506077
Help:
how to install this plugin ?
1° download FG ScreenClipper at https://www.autohotkey.com/boards/viewtopic.php?p=506077#p506077
2° put this plugin in the Lib folder of the main script
3° insert #Include FG_Context_Clip_Menu.ahk in the INCLUDE SECTION of the main script ---> RUN_ScreenCLip.ahk

Note this plugin has internal default shortcuts (see below) that you can change
or migrate in the #ifwinactive section of the main run script  (Run_screenclip.ahk)
*/ ;---------------------------------------------------------------------------------------------------------------------

;DEFAULT SHORTCUT ---------------------------------------------------
; You will find the default internal shortcut (rbutton::) at the end of this script.
; Note: Internal default shortcuts for menu plugins are by default desactivated.


; ------------------ Simplified Menu---------------------------------------------------------------------------

Menu, FG_Context_Clip_2, add, COPY:  &Clipboard										, FG_Context_Clip_2_Handler
Menu, FG_Context_Clip_2, add, COPY:  Clipboard (with Border)						, FG_Context_Clip_2_Handler
Menu, FG_Context_Clip_2, add
Menu, FG_Context_Clip_2, add, SAVE:  &File											, FG_Context_Clip_2_Handler
Menu, FG_Context_Clip_2, add, SAVE:  File (with Border)								, FG_Context_Clip_2_Handler
Menu, FG_Context_Clip_2, add, SAVE:  File && Email									, FG_Context_Clip_2_Handler
Menu, FG_Context_Clip_2, add
Menu, FG_Context_Clip_2, add, OPEN :  Saved Images Folder     						, FG_Context_Clip_2_Handler
Menu, FG_Context_Clip_2, add, CLOSE:  Clip Image									, FG_Context_Clip_2_Handler


FG_Context_Clip_2_Handler(){
	global
		if (A_ThisMenuItemPos = 9) ; Close (destroy) Clip Image
		{
			 WinGet, Hwnd, ID, A
	         MaxGuis := SCW_Reg("MaxGuis"), i := SCW_Reg("StartAfter")
        	Loop % MaxGuis {
	       	     if (SCW_Reg("G" ++i "#HWND") = hwnd) {
		    	     currentgui := i
		    	     break
		            }}
			gui %currentgui%: destroy
			FileDelete, % CacheFolder "\" currentgui ".png"          ; also remove cached image (if there is one)
		}

		Sleep 350	; Context Menu selection fades out and needs time to disappear before Clipping
		if  (A_ThisMenuItemPos = 1)		; Clipboard
			SCW_Win2Clipboard()
		else if (A_ThisMenuItemPos = 2)	; Clipboard with Border
			SCW_Win2Clipboard(0)
			else if (A_ThisMenuItemPos = 4) ; File
			SCW_Win2File(Settings_SavePath)
		else if (A_ThisMenuItemPos = 5) ; File with Border
			SCW_Win2File(Settings_SavePath,,0)
		else if (A_ThisMenuItemPos = 6) ; File & Email
		{
			File := SCW_Win2File(Settings_SavePath)
			Email_AttachFile(File)
		}
		else if (A_ThisMenuItemPos = 8) ; open saved images folder
			Run, % Settings_SavePath

		;~ MsgBox You selected %A_ThisMenuItemPos% - %A_ThisMenuItem% from the menu %A_ThisMenu%.
}

; ------------------- Full Menu --------------------------------------------------------------------------------

Menu, FG_Context_Clip_1, add, COPY:  &Clipboard										, FG_Context_Clip_1_Handler
Menu, FG_Context_Clip_1, add, COPY:  Clipboard (with Border)						, FG_Context_Clip_1_Handler
Menu, FG_Context_Clip_1, add
Menu, FG_Context_Clip_1, add, SAVE:  &PDF											, FG_Context_Clip_1_Handler
Menu, FG_Context_Clip_1, add, SAVE:  PDF (with Border)								, FG_Context_Clip_1_Handler
Menu, FG_Context_Clip_1, add, SAVE:  P&DF - Saved									, FG_Context_Clip_1_Handler
Menu, FG_Context_Clip_1, add, SAVE:  PDF - Saved (with Border)						, FG_Context_Clip_1_Handler
Menu, FG_Context_Clip_1, add
Menu, FG_Context_Clip_1, add, SAVE:  &File											, FG_Context_Clip_1_Handler
Menu, FG_Context_Clip_1, add, SAVE:  File (with Border)								, FG_Context_Clip_1_Handler
Menu, FG_Context_Clip_1, add, SAVE:  File && Email									, FG_Context_Clip_1_Handler
Menu, FG_Context_Clip_1, add, SAVE:  File && Imgur									, FG_Context_Clip_1_Handler
Menu, FG_Context_Clip_1, add, SAVE:  File`, Imgur && Email							, FG_Context_Clip_1_Handler
Menu, FG_Context_Clip_1, add
Menu, FG_Context_Clip_1, add
Menu, FG_Context_Clip_1, add, CLOSE:  Clip Image									, FG_Context_Clip_1_Handler

;~ Context Menu 1 handler (Right Click)
FG_Context_Clip_1_Handler(){
	global
		if (A_ThisMenuItemPos = 17) ; Close (destroy) Clip Image
		{
			 WinGet, Hwnd, ID, A
	         MaxGuis := SCW_Reg("MaxGuis"), i := SCW_Reg("StartAfter")
        	Loop % MaxGuis {
	       	     if (SCW_Reg("G" ++i "#HWND") = hwnd) {
		    	     currentgui := i
		    	     break
		            }}
			gui %currentgui%: destroy
			FileDelete, % CacheFolder "\" currentgui ".png"          ; also remove cached image (if there is one)
		}
		Sleep 350	; Context Menu selection fades out and needs time to disappear before Clipping
		if  (A_ThisMenuItemPos = 1)		; Clipboard
			SCW_Win2Clipboard()
		else if (A_ThisMenuItemPos = 2)	; Clipboard with Border
			SCW_Win2Clipboard(0)
		else if (A_ThisMenuItemPos = 4) ; Clipboard to PDF
		{
			SCW_Win2Clipboard()
			Clipboard2Acrobat()
		}
		else if (A_ThisMenuItemPos = 5) ; Clipboard with Border to PDF
		{
			SCW_Win2Clipboard(0)
			Clipboard2Acrobat()
		}
		else if (A_ThisMenuItemPos = 6) ; Clipboard to PDF and Save
		{
			SCW_Win2Clipboard()
			Clipboard2Acrobat(Settings_SavePathPDF)
		}
		else if (A_ThisMenuItemPos = 7) ; Clipboard with Border to PDF and Save
		{
			SCW_Win2Clipboard(0)
			Clipboard2Acrobat(Settings_SavePathPDF)
		}
		else if (A_ThisMenuItemPos = 9) ; File
			SCW_Win2File(Settings_SavePath)
		else if (A_ThisMenuItemPos = 10) ; File with Border
			SCW_Win2File(Settings_SavePath,,0)
		else if (A_ThisMenuItemPos = 11) ; File & Email
		{
			File := SCW_Win2File(Settings_SavePath)
			Email_AttachFile(File)
		}
		else if (A_ThisMenuItemPos = 12) ; File & Imgur
		{
			File := SCW_Win2File(Settings_SavePath)
			URL := Imgur_Post(File, Settings_Imgur_Client)
			Clipboard := URL
		}
		else if (A_ThisMenuItemPos = 13) ; File, Imgur & Email
		{
			File := SCW_Win2File(Settings_SavePath)
			URL := Imgur_Post(File, Settings_Imgur_Client)
			Email_AttachFile(File, URL)
		}
		else if (A_ThisMenuItemPos = 16) ; open saved images folder
			Run, % Settings_SavePath

		;~ MsgBox You selected %A_ThisMenuItemPos% - %A_ThisMenuItem% from the menu %A_ThisMenu%.
}



;~ ; DEFAULT SHORTCUTS ---------------------------------------------------
;~ #IfWinActive, ScreenClipperWindow ahk_class AutoHotkeyGUI
;~ Rbutton:: Menu, FG_Context_Clip_2, Show
;~ #IfWinActive
;~ ;----------------------------------------------------------------------

-

All suggestions or new plugins are welcome
Regards

[SpeedMaster]

[PLUGIN] Hide Show borders

how to install this plugin ?
1° download FG ScreenClipper at viewtopic.php?p=506077#p506077
2° put this plugin in the Lib folder of the main script ( RUN_ScreenCLip.ahk)
2° insert '#Include SM_Borders.ahk' in the 'include section' of the main script

Internal shortcuts:
Press B to hide/restore current selected clip image
Press Ctrl B to restore all hidden clip image borders

I have condensed your code a bit to make the hotkey section more readable

@Gorgrak Thank you, it helped me a lot to develop this plugin

File Name: SM_Borders.ahk

Code: Select all

/*--------------------------------------------------------------------------------------------------------------------
Hide Borders Plugin (by Speedmaster)
File Name : SM_Borders.ahk
version: 1.0
topic: https://www.autohotkey.com/boards/viewtopic.php?p=506077#p506077
Help:
how to install this plugin ?
1° download FG ScreenClipper at https://www.autohotkey.com/boards/viewtopic.php?p=506077#p506077
2° put this plugin in the Lib folder of the main script
2° insert '#Include SM_Borders.ahk' in the 'include section' of the main script ---> RUN_ScreenCLip.ahk

Note this plugin has internal default shortcuts (see below) that you can change 
or migrate in the #ifwinactive section of the main run script
*/---------------------------------------------------------------------------------------------------------------------


; DEFAULT SHORTCUTS ---------------------------------------------------
#IfWinActive, ScreenClipperWindow ahk_class AutoHotkeyGUI
b::SM_Borders()                 ; hide/restore current selected clip image  
^b::SM_RestoreAllBorders()      ; restore all hidden clip image borders
#IfWinActive
;--------------------------------------------------------------


; FUNCTIONS 
;------------------------------------- Hide/Show active window borders ------------------------------------------------
; function toggle borders 
SM_Borders() {
	WinGet, Hwnd, ID, A
	WinGet, Style, Style, ahk_id %Hwnd%
	if (Style & 0x2000)  ; toggle selected
	{
		WinSet, Style, -0x2000, A
		WinSet, Region, , A 
		return false
	}
	else                 ; retore selected
	{
		WinGetPos, X, Y, W, H,  ahk_id %Hwnd%
		W -= 6, H -= 6
		WinSet, Style, +0x2000, A
		WinSet, Region, 3-3 W%W% H%H%, A
		return true
	}	
}

; function to restore all hidden borders
SM_RestoreAllBorders() {
   MaxGuis := SCW_Reg("MaxGuis"), StartAfter := SCW_Reg("StartAfter")
   Loop, %MaxGuis%
   {
      StartAfter++
      Gui %StartAfter%: +lastfound
	  WinSet, Style, -0x2000
      WinSet, Region,
   }
   return false
}

[Gorgrak]

@SpeedMaster
Yeah I love using Ternary to condense stuff into 1 line.

[SpeedMaster]

[PLUGIN] Rotate Flip v1.7

how to install this plugin ?
1° download FG ScreenClipper at viewtopic.php?p=506077#p506077
2° put this plugin in the Lib folder of the main script
3° Install plugin SM_Resizer.ahk at viewtopic.php?p=509598#p509598
4° insert "#Include SM_RotateFlip.ahk" in the INCLUDE SECTION of the main script ---> RUN_ScreenCLip.ahk

Internal shortcuts:
Press R to rotate 90° right (usefull for making vertical text)
Press Ctrl R to rotate 180° (usefull for turning a picture upside down)

Note:

• You can try others numbers for the function SM_RotateFlip(1) (up to 6) to mirror or invert the clip image.
• the plugin requires the SM_resizer.ahk plugin to be installed but it can also work in standalone by disabling the function call for resizing
• the plugin use cached images stored in the "\temp" folder in the script directroy. The cache folder is cleared at startup and on exit.

File Name: SM_RotateFlip.ahk

Code: Select all

/*--------------------------------------------------------------------------------------------------------------------
[Plugin] Rotate/Flip (by Speedmaster)
File Name : SM_RotateFlip.ahk
version: 1.7   2023 04 23
topic: https://www.autohotkey.com/boards/viewtopic.php?p=506077#p506077
Help:
how to install this plugin ?
1° download FG ScreenClipper at https://www.autohotkey.com/boards/viewtopic.php?p=506077#p506077
2° put this plugin in the Lib folder of the main script
3° Install plugin SM_Resizer.ahk at https://www.autohotkey.com/boards/viewtopic.php?p=509598#p509598
4° insert "#Include SM_RotateFlip.ahk" in the INCLUDE SECTION of the main script ---> RUN_ScreenCLip.ahk

Note this plugin has internal default shortcuts (see below) that you can change 
or migrate in the #ifwinactive section of the main run script
*/---------------------------------------------------------------------------------------------------------------------


; DEFAULT SHORTCUTS ---------------------------------------------------
;Try others numbers (up to 6) to mirror or invert the clip image.
#IfWinActive, ScreenClipperWindow ahk_class AutoHotkeyGUI
r::SM_RotateFlip(1)    ; rotate 90° right (usefull for making vertical text)
^r::SM_RotateFlip(2)   ; rotate 180° (usefull to turn image)
#IfWinActive
;--------------------------------------------------------------

;-------- FUNTION TO ROTATE OR FLIP IMAGE ---------------------
SM_RotateFlip(type:=1){
global zlist, cachefolder

	imageput.gdiplusstartup()

	(!CacheFolder)&&CacheFolder:="temp"

	IfNotExist, %CacheFolder%
		FileCreateDir, %CacheFolder%
		if (ErrorLevel) {
			CacheFolder:=A_temp
        }

	WinGet, hwnd, ID, A
	MaxGuis := SCW_Reg("MaxGuis"), i := SCW_Reg("StartAfter")		
	Loop % MaxGuis {
		if (SCW_Reg("G" ++i "#HWND") = hwnd) {
			currentgui := i
			break
		}
	}	
	
	winGetPos, X, Y, W, H, ahk_id %Hwnd%
	x:=x+3, y:=y+3, w:=w-6, h:=h-6
	imgg:=CacheFolder "\" currentgui ".png"
	if (!FileExist(imgg)) {
		pBitmap := Gdip_BitmapFromScreen(X "|" Y "|" W "|" H)
		FileName := currentgui ".PNG"
		Gdip_SaveBitmapToFile(pBitmap, CacheFolder "\" FileName)
		imgg:=CacheFolder "\" FileName
	}

	pBitmap:=Gdip_CreateBitmapFromFileSimplified(imgg)
	Gdip_ImageRotateFlip(pBitmap, type) 
	WinSet, Style, -0x2000, A
	WinSet, Region, , A   ; restore hidden borders (if any) before writing image in gui

	Gdip_SaveBitmapToFile(pBitmap, imgg)

	if !(zlist["Scaled"][currentgui]) {
		SCW_CreateLayeredWinMod(currentgui,pBitmap,x,y)
    }
	if (zlist["Scaled"][currentgui]) {
		sm_resize("1","0")                        ; desactivate this line if the resizer plugin is not installed
	}

	Gdip_DisposeImage(pBitmap)
	imageput.gdiplusShutdown()		
}

[Avastgard]

Awesome, thanks for this!

But I can't get it to work. The yellow square shows, but disappears once I let go of LButton and doesn't clip the image.

Could you further explain how to install the plugin? Here's the folder structure I have:

Code: Select all

...ScreenClipper\
	Lib\
	RUN_ScreenCLip.ahk

...Lib\
	FG_Context_Clip_Menu.ahk"
	FG_Header.ahk"
	FG_ScreenClip.ahk"
	Gdip.ahk"
	SM_RotateFlip.ahk"

[SpeedMaster]

I can't get it to work. The yellow square shows, but disappears once I let go of LButton and doesn't clip the image.

The folder and file structure is correct.
It seems that the GDI library I had specified was not compatible with the AHK U64 version.
I tested with the library Gdip_all (from Marius Șucan) and it woks fine now. https://github.com/marius-sucan/AHK-GDIp-Library-Compilation
I updated the previous links to work with gdip_all.
Thank you for reporting this problem.
I hope it will work now.

[SpeedMaster]

Hello,
I made some necessary updates in the starting package. viewtopic.php?p=506077#p506077
changes:

• added version for the starting package (v1.1)
• added Global var GuiNum in the header file
• The context clip menu is now modified to behave like a plugin . Bug fix: removed "return" + menus handlers are now functions

Regards

[Avastgard]

Thanks for the update, @SpeedMaster!

Do you plan to add OCR functionality?

[SpeedMaster]

Do you plan to add OCR functionality?

No but this should not be too hard to implement since there is already a library available. (Vis2 OCR by iseahound )
I have written a plugin (wrapper) that should do the trick.
See below...
Not fully tested yet. Can you tell me if it works ?

[SpeedMaster]

[PLUGIN] OCR v1.3.02 (with Tesseract)

how to install this plugin ?
1° download ScreenClipperStartingPackage.zip at viewtopic.php?p=506077#p506077
2° put this plugin in the Lib folder of the main script (the folder where "RUN_ScreenCLip.ahk" file is located)
3° insert entry '#Include SM_Vis2.ahk' in the 'include section' of the main script ---> RUN_ScreenCLip.ahk
4° download Vis2 library (by iseahound) at https://github.com/iseahound/Vis2
5° copy the "bin" folder in the main Run script directory (the folder where "RUN_ScreenCLip.ahk" file is located)
6° insert Vis2.ahk, Json.ahk and Imageput.ahk in the \Lib folder
7° select a clip image and press T then select area for OCR

Internal shortcuts:
Press T to save OCR text in clipboard

Warning: This plugin can freeze your screen if it has not been properly installed
make sure that the Bin folder is in the main RUN script folder and that all other libraries are in the Lib folder before trying it.

File Name: SM_Vis2.ahk

Code: Select all

/*--------------------------------------------------------------------------------------------------------------------
File Name : SM_Vis2.ahk 
version: 1.3.02
topic: https://www.autohotkey.com/boards/viewtopic.php?p=506077#p506077
Help:
how to install this plugin ?
1° download ScreenClipperStartingPackage at https://www.autohotkey.com/boards/viewtopic.php?p=506077#p506077
2° put this plugin in the Lib folder of the main script (the folder where "RUN_ScreenCLip.ahk" file is located)
3° insert entry '#Include SM_Vis2.ahk' in the 'include section' of the main script ---> RUN_ScreenCLip.ahk
4° download Vis2 library (by iseahound) at https://github.com/iseahound/Vis2
5° copy the "bin" folder in the main Run script directory (the folder where "RUN_ScreenCLip.ahk" file is located)
6° insert Vis2.ahk, Json.ahk and Imageput.ahk in the \Lib folder
7° select a clip image and press T then select area for OCR

Note this plugin has internal default shortcuts (see below) that you can change 
or migrate in the #ifwinactive section of the main run script
*/---------------------------------------------------------------------------------------------------------------------

#Include Vis2.ahk     ; by iseahound   https://github.com/iseahound/Vis2

; DEFAULT SHORTCUTS ---------------------------------------------------
;Press T to select with mouse area for ocr.

#IfWinActive, ScreenClipperWindow ahk_class AutoHotkeyGUI
t::SM_OCR(1)                    ; sm_ocr(1)= save to clipboard and show clipboard in message box  -   sm_ocr(2) = save to clipboard and open clipboard in notepad 
#IfWinActive

;-------- FUNCTION SM_OCR ---------------------
;HELP: 
;     if output=1 .......... save to clipboard and show clipboard in message box
;     if output=2 .......... save to clipboard and open clipboard in notepad 
;     if RemoveEmptyLines=true ........... save to clipboard and remove empty lines from clipboard

SM_OCR(output:="2", RemoveEmptyLines:=true){
	if !pToken := Gdip_Startup()
	{
		MsgBox, 64, GDI+ error, GDI+ failed to start. Please ensure you have GDI+ on your system.
		return
	}
	if (output=1) {
		ocr()
		if RemoveEmptyLines
            clipboard:=RegExReplace(clipboard, "`am)^\R")
		msgbox, % clipboard
}
else if (output=2) {	
	ocr()
sleep, 100
	if RemoveEmptyLines
	   clipboard:=RegExReplace(clipboard, "`am)^\R")
	Run Notepad.exe
	Sleep, 100
	SendInput ^v
	}
}

[Avastgard]

Thanks, it appears to be working. However, OCR is very slow and it is a very important feature to me. I have been using Joe Glines' version (Window Snipping.ahk for a while, which is less stable (script needs to be reloaded every now and then), but has a much faster OCR.

By the way, about the rotating plugin:

[PLUGIN] Rotate Flip

how to install this plugin ?
1° download FG ScreenClipper at viewtopic.php?p=506077#p506077
2° put this plugin in the Lib folder of the main script ( RUN_ScreenCLip.ahk)
2° insert #Include SM_RotateFlip.ahk in the INCLUDE SECTION of the main script ( RUN_ScreenCLip.ahk)

Internal shortcuts:
Press R to rotate 90° right (usefull for making vertical text)
Press Ctrl R to rotate 180° (usefull for turning a picture upside down)
Note: You can try others numbers (up to 6) to mirror or invert the clip image.

File Name: SM_RotateFlip.ahk

Code: Select all

/*--------------------------------------------------------------------------------------------------------------------
[Plugin] Rotate/Flip (by Speedmaster)
File Name : SM_RotateFlip.ahk
version: 1.0
topic: https://www.autohotkey.com/boards/viewtopic.php?p=506077#p506077
Help:
how to install this plugin ?
1° download FG ScreenClipper at https://www.autohotkey.com/boards/viewtopic.php?p=506077#p506077
2° put this plugin in the Lib folder of the main script
2° insert "#Include SM_RotateFlip.ahk" in the INCLUDE SECTION of the main script ---> RUN_ScreenCLip.ahk

Note this plugin has internal default shortcuts (see below) that you can change 
or migrate in the #ifwinactive section of the main run script
*/---------------------------------------------------------------------------------------------------------------------


; DEFAULT SHORTCUTS ---------------------------------------------------
;Try others numbers (up to 6) to mirror or invert the clip image.
#IfWinActive, ScreenClipperWindow ahk_class AutoHotkeyGUI
r::SM_RotateFlip(1)    ; rotate 90° right (usefull for making vertical text)
^r::SM_RotateFlip(2)   ; rotate 180° (usefull to turn image)
#IfWinActive
;--------------------------------------------------------------

;-------- FUNTION TO ROTATE OR FLIP IMAGE ---------------------
SM_RotateFlip(type:=1){
WinGet, hwnd, ID, ahk_class AutoHotkeyGUI
	Loop 99 {
		Gui %A_Index%: +LastFound
		if WinExist() = hwnd {
			currentgui := A_Index
			break
		}
	}
winGetPos, X, Y, W, H, ahk_id %Hwnd%
x:=x+3, y:=y+3, w:=w-6, h:=h-6
pToken := Gdip_Startup()
pBitmap := Gdip_BitmapFromScreen(X "|" Y "|" W "|" H)
Gdip_ImageRotateFlip(pBitmap, type) 
WinSet, Style, -0x2000, A
WinSet, Region, , A   ; restore hidden borders (if any) before writing image in gui
SCW_CreateLayeredWinMod(currentgui,pBitmap,x,y)
Gdip_Shutdown(pToken)
}

R and Ctrl + R work fine for me, but the number options don't. Do I have to use NumPad numbers to make it work?

[SpeedMaster]

Thanks, it appears to be working. However, OCR is very slow...

Yep, it's really too slow when specifying coordinates , but it's much faster when you do it manually with Vis2's own selector.
I updated the previous SM_OCR plugin to v1.2 viewtopic.php?f=6&t=12088&start=240#p507222
New function: SM_OCR(output:="2", RemoveEmptyLines:=true)
Now when you press T the internal selector is launched to manually select with the mouse the region to OCR.
I also added an option to delete empty lines and an option to output text to notepad (output=2) or the message box (output=1).

By the way, about the rotating plugin:
R and Ctrl + R work fine for me, but the number options don't. Do I have to use NumPad numbers to make it work?

No, this has nothing to do with the numeric keypad, it is rather a parameter for the type of rotation SM_RotateFlip(type:=1). (type 1 to 6)
You have to create a keyboard shortcut in the plugin to test all the other possibilities.
The other possibilities are not really interesting, that's why I didn't incorporate them in the script.

here is a complete list of shortcuts to try

Spoiler

Code: Select all

r::SM_RotateFlip(1)    ; rotate 90° right (usefull for making vertical text)
^r::SM_RotateFlip(2)   ; rotate 180° (usefull to turn image)
!r::SM_RotateFlip(3)   ; rotate 90° left
f::SM_RotateFlip(4)    ; (mirror) horizontal flip
!f::SM_RotateFlip(5)   ; rotate 90° right and flip vertical
^f::SM_RotateFlip(6)   ; (mirror) vertical flip

Regards

[SpeedMaster]

Press T to save OCR text in clipboard

After some tests I noticed that the plugin for ocr (SM_Vis2) was unstable and freezing the screen.
I added a line in the plugin script to force the launch of gdip, the problem seems to be solved now. posting.php?mode=quote&f=6&p=507222#pr507222
Regard

[SpeedMaster]

[PLUGIN] Hide/Show All Clip Images v1.0

how to install this plugin ?
1° download FG ScreenClipper v1.2+ at viewtopic.php?p=506077#p506077
2° put this plugin in the Lib folder of the main RUN script
2° insert this line " #Include SM_HideShowAll.ahk " in the INCLUDE SECTION of the main script ---> RUN_ScreenCLip.ahk

Internal Global shortcut:
Press F12 to hide or show all clip images.

Note: you can always change the keyboard shortcut by the one you like, taking care not to conflict with the shortcuts of other plugins

File Name: SM_HideShowAll.ahk

Code: Select all

/*--------------------------------------------------------------------------------------------------------------------
[Plugin] Hide/Show (toggle) All Clip Images  (by Speedmaster)
File Name : SM_HideShowAll.ahk
version: 1.0.00
topic: https://www.autohotkey.com/boards/viewtopic.php?p=506077#p506077
Help:
how to install this plugin ?
1° download FG ScreenClipper at https://www.autohotkey.com/boards/viewtopic.php?p=506077#p506077
2° put this plugin in the Lib folder of the main script
2° insert line " #Include SM_HideShowAll.ahk " in the INCLUDE SECTION of the main script ---> RUN_ScreenCLip.ahk

Note this plugin has internal default shortcuts (see below) that you can change 
or migrate in the HOTKEYS GLOBAL SECTION of the main RUN script
*/---------------------------------------------------------------------------------------------------------------------



; HOTKEYS GLOBAL SECTION
;-----------------------------------------------

~F12::SM_HideShowAll()     ; toggle visibility of all clip images





;-------- FUNCTION SM_HideShowAll() ---------------------
;HELP: 
;     this function has a static true/false variable that toggle visibility of all clip images

SM_HideShowAll() {
static HideAll
HideAll:=!HideAll
MaxGuis := SCW_Reg("MaxGuis"), i := SCW_Reg("StartAfter")
	Loop, %MaxGuis%
	{
		++i
		Gui %i%: +LastFound
		
		if (HideAll) {
		    if (SCW_Reg("G" i "#HWND") = WinExist()) 
				Gui %i%: hide
		}
		else 
		    if (SCW_Reg("G" i "#HWND") = WinExist()) 
				Gui %i%: show, NA
	}
}	

Cheers

[SpeedMaster]

[PLUGIN] Hide/Show All Clip Images
Press F12 to hide or show all clip images.

I noticed that the hide/show all plugin also showed the images that had been previously closed.
I updated the main RUN file and the context clip menu plugin so that it would destroy the window properly instead of hiding it.
Main files update v1.3 : viewtopic.php?p=506077#p506077

cheers

[SpeedMaster]

[PLUGIN] Duplicate v1.2

how to install this plugin ?
1° download FG ScreenClipper v1.2+ at viewtopic.php?p=506077#p506077
2° put this plugin in the Lib folder of the main RUN script
3° insert this line " #Include SM_Duplicate.ahk " in the INCLUDE SECTION of the main script ---> RUN_ScreenCLip.ahk
4° Install plugin SM_Resizer.ahk at viewtopic.php?p=509598#p509598

Internal shortcut:
Press D to use selected image area for making a new clip image. ( d for duplicate )

Note: the new duplicated image is placed just in front of the selected clip image giving the illusion that nothing happened...
Please move the new clip image with the mouse to check if everything went well

File Name: SM_Duplicate.ahk

Code: Select all

/*--------------------------------------------------------------------------------------------------------------------
[Plugin] Duplicate (by Speedmaster)
File Name : SM_Duplicate.ahk
version: 1.2
topic: https://www.autohotkey.com/boards/viewtopic.php?p=506077#p506077
Help:
how to install this plugin ?
1° download FG ScreenClipper at https://www.autohotkey.com/boards/viewtopic.php?p=506077#p506077
2° put this plugin in the Lib folder of the main RUN script
3° insert "#Include SM_Duplicate.ahk" in the INCLUDE SECTION of the main RUN script ---> RUN_ScreenCLip.ahk
4° Install plugin SM_Resizer.ahk at https://www.autohotkey.com/boards/viewtopic.php?p=509598#p509598

Note this plugin has internal default shortcuts (see below) that you can change 
or migrate in the #ifwinactive section of the main run script
*/---------------------------------------------------------------------------------------------------------------------


; DEFAULT SHORTCUT ----- (#ifwinactive section)----------------------------------------------
#IfWinActive, ScreenClipperWindow ahk_class AutoHotkeyGUI
d::SM_Duplicate()               ; duplicate (use selected image area for making a new clip image)
#IfWinActive

;-----FUNCTION DUPLICATE AREA------------------------------------------
SM_Duplicate(DuplicateToPos:=""){
	global GuiNum
	SCW_ScreenClip2Win(SetClipboard:=0)
	if (DuplicateToPos)
	guinum:=DuplicateToPos
	WinGetPos , OutX, OutY, OutWidth, OutHeight, A
	OutX:=OutX+3, OutY:=OutY+3, OutWidth:=OutWidth-6, OutHeight:=OutHeight-6
	Area := OutX "|" OutY "|" OutWidth "|" OutHeight
	StringSplit, v, Area, |
	if (v3 < 10 and v4 < 10)   ; too small area
		return
    imageput.gdiplusstartup()
	pBitmap := Gdip_BitmapFromScreen(Area)
	hwnd := SCW_CreateLayeredWinMod(guinum,pBitmap,v1,v2, SCW_Reg("DrawCloseButton"))
	Gdip_DisposeImage(pBitmap)
	imageput.gdiplusShutdown()	
}	

Cheers

[SpeedMaster]

[PLUGIN] Shrink v1.0 (by Juho-Lee)

Usage:
Double click to shrink or restore the window size

how to install this plugin ?
1° download FG ScreenClipper v1.2+ at viewtopic.php?p=506077#p506077
2° put this plugin in the Lib folder of the main RUN script
3° Note: this is a header plugin which means that it must be loaded before the plugins that contain shortcuts
insert this line "#Include JL_Shrink.ahk" in the INCLUDE SECTION of the main RUN script just after
the line that contains "#Include Fg_Context_Clip_Menu.ahk" for it to work properly

like this:
#Include gdip_all.ahk
#Include FG_Header.ahk
#Include FG_ScreenClip.ahk
#Include FG_Context_Clip_Menu.ahk
#Include JL_Shrink.ahk <------- insert the line entry here

Internal shortcut:
DOUBLE CLICK to shrink the window and double click again to restore it.

File Name: JL_Shrink.ahk

Code: Select all

/*--------------------------------------------------------------------------------------------------------------------
[Plugin] Shrink  (by Juho-Lee [url]https://juho-lee.com[/url])
File Name : JL_Shrink.ahk
version: 1.0
topic: https://www.autohotkey.com/boards/viewtopic.php?p=506077#p506077
Help:
how to install this plugin ?
1° download FG ScreenClipper at https://www.autohotkey.com/boards/viewtopic.php?p=506077#p506077
2° put this plugin in the Lib folder of the main script
3° Note: this is a header plugin which means that it must be loaded before the plugins that contain shortcuts
   insert this line "#Include JL_Shrink.ahk" in the INCLUDE SECTION of the main RUN script just after 
   the line that contains "#Include Fg_Context_Clip_Menu.ahk" for it to work properly

   like this:
   #Include gdip_all.ahk               
   #Include FG_Header.ahk 
   #Include FG_ScreenClip.ahk 
   #Include FG_Context_Clip_Menu.ahk
   #Include JL_Shrink.ahk            <------- insert the line entry here
*/---------------------------------------------------------------------------------------------------------------------


; DEFAULT SHORTCUT ---------------------------------------------------
;double click to downsize. Double click again to resize.

OnMessage(0x0203, "WM_LBUTTONDBLCLK") 
WM_LBUTTONDBLCLK() { 
    
   global
    
   WinGet, TempID, , A
   WinGetPos, , , Temp_Width, Temp_Height, A 
   
   If (Temp_Width = 30 && Temp_Height = 30) {
      WinMove, A, , , , % %TempID%_Width, % %TempID%_Height
   } else {
   %TempID%_Width := Temp_Width
   %TempID%_Height := Temp_Height
   WinMove, A, , , , 30, 30
   }      

}

Learn more about the author at https://juho-lee.com
Regards