Create hotkey to adjust brightness on specific level Topic is solved

[alf2314]

hello, AHK.
There are several solutions to change display brightness with AHK hotkeys, for example I like this one (it is able to show default "level flyout")

Code: Select all

F6::
  AdjustScreenBrightness(-3)
  Return
  
F7::
  AdjustScreenBrightness(3)
  Return
  
AdjustScreenBrightness(step) {
	static service := "winmgmts:{impersonationLevel=impersonate}!\\.\root\WMI"
	monitors := ComObjGet(service).ExecQuery("SELECT * FROM WmiMonitorBrightness WHERE Active=TRUE")
	monMethods := ComObjGet(service).ExecQuery("SELECT * FROM wmiMonitorBrightNessMethods WHERE Active=TRUE")
	for i in monitors {
		curr := i.CurrentBrightness
		break
	}
	toSet := curr + step
	if (toSet < 10)
		toSet := 10
	if (toSet > 100)
		toSet := 100
	for i in monMethods {
		i.WmiSetBrightness(1, toSet)
		break
	}
	BrightnessOSD()
}
BrightnessOSD() {
	static PostMessagePtr := DllCall("GetProcAddress", "Ptr", DllCall("GetModuleHandle", "Str", "user32.dll", "Ptr"), "AStr", A_IsUnicode ? "PostMessageW" : "PostMessageA", "Ptr")
	 ,WM_SHELLHOOK := DllCall("RegisterWindowMessage", "Str", "SHELLHOOK", "UInt")
	static FindWindow := DllCall("GetProcAddress", "Ptr", DllCall("GetModuleHandle", "Str", "user32.dll", "Ptr"), "AStr", A_IsUnicode ? "FindWindowW" : "FindWindowA", "Ptr")
	HWND := DllCall(FindWindow, "Str", "NativeHWNDHost", "Str", "", "Ptr")
	IF !(HWND) {
		try IF ((shellProvider := ComObjCreate("{C2F03A33-21F5-47FA-B4BB-156362A2F239}", "{00000000-0000-0000-C000-000000000046}"))) {
			try IF ((flyoutDisp := ComObjQuery(shellProvider, "{41f9d2fb-7834-4ab6-8b1b-73e74064b465}", "{41f9d2fb-7834-4ab6-8b1b-73e74064b465}"))) {
				DllCall(NumGet(NumGet(flyoutDisp+0)+3*A_PtrSize), "Ptr", flyoutDisp, "Int", 0, "UInt", 0)
				 ,ObjRelease(flyoutDisp)
			}
			ObjRelease(shellProvider)
		}
		HWND := DllCall(FindWindow, "Str", "NativeHWNDHost", "Str", "", "Ptr")
	}
	DllCall(PostMessagePtr, "Ptr", HWND, "UInt", WM_SHELLHOOK, "Ptr", 0x37, "Ptr", 0)
}

but I failed to find any script that can adjust brightness on specific position, like F6 = 33%, F7 = 66%, F8 = 99%
so instead of adjusting the "step" you just press the key once and get preferred brightness level

Is it possible?

thanks

[mikeyww]

See viewtopic.php?p=365164#p365164.

[alf2314]

greetings, @mikeyww , I appreciate your attention to my question.
Could you please specify what exact post you r reffering to ?
Im asking because as I learnt from here the solution Im looking for is called "jump" parameter.

If my Browser works correctly, from your link Im getting this message

Here's a pretty simple approach using AHk + WMI

Code: Select all

; Variables
Increments 			:= 10 ; < lower for a more granular change, higher for larger jump in brightness 
CurrentBrightness 	:= GetCurrentBrightNess()

; Hot Keys
F6::ChangeBrightness( CurrentBrightness -= Increments ) ; decrease brightness
F7::ChangeBrightness( CurrentBrightness += Increments ) ; increase brightness

; Functions
ChangeBrightness( ByRef brightness, timeout = 1 )
{
	if ( brightness > 0 && brightness < 100 )
	{
		For property in ComObjGet( "winmgmts:\\.\root\WMI" ).ExecQuery( "SELECT * FROM WmiMonitorBrightnessMethods" )
			property.WmiSetBrightness( timeout, brightness )	
	}
 	else if ( brightness >= 100 )
 	{
 		brightness := 100
 	}
 	else if ( brightness <= 0 )
 	{
 		brightness := 0
 	}
}

GetCurrentBrightNess()
{
	For property in ComObjGet( "winmgmts:\\.\root\WMI" ).ExecQuery( "SELECT * FROM WmiMonitorBrightness" )
		currentBrightness := property.CurrentBrightness	

	return currentBrightness
}

I'm sure I had an even easier, less redundant approach before...
If I find it i'll post it...

Anyway hope this helps

and this is nothing common with my question, as I may see.
I also checked every link you mentioned

https://autohotkey.com/board/topic/121999-screen-dimming-via-autohotkey/
https://autohotkey.com/board/topic/83100-laptop-screen-brightness/
https://gist.github.com/krrr/3c3f1747480189dbb71f
https://github.com/hasantr/WinM
https://github.com/tigerlily-dev/tigerlilys-Screen-Dimmer/
https://superuser.com/questions/651706/map-fn-home-to-screen-brightness-using-autohotkey
viewtopic.php?f=83&t=80086
viewtopic.php?p=317763
viewtopic.php?style=1&t=65129&p=279720
viewtopic.php?t=26921&p=126135

and from 1 I actually find out about "jump".
but unfortunatelly none of the scripts are using this, I even have no example how to deal with jump.
All the script s from every topic I found are about making the brightness higher to 5%, 10% etc, or lower, and I cant use any of it because every script which mentions Jump has it set to FALSE, there is no example of script showing how to work with TRUE

[mikeyww]

Code: Select all

changeBrightness(20)
Sleep, 500
changeBrightness(30)
Sleep, 500
changeBrightness(40)
Sleep, 500
changeBrightness(50)
Sleep, 500
changeBrightness(60)

changeBrightness(ByRef brightness, timeout := 1) {
 For property in ComObjGet("winmgmts:\\.\root\WMI").ExecQuery("SELECT * FROM WmiMonitorBrightnessMethods")
  property.WmiSetBrightness(timeout, brightness := Max(0, Min(brightness, 100)))
}

[alf2314]

as I see from this code, the author created 3 types pf brightness, but I dont understand how to run it, what are the hotkeys for 50, for 100
why so much difficult in such simple action

It should. Run this script and it should change it to three brightness levels:

Code: Select all

ChangeBrightness(0)
Sleep, 2000
ChangeBrightness(100)
Sleep, 2000
ChangeBrightness(50)
return

ChangeBrightness( ByRef brightness := 50, timeout = 1 )
{
	if ( brightness >= 0 && brightness <= 100 )
	{
		For property in ComObjGet( "winmgmts:\\.\root\WMI" ).ExecQuery( "SELECT * FROM WmiMonitorBrightnessMethods" )
			property.WmiSetBrightness( timeout, brightness )	
	}
 	else if ( brightness > 100 )
 	{
 		brightness := 100
 	}
 	else if ( brightness < 0 )
 	{
 		brightness := 0
 	}
}

[alf2314]

Code: Select all

changeBrightness(20)
Sleep, 500
changeBrightness(30)
Sleep, 500
changeBrightness(40)
Sleep, 500
changeBrightness(50)
Sleep, 500
changeBrightness(60)

changeBrightness(ByRef brightness, timeout := 1) {
 For property in ComObjGet("winmgmts:\\.\root\WMI").ExecQuery("SELECT * FROM WmiMonitorBrightnessMethods")
  property.WmiSetBrightness(timeout, brightness := Max(0, Min(brightness, 100)))
}

it looks like close to what Im looking for, but how to use it ?

[mikeyww]

Have you run the script to test it? What happens when you run the script?

[alf2314]

Have you run the script to test it? What happens when you run the script?

yes sir, it runs brightness up from 20 to 100 step by step , for about 3 seconds

to 60, Im sorry

[mikeyww]

So you have your answer, right?

Code: Select all

F6::changeBrightness(33)
F7::changeBrightness(66)
F8::changeBrightness(99)

changeBrightness(ByRef brightness, timeout := 1) {
 For property in ComObjGet("winmgmts:\\.\root\WMI").ExecQuery("SELECT * FROM WmiMonitorBrightnessMethods")
  property.WmiSetBrightness(timeout, brightness := Max(0, Min(brightness, 100)))
}

[alf2314]

So you have your answer, right?

Code: Select all

F6::changeBrightness(33)
F7::changeBrightness(66)
F8::changeBrightness(99)

changeBrightness(ByRef brightness, timeout := 1) {
 For property in ComObjGet("winmgmts:\\.\root\WMI").ExecQuery("SELECT * FROM WmiMonitorBrightnessMethods")
  property.WmiSetBrightness(timeout, brightness := Max(0, Min(brightness, 100)))
}

wow
THAT
1) looks simple
2) looks nice
3) it works
4) can be converted easily into .EXE

Thakn you so much ! That is amazing !

what a brilliant code !
thanks , going to work with it. I think this is revolutionary , I cant believe no one posted any similar code before , with such simplicity and without overburden stuff, like ACDC getting info and similar.
Just straight brightness adjustment with nothing excess.

thanks, pure magic

how can anyone mot skilled (like me) get into this monster

Code: Select all

; ----------- Change laptop brightness by an arbitrary step. --------------
; This is an AutoHotKey for increment/decrement the Laptop Monitor Brighnes (Dim Screen) by an arbitary step.
; "CapsLock + Right/Left rrow" Keys is set for changing the screen Dim.
; I tested it on Windows 10. + I'm sure it works on windows 7, too. ---
CapsLock & Right:: 
	DimStep = 5
	; ----------------------------
	DllCall("powrprof\PowerGetActiveScheme", "Ptr", 0, "Ptr*", currSchemeGuid, "UInt")
	VarSetCapacity(GUID_VIDEO_SUBGROUP__, 16)
	NumPut(0x7516B95F, GUID_VIDEO_SUBGROUP__, 0, "UInt"), NumPut(0x4464F776, GUID_VIDEO_SUBGROUP__, 4, "UInt")
	NumPut(0x1606538C, GUID_VIDEO_SUBGROUP__, 8, "UInt"), NumPut(0x99CC407F, GUID_VIDEO_SUBGROUP__, 12, "UInt")
	VarSetCapacity(GUID_DEVICE_POWER_POLICY_VIDEO_BRIGHTNESS__, 16)
	NumPut(0xADED5E82, GUID_DEVICE_POWER_POLICY_VIDEO_BRIGHTNESS__, 0, "UInt"), NumPut(0x4619B909, GUID_DEVICE_POWER_POLICY_VIDEO_BRIGHTNESS__, 4, "UInt")
	NumPut(0xD7F54999, GUID_DEVICE_POWER_POLICY_VIDEO_BRIGHTNESS__, 8, "UInt"), NumPut(0xCB0BAC1D, GUID_DEVICE_POWER_POLICY_VIDEO_BRIGHTNESS__, 12, "UInt")
	schemeGuid := currSchemeGuid
	; ----------------------------
	powerstatusValue := powerstatus()
	if (powerstatusValue = 1) {
		DllCall("powrprof\PowerReadACValueIndex", "Ptr", 0, "Ptr", schemeGuid, "Ptr", &GUID_VIDEO_SUBGROUP__, "Ptr", &GUID_DEVICE_POWER_POLICY_VIDEO_BRIGHTNESS__, "UInt*", currBrightnessAC, "UInt")
		; MsgBox, currBrightnessAC = %currBrightnessAC%
		currBrightness := currBrightnessAC + DimStep
		DllCall("powrprof\PowerWriteACValueIndex", "Ptr", 0, "Ptr", currSchemeGuid, "Ptr", &GUID_VIDEO_SUBGROUP__, "Ptr", &GUID_DEVICE_POWER_POLICY_VIDEO_BRIGHTNESS__, "UInt", currBrightness, "UInt")
	}
	else {
		DllCall("powrprof\PowerReadDCValueIndex", "Ptr", 0, "Ptr", currSchemeGuid, "Ptr", &GUID_VIDEO_SUBGROUP__, "Ptr", &GUID_DEVICE_POWER_POLICY_VIDEO_BRIGHTNESS__, "UInt*", currBrightnessDC, "UInt")
		; MsgBox, currBrightnessDC = %currBrightnessDC%
		currBrightness := currBrightnessDC + DimStep
		DllCall("powrprof\PowerWriteDCValueIndex", "Ptr", 0, "Ptr", currSchemeGuid, "Ptr", &GUID_VIDEO_SUBGROUP__, "Ptr", &GUID_DEVICE_POWER_POLICY_VIDEO_BRIGHTNESS__, "UInt", currBrightness, "UInt")
	}
	DllCall("powrprof\PowerSetActiveScheme", "Ptr", 0, "Ptr", currSchemeGuid, "UInt")
return


CapsLock & Left:: 
	DimStep = 5
	; ----------------------------
	DllCall("powrprof\PowerGetActiveScheme", "Ptr", 0, "Ptr*", currSchemeGuid, "UInt")
	VarSetCapacity(GUID_VIDEO_SUBGROUP__, 16)
	NumPut(0x7516B95F, GUID_VIDEO_SUBGROUP__, 0, "UInt"), NumPut(0x4464F776, GUID_VIDEO_SUBGROUP__, 4, "UInt")
	NumPut(0x1606538C, GUID_VIDEO_SUBGROUP__, 8, "UInt"), NumPut(0x99CC407F, GUID_VIDEO_SUBGROUP__, 12, "UInt")
	VarSetCapacity(GUID_DEVICE_POWER_POLICY_VIDEO_BRIGHTNESS__, 16)
	NumPut(0xADED5E82, GUID_DEVICE_POWER_POLICY_VIDEO_BRIGHTNESS__, 0, "UInt"), NumPut(0x4619B909, GUID_DEVICE_POWER_POLICY_VIDEO_BRIGHTNESS__, 4, "UInt")
	NumPut(0xD7F54999, GUID_DEVICE_POWER_POLICY_VIDEO_BRIGHTNESS__, 8, "UInt"), NumPut(0xCB0BAC1D, GUID_DEVICE_POWER_POLICY_VIDEO_BRIGHTNESS__, 12, "UInt")
	schemeGuid := currSchemeGuid
	; ----------------------------
	powerstatusValue := powerstatus()
	if (powerstatusValue = 1) {
		DllCall("powrprof\PowerReadACValueIndex", "Ptr", 0, "Ptr", schemeGuid, "Ptr", &GUID_VIDEO_SUBGROUP__, "Ptr", &GUID_DEVICE_POWER_POLICY_VIDEO_BRIGHTNESS__, "UInt*", currBrightnessAC, "UInt")
		; MsgBox, currBrightnessAC = %currBrightnessAC%
		currBrightness := currBrightnessAC - DimStep
		DllCall("powrprof\PowerWriteACValueIndex", "Ptr", 0, "Ptr", currSchemeGuid, "Ptr", &GUID_VIDEO_SUBGROUP__, "Ptr", &GUID_DEVICE_POWER_POLICY_VIDEO_BRIGHTNESS__, "UInt", currBrightness, "UInt")
	}
	else {
		DllCall("powrprof\PowerReadDCValueIndex", "Ptr", 0, "Ptr", currSchemeGuid, "Ptr", &GUID_VIDEO_SUBGROUP__, "Ptr", &GUID_DEVICE_POWER_POLICY_VIDEO_BRIGHTNESS__, "UInt*", currBrightnessDC, "UInt")
		; MsgBox, currBrightnessDC = %currBrightnessDC%
		currBrightness := currBrightnessDC - DimStep
		DllCall("powrprof\PowerWriteDCValueIndex", "Ptr", 0, "Ptr", currSchemeGuid, "Ptr", &GUID_VIDEO_SUBGROUP__, "Ptr", &GUID_DEVICE_POWER_POLICY_VIDEO_BRIGHTNESS__, "UInt", currBrightness, "UInt")
	}
	DllCall("powrprof\PowerSetActiveScheme", "Ptr", 0, "Ptr", currSchemeGuid, "UInt")
return


; ----  sub functions --------
powerstatus() {
	VarSetCapacity(powerstatus, 1+1+1+1+4+4)
	success := DllCall("kernel32.dll\GetSystemPowerStatus", "uint", &powerstatus)

	acLineStatus:=ReadInteger(&powerstatus,0,1,false)
	batteryFlag:=ReadInteger(&powerstatus,1,1,false)
	batteryLifePercent:=ReadInteger(&powerstatus,2,1,false)
	batteryLifeTime:=ReadInteger(&powerstatus,4,4,false)
	batteryFullLifeTime:=ReadInteger(&powerstatus,8,4,false)

	output=AC Status: %acLineStatus%`nBattery Flag: %batteryFlag%`nBattery Life (percent): %batteryLifePercent%`nBattery Life (time): %batteryLifeTime%`nBattery Life (full time): %batteryFullLifeTime%
	; MsgBox, %output%
	return acLineStatus
}
ReadInteger( p_address, p_offset, p_size, p_hex=true )
{
  value = 0
  old_FormatInteger := a_FormatInteger
  if ( p_hex )
	SetFormat, integer, hex
  else
	SetFormat, integer, dec
  loop, %p_size%
	value := value+( *( ( p_address+p_offset )+( a_Index-1 ) ) << ( 8* ( a_Index-1 ) ) )
  SetFormat, integer, %old_FormatInteger%
  return, value
}
; -------------------------- End -------------------------

and now compare it to ths solution here.
thats phenomenal
I so enjoy using it, it works superbly