Merging arrays question

[sinkfaze]

I'm having trouble conceptualizing the method to accomplish this. I have two arrays, one with values only and one with arrays of values. I need to merge these into the array of values only in their intended sequential order. So for example:

Code: Select all

Arr1 :=	[1,4,7]
Arr2 :=	[[2,3],[5,6],[8,9,10]]

Arr1 should become:

Code: Select all

Arr1 :=	[1,2,3,4,5,6,7,8,9,10]

Just to clarify, I'm not asking how to push all of the data to Arr1 and sort it, the numbers are just stand ins for data that needs to be ordered in the new array. For example, the data at [8,9,10] in Arr2 is related to the data at 7 in Arr1, [5,6] to 4, etc.

My original thought was to reverse the order of Arr2 [[8,9,10],[5,6],[2,3]] and insert the values into Arr1 from back to front, but I'm stalling on that method. Any help is greatly appreciated.

[teadrinker]

Why not like this:

Code: Select all

Arr1 :=	[1,4,7]
Arr2 :=	[[2,3],[5,6],[8,9,10]]

offset := 2
Loop % Arr1.Count() {
   Arr1.InsertAt(offset, Arr2[A_Index]*)
   offset += Arr2[A_Index].Count() + 1
}

[swagfag]

Code: Select all

Arr1 :=	[1,4,7]
Arr2 :=	[[2,3],[5,6],[8,9,10]]

Arr3 := []
for i, e in Arr1
	Arr3.Push(e, Arr2[i]*)

Arr1 := Arr3

[teadrinker]

Arr3 := []

What if arr 4GB ?

[swagfag]

what if what

[teadrinker]

You are creating an extra object, where it's unnecessary. This is a waste of memory, if arrays are large, it might matter.

[swagfag]

u dont say.

i dont see "oh and keep the memory footprint low" anywhere in the requirements. why arent u deleting from Arr2 then?

[teadrinker]

why arent u deleting from Arr2 then?

An initial object mustn't be changed unless this clearly required.

i dont see "oh and keep the memory footprint low" anywhere in the requirements

Well, in programming it's usually required by default. If there is an opportunity not to incur additional costs, it is better not to do this.

[swagfag]

hear! hear! the Arbiter of Programming descends upon to enlighten us whats required, what isnt, whats necessary and what isnt, what should be done and what shouldnt!

An initial object mustn't be changed unless this clearly required.

says who? you? what happened to ur being overly concerned about memory?

Well, in programming it's usually required by default.

says who? you? and here i was thinking what was required in programming was to solve the problem

If there is an opportunity not to incur additional costs, it is better not to do this.

says who? you? how do u know its going to incur additional costs?

get off ur high horse already. only OP knows the requirements

[teadrinker]

I think you need to calm down a bit.

[Chunjee]

Just to clarify, I'm not asking how to push all of the data to Arr1 and sort it, the numbers are just stand ins for data that needs to be ordered in the new array. For example, the data at [8,9,10] in Arr2 is related to the data at 7 in Arr1, [5,6] to 4, etc.

I call that a zip, not a merge. how I would do it:

Code: Select all

A := new biga() ; requires https://github.com/biga-ahk/biga.ahk

Arr1 := [1,4,7]
Arr2 := [[2,3],[5,6],[8,9,10]]

Arr3 := A.flattenDeep(A.zip(Arr1, Arr2))
; => [1, 2, 3, 4, 5, 6, 7, 8, 9, 10]

https://biga-ahk.github.io/biga.ahk/#/?id=zip
https://biga-ahk.github.io/biga.ahk/#/?id=flattendeep

[malcev]

teadrinker, compare:

Code: Select all

setbatchlines -1
loop 2
{
   Arr1 := [], Arr2 := []
   loop 100000
   {
      Arr1.Push(A_Index)
      Arr2.Push([A_Index, A_Index])
   }
   a := a_tickcount
   if (A_Index = 1)
   {
      offset := 2
      Loop % Arr1.Count() {
         Arr1.InsertAt(offset, Arr2[A_Index]*)
         offset += Arr2[A_Index].Count() + 1
      }
   }
   else
   {
      Arr3 := []
      for i, e in Arr1
         Arr3.Push(e, Arr2[i]*)
      Arr1 := Arr3
   }
   speed%A_Index% := a_tickcount - a
}
msgbox % speed1 "`n" speed2

[teadrinker]

Yes, Push() is faster than InsertAt(), I don't say this is not true.

[malcev]

Doesn`t that mean if arrays are large swagfag`s code is better?

[teadrinker]

Not necessary. It depends what is in priority, speed, or memory consumption. It takes about one and a half times more memory.

[teadrinker]

Code: Select all

setbatchlines -1
loop 2
{
   Arr1 := [], Arr2 := []
   loop 10000
   {
      Arr1.Push(A_Index)
      Arr2.Push([A_Index, A_Index, A_Index, A_Index, A_Index, A_Index, A_Index, A_Index, A_Index, A_Index])
   }
   a := a_tickcount
   if (A_Index = 1)
   {
      offset := 2
      Loop % Arr1.Count() {
         Arr1.InsertAt(offset, Arr2[A_Index]*)
         offset += Arr2[A_Index].Count() + 1
      }
   }
   else
   {
      Arr3 := []
      for i, e in Arr1
         Arr3.Push(e, Arr2[i]*)
      Arr1 := Arr3
   }
   speed%A_Index% := a_tickcount - a
}
msgbox % speed1 "`n" speed2