Seperate string list Topic is solved

[marc873a]

Hello everyone.

I have a txt file with a bunch of different words separated by a newline.
I want to retrieve the words and separate them into variables that contain x amount of the words. Let's just say 10 words per variable. What is the simplest way to do this?

So far I have thist

Code: Select all

FileRead, text, test.txt
text := StrSplit(text, "`n")

What to do now?

Thanks in advance and have a good day:)

[mikeyww]

You can post a sample text file below.

[marc873a]

This is just a text file with numbers from 1 to 300

[mikeyww]

Code: Select all

file         = %A_ScriptDir%\test.txt
wordsPerVar  = 10
var         := []
If !FileExist(file) {
 MsgBox, 48, Error, File not found. Aborting.`n`n%file%
 Return
} Else FileRead, text, %file%
While (text > "") {
 word := StrSplit(text, [" ", "`n"], "`r", rest := wordsPerVar + 1), str := ""
 Loop, %wordsPerVar%
  str .= word[A_Index] " "
 var.Push(Trim(str)), text := word[rest]
 MsgBox,, % "String #" var.Count(), % var[var.Count()]
}

[marc873a]

Thanks!
This is definitely above my AHK coding level but it works perfectly.

I'm wondering what the output variables are?
Like is it var(1), var(2), var(3) etc

[mikeyww]

Code: Select all

MsgBox, % var.1
MsgBox, % var.2
MsgBox, % var.3
Etc.

Explained: Simple arrays

[marc873a]

Perfect. Thanks

[flyingDman]

Or:

Code: Select all

file := A_ScriptDir "\test.txt"
fileread, fl, % file
z  := 10, cnt := 1
while cnt
	fl := strreplace(strreplace(fl,"`r`n", " ",, z-1),"`r`n", "`n",cnt, 1)
msgbox % fl

[AlphaBravo]

another way

Code: Select all

x := 10	;  x amount of the words
n := 1, var:=[]
for i, v in StrSplit(text, "`n", "`r")
	var[ m:=Mod(i, x) ? n : n++] .= v (m ? " " : "")

for i, v in var
	MsgBox % "var." i " = " v