Paste a saved image into a document

[gyro2222]

i've been trying to load a jpg image into the clipboard to paste into a document.
for example, past my signature into a word document without using word macros

I tried to save and load a captured area to a file and then load it. However, now every time I do a partial screen capture it overwrites the prior clip file, even without autohotkey running.

I'd love something simple. Basically insert c:\signature.jpg at cursor
suggestions?
Thanks,
Hal


Here's the code I had from another users suggestion:

Code: Select all

;USE THIS TO SAVE A CLIPBOARD IMAGE TO A FILE TO USE FOR PASTING WITH 2ND SCRIPT FOLLOWING THIS
;FIRST COPY AN IMAGE TO CLIPBOARD USING SNIPING TOOL ETC
#!'::        
;  win alt'
#Persistent

OnClipboardChange:
 if(A_EventInfo=2)   ; if the Clipboard contains images
{
;FileDelete, C:\image saved.clip
ToolTip image saved
FileAppend, %ClipboardAll%, d:\dropbox\_SIGNATURE FILES\CLIPautohotkey\MailSignOff.clip	  ; save image
Sleep 1000
ToolTip
}
return



;USE THIS TO LOAD & PASTE MailSignOFF TO CLIPBOARD 
;THIS ONE IS E-MAIL SIGNOFF
#+/::
 ; win-shft/
;ClipSaved := ClipboardAll
;Clipboard =
FileRead, Clipboard, *c d:\dropbox\_SIGNATURE FILES\CLIPautohotkey\MailSignoff.clip
ClipWait, 2
Send ^v
;clipboard := ClipSaved
return

[Mod edit: [code][/code] tags added]

[Scr1pter]

Hi,

I made something similar a while ago, by using gdip:

Code: Select all

#SingleInstance force
#include Gdip_All.ahk

F1::
picturePath = C:\Users\USER\Documents\AHK\picture.png ; Path to picture
Read_In_Picture(picturePath) ; Grafik in die Zwischenablage kopieren 
return

Read_In_Picture(picture)
{
  pToken := Gdip_Startup() ; Gdip-Instanz starten
  pBitmap := Gdip_CreateBitmapFromFile(picture) ; Grafik definieren
  Gdip_SetBitmapToClipboard(pBitmap) ; Grafik in die Zwischenablage kopieren PICTURE TO CLIPBOARD
  Gdip_DisposeImage(pBitmap) ; Grafiken aus Speicher entfernen
  Gdip_Shutdown(pToken) ; Gdip-Instanz schließen
}

After using that function, you should just paste the picture.
It should also work with jpg, but perhaps you can switch to png?

Cheers!

[flyingDman]

Basically insert c:\signature.jpg at cursor

Try:

Code: Select all

oWord := ComObjActive("Word.Application")
oWord.ActiveDocument.Shapes.AddPicture("c:\signature.jpg")

[teadrinker]

Code: Select all

OnClipboardChange:
if(A_EventInfo=2)   ; if the Clipboard contains images
{
FileDelete, d:\dropbox\_SIGNATURE FILES\CLIPautohotkey\MailSignOff.clip
ToolTip image saved
FileAppend, %ClipboardAll%, d:\dropbox\_SIGNATURE FILES\CLIPautohotkey\MailSignOff.clip
Sleep 1000
ToolTip
}
return 

#+/::
if !Word := GetActiveWord() {
   MsgBox, Failed to get active Word document
   Return
}
FileRead, Clipboard, *c d:\dropbox\_SIGNATURE FILES\CLIPautohotkey\MailSignOff.clip
Word.Selection.PasteSpecial()
Return

GetActiveWord()  {
   ControlGet, ControlHwnd, Hwnd,, _WwG1, % "ahk_id" WinExist("A")
   Return AccObjectFromWindow(ControlHwnd, -16).Application
}

AccObjectFromWindow(hWnd, idObject = 0)
{
   static IID_IDispatch   := "{00020400-0000-0000-C000-000000000046}"
        , IID_IAccessible := "{618736E0-3C3D-11CF-810C-00AA00389B71}"
        , OBJID_NATIVEOM  := 0xFFFFFFF0, VT_DISPATCH := 9, F_OWNVALUE := 1
        , h := DllCall("LoadLibrary", Str, "oleacc", Ptr)
        
   VarSetCapacity(IID, 16), idObject &= 0xFFFFFFFF
   DllCall("ole32\CLSIDFromString", Str, idObject = OBJID_NATIVEOM ? IID_IDispatch : IID_IAccessible, Ptr, &IID)
   if DllCall("oleacc\AccessibleObjectFromWindow", Ptr, hWnd, UInt, idObject, Ptr, &IID, PtrP, pAcc) = 0
      Return ComObjEnwrap(VT_DISPATCH, pAcc, F_OWNVALUE)
}

[submeg]

Hi,

I made something similar a while ago, by using gdip:

Code: Select all

#SingleInstance force
#include Gdip_All.ahk

F1::
picturePath = C:\Users\USER\Documents\AHK\picture.png ; Path to picture
Read_In_Picture(picturePath) ; Grafik in die Zwischenablage kopieren 
return

Read_In_Picture(picture)
{
  pToken := Gdip_Startup() ; Gdip-Instanz starten
  pBitmap := Gdip_CreateBitmapFromFile(picture) ; Grafik definieren
  Gdip_SetBitmapToClipboard(pBitmap) ; Grafik in die Zwischenablage kopieren PICTURE TO CLIPBOARD
  Gdip_DisposeImage(pBitmap) ; Grafiken aus Speicher entfernen
  Gdip_Shutdown(pToken) ; Gdip-Instanz schließen
}

After using that function, you should just paste the picture.
It should also work with jpg, but perhaps you can switch to png?

Cheers!

Hey @Scr1pter, I tried this, but when I press CTRL + V to paste, it says "the information on the clipboard can't be inserted into Paint."

My script is identical to yours:

Code: Select all

#SingleInstance force
#include C:\Users\PATH\AutoHotkey\Lib\Gdip_All.ahk

a::

PM_IconWaiting()

Return


PM_IconWaiting()
{

picturePath = C:\Users\PATH\AutoHotkey\Lib\Icons\JS_InfoWait.png

Read_In_Picture(picturePath) ; Grafik in die Zwischenablage kopieren 

}
Return

Read_In_Picture(picturePath)
{
  pToken := Gdip_Startup() ; Gdip-Instanz starten
  pBitmap := Gdip_CreateBitmapFromFile(picture) ; Grafik definieren
  Gdip_SetBitmapToClipboard(pBitmap) ; Grafik in die Zwischenablage kopieren PICTURE TO CLIPBOARD
  Gdip_DisposeImage(pBitmap) ; Grafiken aus Speicher entfernen
  Gdip_Shutdown(pToken) ; Gdip-Instanz schließen
}

Any ideas?

[ananthuthilakan]

Code: Select all

#include ImagePut (for v1).ahk ; https://github.com/iseahound/ImagePut
picturePath := "C:\Users\USER\Documents\AHK\picture.png"

F1::
ImagePutClipboard({image: picturePath, scale: ["500", "auto"]}) ; scale for width and height
; ImagePutClipboard(picturePath)  ; no scaling
sleep, 50
SendInput, ^{v}
return