Translating with Deepl API

[enrz]

Hi everyone!
I'm trying to create a script that translate with deepl.com a text I insert in an InputBox.
I want to use the Deepl API (free) and recive the translation in a msgbox,
The Http Request is this:

EXAMPLE REQUEST
POST /v2/translate?auth_key=[KEY]> HTTP/1.0
Host: api.deepl.com
User-Agent: YourApp
Accept: */*
Content-Length: [length]
Content-Type: application/x-www-form-urlencoded
auth_key=[KEY]&text=Hello, world&target_lang=DE

EXAMPLE RESPONSE
{
"translations": [{
"detected_source_language":"EN",
"text":"Hallo, Welt!"
}]
}

How Can I implement this in AHK? I think with WinHttp but it doesn't work.
Thanks

[RussF]

Much has already been written on this topic, one of which is this one. I suggest you do a forum search for "deepl" or "deepl.com" and see what is there rather than reinvent the wheel.

Russ

[enrz]

Thanks, I didn't found anything useful.
I try to create this script, based on Airtable http request. Is It correct?

Code: Select all

!r::
InputBox, txt, Text to translate

Data := {"Host":"api-free.deepl.com", "User-Agent":"YourApp","Accept":" */*","Content-Length":"5","Content-Type":"application/x-www-form-urlencoded"}

WinHttp := ComObjCreate("WinHttp.WinHttpRequest.5.1")
WinHttp.Open("POST", "https://api-free.deepl.com/v2/translate?auth_key=KEY" HTTP/1.0)
WinHttp.SetRequestHeader("Content-Type", "application/json")
WinHttp.SetRequestHeader("Authorization", "Bearer" "KEY&text="%txt%, "world&target_lang=EN")
WinHttp.Send(Data)
MsgBox % WinHttp.ResponseText

return

[RussF]

I'm sorry, I can't speak to your code. I adapted this script from @teadrinker (thank you, @teadrinker!) to make a Google-based translation utility for my wife who is a kindergarten teacher. She uses it to translate a weekly newsletter to the parents of her students, a few who are non-English-speaking.

I've heard that Google has a limit on the number of calls to this utility, but we have never run up against it. Deepl has published limits on its free version. I do remember a thread dealing with deepl banning users trying to hit it too much for free.

When I search the AHK forum with just the keyword "deepl", I get 110 hits. Have you investigated all of these?

Russ

[malcev]

Thanks, I didn't found anything useful.

Why? Last my post in this topic with link to deepl hack should work.
viewtopic.php?p=435542#p435542
Just need to translate it from python or use python.
Also if You are interested in reverse-engineering then You can read this article.
https://zu1k.com/posts/thinking/deception-tactics-in-deepl-api-design/

[teadrinker]

Last my post in this topic with link to deepl hack should work.

Tried, doesn't work. Error «Too many requests» after split_into_sentences(text, kwargs).

Spoiler

Code: Select all

global API_URL := "https://www2.deepl.com/jsonrpc"
     , MAGIC_NUMBER := 0xCAFEBABE
     , headers := { accept: "*/*"
                  , "accept-language": "en-US;q=0.8,en;q=0.7"
                  , authority: "www2.deepl.com"
                  , "content-type": "application/json"
                  , origin: "https://www.deepl.com"
                  , referer: "https://www.deepl.com/translator"
                  , "sec-fetch-dest": "empty"
                  , "sec-fetch-mode": "cors"
                  , "sec-fetch-site": "same-site"
                  , "user-agent": "Mozilla/5.0 (Linux; Android 6.0; Nexus 5 Build/MRA58N) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/83.0.4103.97 Mobile Safari/537.36" }
     
MsgBox, % translate("EN", "RU", "Hello, World!", {formality_tone: "formal"})

translate(source_language, target_language, text, kwargs) {
   response := request_translation(source_language, target_language, text, kwargs)
}

request_translation(source_language, target_language, text, kwargs) {
   sentences := split_into_sentences(text, kwargs)
   data := generate_translation_request_data(source_language, target_language, sentences, MAGIC_NUMBER, kwargs*)
}

generate_translation_request_data(source_language, target_language, sentences, MAGIC_NUMBER, alternatives := 1, formality_tone := "") {
   return { jsonrpc: "2.0"
          , method: "LMT_handle_jobs"
          , params: { jobs: generate_jobs(sentences, alternatives)
                    , lang: { user_preferred_langs: [target_language, source_language]
                            , source_lang_computed: source_language
                            , target_lang: target_language }
                    , priority: 1
                    , commonJobParams: generate_common_job_params(formality_tone)
                    , timestamp: generate_timestamp(sentences) }
          , id: 40430000 }
}

generate_jobs(sentences, beams := 1) {
   jobs := []
   for k, sentence in sentences {
      jobs.Push( { kind: "default"
                 , raw_en_sentence: sentence
                 , raw_en_context_before: sentences[k - 1]
                 , raw_en_context_after: [sentences[k + 1]]
                 , preferred_num_beams: beams } )
   }
   Return jobs
}

split_into_sentences(text, kwargs) {
   data := generate_split_sentences_request_data(text, MAGIC_NUMBER)
   MsgBox, % WebRequest(API_URL, "POST", headers, AhkToJSON(data), error := "")
   MsgBox, % error
}

generate_common_job_params(formality_tone) {
   if !formality_tone
      Return {}
   if formality_tone not in formal,informal
      throw "formality_tone not supported"
   return {formality: formality_tone}
}

generate_timestamp(sentences) {
   Return A_TickCount ; not implemented yet
}

generate_split_sentences_request_data(text, identifier) {
   Return { jsonrpc: "2.0"
          , method: "LMT_split_into_sentences"
          , params: { texts: [text]
                    , lang: {lang_user_selected: "auto", user_preferred_langs: []} }
          , id: identifier }
}

WebRequest(url, method := "GET", HeadersArray := "", body := "", ByRef error := "") {
   Whr := ComObjCreate("WinHttp.WinHttpRequest.5.1")
   Whr.Open(method, url, true)
   for name, value in HeadersArray
      Whr.SetRequestHeader(name, value)
   Whr.Send(body)
   Whr.WaitForResponse()
   status := Whr.status
   if (status != 200)
      error := "HttpRequest error, status: " . status
   Arr := Whr.responseBody
   pData := NumGet(ComObjValue(arr) + 8 + A_PtrSize)
   length := Arr.MaxIndex() + 1
   Return StrGet(pData, length, "UTF-8")
}

AhkToJSON(obj, indent := "") {
   static Doc, JS
   if !Doc {
      Doc := ComObjCreate("htmlfile")
      Doc.write("<meta http-equiv=""X-UA-Compatible"" content=""IE=9"">")
      JS := Doc.parentWindow
      ( Doc.documentMode < 9 && JS.execScript() )
   }
   if indent|1 {
      if IsObject( obj ) {
         isArray := true
         for key in obj {
            if IsObject(key)
               throw Exception("Invalid key")
            if !( key = A_Index || isArray := false )
               break
         }
         for k, v in obj
            str .= ( A_Index = 1 ? "" : "," ) . ( isArray ? "" : %A_ThisFunc%(k, true) . ":" ) . %A_ThisFunc%(v, true)

         Return isArray ? "[" str "]" : "{" str "}"
      }
      else if !(obj*1 = "" || RegExMatch(obj, "^-?0|\s"))
         Return obj
      
      for k, v in [["\", "\\"], [A_Tab, "\t"], ["""", "\"""], ["/", "\/"], ["`n", "\n"], ["`r", "\r"], [Chr(12), "\f"], [Chr(8), "\b"]]
         obj := StrReplace( obj, v[1], v[2] )

      Return """" obj """"
   }
   sObj := %A_ThisFunc%(obj, true)
   Return JS.eval("JSON.stringify(" . sObj . ",'','" . indent . "')")
}

[malcev]

This is because You dont generate needed timestamps

Code: Select all

generate_timestamp(sentences) {
   Return A_TickCount ; not implemented yet
}

Also here is written about this issue.
https://github.com/ptrstn/deepl-translate/issues/16
Need add some sleep between requests.

[teadrinker]

For me an error rises after the first request. Tryed also using VPN.

[malcev]

https://github.com/ptrstn/deepl-translate/blob/master/deepl/hacks.py

[teadrinker]

What do you mean? generate_id() ? For me no luck.

[malcev]

I mean

Code: Select all

def calculate_valid_timestamp(timestamp, i_count):
    try:
        return timestamp + (i_count - timestamp % i_count)
    except ZeroDivisionError:
        return timestamp


def generate_timestamp(sentences):
    now = int(time.time() * 1000)
    i_count = 1
    for sentence in sentences:
        i_count += sentence.count("i")

    return calculate_valid_timestamp(now, i_count)

[teadrinker]

Timestamp is used after split_into_sentences() call.

[malcev]

Python code

Code: Select all

def generate_translation_request_data(
    source_language,
    target_language,
    sentences,
    identifier=MAGIC_NUMBER,
    alternatives=1,
    formality_tone=None,
):
    return {
        "jsonrpc": "2.0",
        "method": "LMT_handle_jobs",
        "params": {
            "jobs": generate_jobs(sentences, beams=alternatives),
            "lang": {
                "user_preferred_langs": [target_language, source_language],
                "source_lang_computed": source_language,
                "target_lang": target_language,
            },
            "priority": 1,
            "commonJobParams": generate_common_job_params(formality_tone),
            "timestamp": generate_timestamp(sentences),
        },
        "id": identifier,
    }
    
def calculate_valid_timestamp(timestamp, i_count):
    try:
        return timestamp + (i_count - timestamp % i_count)
    except ZeroDivisionError:
        return timestamp


def generate_timestamp(sentences):
    now = int(time.time() * 1000)
    i_count = 1
    for sentence in sentences:
        i_count += sentence.count("i")

    return calculate_valid_timestamp(now, i_count)

I do not see where You generate valid timestamps.

[teadrinker]

split_into_sentences() doesn't use a timestamp, as I said.

[malcev]

If You run deepl from browser, then the very first post request will be https://w.deepl.com/web?request_type=jsonrpc&il=EN&method=getClientState

[teadrinker]

I see https://www2.deepl.com/jsonrpc?method=LMT_handle_jobs.

[malcev]

Clear, cookies, cache, change ip.
I see
1) https://www.deepl.com/PHP/backend/privacy.php?request_type=jsonrpc&il=EN&method=enableDataUse
2) https://w.deepl.com/web?request_type=jsonrpc&il=EN&method=getClientState
3) https://www2.deepl.com/jsonrpc?method=LMT_split_text
4) https://www2.deepl.com/jsonrpc?method=LMT_handle_jobs ; with generated timestamp
May be deepl developers have changed "LMT_split_into_sentences" to "LMT_split_text" method.

[teadrinker]

Did it, still see https://www2.deepl.com/jsonrpc?method=LMT_handle_jobs as the first request.

[teadrinker]

I meant requests after inserting text into the field, but if i reload the page, requests look like you showed.

[malcev]

Should work something like this.

Code: Select all

StringCaseSense, On
text := "Hello, World! "
id := 12340000
WinHTTP := ComObjCreate("WinHttp.WinHttpRequest.5.1")
loop
{
   WinHTTP.Open("POST", "https://www2.deepl.com/jsonrpc", true)
   WinHTTP.SetRequestHeader("content-type", "application/json")
   WinHTTP.SetRequestHeader("user-agent", "Mozilla/5.0 (Windows NT 10.0; Win64; x64) AppleWebKit/537.36 (KHTML, like Gecko) Chrome/99.0.4844.84 Safari/537.36 OPR/85.0.4341.75")
   id++
   if (Mod(id+3, 13) = 0) or (Mod(id+5, 29) = 0)
      method = "method" :
   else
      method = "method":
   text .= "i"
   StrReplace(text, "i",, i_count)
   i_count++
   timestamp := A_NowUTC
   timestamp -= 19700101000000, S
   timestamp .= A_MSec
   timestamp := timestamp + i_count - Mod(timestamp, i_count)
   json = {"jsonrpc": "2.0", %method% "LMT_handle_texts", "id": %id%, "params": {"texts": [{"text": "%text%", "requestAlternatives": 3}], "splitting": "newlines", "lang": {"target_lang": "DE"}, "timestamp": %timestamp%, "commonJobParams": {"wasSpoken": false}}}
   WinHTTP.Send(json)
   WinHTTP.WaitForResponse()
   msgbox % WinHTTP.responsetext
}

https://www.sobyte.net/post/2022-04/deepl-api/