Add Part of Folder Name to File Name Topic is solved

[cjsmile999]

Hello everyone! I'm trying to rename the files within each folder with part of the folder name they reside in. Example grab the artist last name from the folder and add that to end of each of the files within that folder: Waiting on the World to Change_Mayer.mp3, ect... Below is a simple example of the file structure.

Current Setup:
Music (folder)
Continuum_John_Mayer_2006 (Folder)
Waiting on the World to Change.mp3
Belief.mp3
Vultures.mp3
Just a Little Love_Reba_McEntire_1984 (Folder)
Just a little love.mp3
Poison Sugar.mp3
If Only.mp3
Ect....

Proposed Setup:
Music (folder)
Continuum_John_Mayer_2006 (Folder)
Waiting on the World to Chance_Mayer.mp3
Belief_Mayer.mp3
Vultures_Mayer.mp3
Just a Little Love_Reba_McEntire_1984 (Folder)
Just a little love_McEntire.mp3
Poison Sugar_McEntire.mp3
If Only_McEntire.mp3
Ect....

I've been able to work out creating a list of folders and parse out section (last name) that I need. What I can't figure out is how to loop through that list and take last name and add it to the end of each file within that corresponding folder.

Code: Select all

FileList := "" 
Path := "E:\Music\*"

;msgbox, %path%
Loop, Files, %Path%, D 
    FileList .= A_LoopFileFullPath "`n"
msgbox, % FileList

Loop, parse, FileList, `n
{

	if (A_LoopField = "")  ; Ignore the blank item at the end of the list.
        continue
	SplitName := StrSplit(A_LoopField, "_") ; Omits periods.
	MsgBox % SplitName[3]
    MsgBox, 4,, File number %A_Index% is %A_LoopField%.  Continue?
    IfMsgBox, No
        break
}

[mikeyww]

Code: Select all

dir := StrReplace(A_Desktop, "Desktop", "Music")
Loop, Files, %dir%\*, D
{ If !Instr(sub := A_LoopFilePath, "_")
   Continue
  part := StrSplit(sub, "_"), artist := part[part.Count() - 1]
  Loop, Files, %sub%\*.*
  { SplitPath, A_LoopFilePath,,, ext, fnBare
    FileMove, %A_LoopFilePath%, %sub%\%fnBare%_%artist%.%ext%
  }
}
MsgBox, 64, Done, Done!

[flyingDman]

@mikeyww do you mean part := StrSplit(sub, "\")?

[mikeyww]

No. The folder example is Continuum_John_Mayer_2006. The file path given by sub is a directory path. After the split, the artist is found by looking for the part that is next to last. The array element number is the element count minus one.

[flyingDman]

I stand corrected. I misread.

[cjsmile999]

Thank you! Works like a champ!!! I'm amazed how helpful everyone is and taking the time to teach us! Hats off to you all, and thank you!