Commandline Zip - progressbar - logfile - 7z or 7zG Topic is solved

[Smile_]

Have to look at it. The only thing is that you should add an error handling - if someone has opened and locked one of the result files and this should be handled differently, it can be a bit tricky to handle with a loop.

If you mean about editing the script, just compile it, AHK script -> Standalone Executable.

Found an "error" in this test code (mtee /+ "c:\temp\InfoFile.txt") must in this case be (mtee "c:\temp\InfoFile.txt")

What error?

Is it possible - instead of redirecting the result to a file - redirecting the result to a variable - but it may be another question.

You wanted to show the result on CMD window and append it to log file and you got that, in CMD commands it is possible to redirect the output into variable but it gonna make the CMD blank, at the moment I D K clear way to do that, it is not so important I think.

Improvement suggestion:
1 - You display the error output inside notepad, I think if you display it in Msgbox like the last MsgBox would be better and make Error sound when message displayed with an Error Icon.
You can find more here https://www.autohotkey.com/docs/commands/MsgBox.htm
2 - The script doesn't use GUI interface, why you don't add one, better graphics and smoother to use and more clearer.
That GUI let the user choose the compressor executable and files to compress or folders and name of file to compress into... etc.
Plus a log box inside the GUI display the user what is happening for example if the program compressing, it displaying " Compressing Squid2 into 7zipSquid.7z ... (Size 100 MB) ".
Plus the other stuffs buttons, and texts ...

[Albireo]

Found an "error" in this test code (mtee /+ "c:\temp\InfoFile.txt") must in this case be (mtee "c:\temp\InfoFile.txt")
/+ Requires that the zip file (result file) already exists. (does not always occur).

---

7-zip compress as function() in AHK (Swedish version)

Code: Select all

; Version 12 maj 2020
#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.

SetBatchLines -1  ; Kör programmet så fort som möjligt
#SingleInstance Force	; Endast "ett" program kan köras samtiodigt

; Förbättringar
; Hantera logfil information
; Sänd return med kör information

Support = Kalle Ohlsson

FromFile := "c:\temp\*.csv"
; FromFile := "c:\temp\OutletFTP"
; FromFile := "c:\Squid2\"
ToFile := "c:\Test Temp\TestOutlet.7z"
InfoFile := "c:\Test Temp\7-ZipResultOut.txt"
ErrLogFile := "c:\Test Temp\7zipErrorOut.log"

FuncZip(FromFile, ToFile, InfoFile, ErrLogFile, "3", "hide")
; FuncZip(FromFile, ToFile, InfoFile, ErrLogFile, "1")
; FuncZip(FromFile, ToFile, InfoFile, ErrLogFile)

; FuncUnZip(SourceFile, ToFile, InfoFile)

MsgBox ,, Rad %A_LineNumber% -> %A_ScriptName%, Klart!

ExitApp



FuncZip(SourceFile, ToZip, InfoFile, ErrFile, CompLevel := 5, vShow := "")
{	; Version 11 maj 2020
	; Utvecklat tillsammans med
	; Commandline Zip - progressbar - logfile - 7z or 7zG Topic is solved
	; https://www.autohotkey.com/boards/viewtopic.php?f=76&t=75647&p=327782#p327782
	; - SourceFile		- De filer / katalog(er) som ska komprimeras
	; - ToZip			- Filnamnet på den komprimerade filen
	; - InfoFile		- Information om komprimeringen
	; - ErrFile			- Eventuella felmeddelanden (oftast låsta filer)
	; - CompLevel		- Ang kompressionsgrad av filer 0=ingen 1,3,5,7,9=max
	;
	; Initiera sökvägar för
	; - Variabler
	; - Program
	; - Filer
	;
	; Kontrollera att exe-filer finns på rätt ställe
	; - 7z.exe
	; - Mtee.exe
	;
	; Radera tidigare resultatfiler
	; - ToZip
	; - InfoFile
	; - ErrFile
	;
	; Skapa zipfil
	; Hantera felkoder
	; 
	; Radera ErrFile om den är tom (skapas alltid - även om innehåll saknas)
	;
	; Läs in Resultatfil
	; Radera Resultatfil
	; Skriv tillbaka resultatfilen (med kompletterade uppgifter)
	; - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - 
	; Förbättringar?
	; Returnera Körinformation från funktionen (som tid, datum, program, arkiv mm.) - användare?
	; Skapa en renare resultatfil genom att köra "test" efter att filen har packats?
	;
	
	Global Support
	
	
	; Initiera
	PassWd := "AHK_HighSecure_Web"
	WorkPath := "c:\Temp"

	StartTime := A_TickCount
	StartErr := False		; Felhantering

	; Kontrollera att lösenordet inte innehåller "blanksteg"
	If InStr(PassWd, A_Space)
	{	MsgBox 16, Rad %A_LineNumber% -> %A_ScriptName%,
		( LTrim 
		 % "Felaktigt lösenord! `n
			Lösenord får inte innehålla 'blanksteg'! 
			(Önskat lösenord .: " PassWd " )`n
			Kontakta .: " Support "`n
			Detta program avslutas!"
		)
		ExitApp
	}

	; Zip - program
	exePath := "C:\Program Files\7-Zip"
	exeProg := "7z.exe"
	; exeProg := "7za.exe"
	; exeProg := "7zG.exe"
	exeFile := exePath "\" exeProg
	
	; Split program (Unix tee)
	TeePath := "C:\Program Files\7-Zip"
	TeeProg := "Mtee.exe"	; Avancerat program med många möjligheter
	; TeeProg := "PipeSplit"	; Enklare Split-program
	TeeFile := TeePath "\" TeeProg
	
	; Kontrollera giltig kompressionsnivå 	
	if CompLevel not in 0,1,3,5,7,9
	{	MsgBox 16, Rad %A_LineNumber% -> %A_ScriptName%,
		( LTrim 
		 % "Fel kompressionsnivå! `n
			Vald kompressionsnivå .: " CompLevel "
			(Giltiga kompressionsnivåer .: 1,3,5,7,9)`n
			Kontakta .: " Support "`n
			Detta program avslutas!"
		)
		ExitApp
	}
	
	; 1a) Kontrollera att 7z.exe finns installerad
	; exePath := "C:\Program Files (x86)"	; Äldre version
	If !FileExist(exeFile)
	{	MsgBox 16, Rad %A_LineNumber% -> %A_ScriptName%,
		( LTrim 
		 % "Zip-program saknas! `n
			Program .: " exeProg "
			Sökväg .: " exePath "`n
			Kontakta .: " Support "
			(Finns programmet 7-zip installerat?)`n
			Detta program avslutas!"
		)
		ExitApp
	}
	
	; 1b) Kolla att Mtee.exe finns ( PipeSplit.exe (tee) existerar )
	If !FileExist(TeeFile)
	{	SplitPath TeeFile, OutFileName, OutDir,, OutNameNoExt
		If !OutNameNoExt
			OutNameNoExt := "Förväntad fil .: Mtee.exe"
		else
			OutNameNoExt := "Finns programmet .: " OutNameNoExt "?"
		If !OutFileName
			OutFileName := "Saknas!"
		If !OutDir
			OutDir := "Saknas!"
		MsgBox 16, Rad %A_LineNumber% -> %A_ScriptName%,
		( LTrim
		 % "Split-program (tee) saknas! `n
			Program .: " OutFileName "
			Sökväg .: " OutDir "
			( " OutNameNoExt " )`n
			Kontakta .: " Support "`n
			Detta program avslutas!"
		)
		ExitApp
	}	
	
	
	; - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
	; 2a) - Saknas resultatkatalog - skapa!
	SplitPath InfoFile, InfoFileName, InfoDir	
	If !FileExist(InfoDir "\*.*")
	{	MsgBox 20, Rad %A_LineNumber% -> %A_ScriptName%,
		( LTrim 
		 %	"Nedanstående katalog saknas! (Dit filer önskas packas upp)`n
			Katalognamn .: `n`t" InfoDir "`n
			Skall katalogen ovan skapas?"
		)
		IfMsgBox Yes
		{	FileCreateDir %InfoDir%
			If ErrorLevel
			{	MsgBox 16, Rad %A_LineNumber% -> %A_ScriptName%,
				( LTrim 
				 %	"Okänt fel! `n
					Misslyckades att skapa katalog!`n
					Katalognamn .: " InfoDir "`n
					Kontakta .: " Support "`n
					Detta program avslutas!"
				)
				ExitApp
			}
			; Kolla att katalogen verkligen skapades
			If !FileExist(InfoDir)
			{	MsgBox 20, Rad %A_LineNumber% -> %A_ScriptName%,
				( LTrim 
				 %	"Katalog saknas fortfarande!
					(Dit filer önskas packas upp)`n
					Katalognamn .: " InfoDir "`n
					Kontakta .: " Support "`n
					Detta program avslutas!"
				)
				ExitApp
			}
		}
		else
		{	MsgBox 16, Rad %A_LineNumber% -> %A_ScriptName%,
			( LTrim 
				Ingen katalog skapades! `n
				Detta program avslutas! `n
			), 3
			ExitApp
		}
	}
	; Om resultatfil existerar - Radera!
	If FileExist(InfoFile)	; Radera informationsfil
	{	FileDelete %InfoFile%
		If ErrorLevel
		{	MsgBox 16, Rad %A_LineNumber% -> %A_ScriptName%,
			( LTrim 
			 %	"Informationsfil kunde inte raderas! `n
				Namn .: " InfoFileName "
				Sökväg .: " InfoDir "`n
				(förmodligen låst av annat program)
				Kontakta .: " Support "`n
				Detta program avslutas!"
			)
			ExitApp
		}
	}
	; - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^
	

	; - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -
	; 2b) - Saknas Errorlogkatalog - skapa!	
	SplitPath ErrFile, ErrFileName, ErrDir	
	If !FileExist(ErrDir "\*.*")
	{	MsgBox 20, Rad %A_LineNumber% -> %A_ScriptName%,
		( LTrim 
		 %	"Katalog Saknas!
			(Dit filer önskas packas upp)`n
			Katalognamn .: " ErrDir "`n
			Skall katalogen ovan skapas?"
		)
		IfMsgBox Yes
		{	FileCreateDir %ErrDir%
			If ErrorLevel
			{	MsgBox 16, Rad %A_LineNumber% -> %A_ScriptName%,
				( LTrim 
				 %	"Okänt fel! `n
					Misslyckades att skapa katalog!`n
					Katalognamn .: " ErrDir "`n
					Kontakta .: " Support "`n
					Detta program avslutas!"
				)
				ExitApp
			}
			; Kolla att katalogen verkligen skapades
			If !FileExist(ErrDir)
			{	MsgBox 20, Rad %A_LineNumber% -> %A_ScriptName%,
				( LTrim 
				 %	"Katalog saknas fortfarande!
					(Dit filer önskas packas upp)`n
					Katalognamn .: " ErrDir "`n
					Kontakta .: " Support "`n
					Detta program avslutas!"
				)
				ExitApp
			}
		}
		else
		{	MsgBox 16, Rad %A_LineNumber% -> %A_ScriptName%,
			( LTrim 
				Ingen katalog skapades! `n
				Detta program avslutas! `n
			), 3
			ExitApp
		}
	}	
	; Om ErrorLog existerar - Radera!
	If FileExist(ErrFile)
	{	FileDelete %ErrFile%
		If ErrorLevel
		{	MsgBox 16, Rad %A_LineNumber% -> %A_ScriptName%,
			( LTrim 
			 %	"Fil, ev. med felmmeddelanden kunde inte raderas! `n
				Namn .: " ErrFileName "
				Sökväg .: " ErrDir "`n
				(förmodligen låst av annat program)
				Kontakta .: " Support "`n
				Detta program avslutas!"
			)
			ExitApp
		}
	}
	; - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^
	
	; - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - - -		
	; 2c) - Saknas zipkatalog - skapa!
	SplitPath ToZip, ZipFileName, ZipDir	
	If !FileExist(ZipDir "\*.*")
	{	MsgBox 20, Rad %A_LineNumber% -> %A_ScriptName%,
		( LTrim 
		 %	"Katalog Saknas!
			(Dit filer önskas packas upp)`n
			Katalognamn .: " ZipDir "`n
			Skall katalogen ovan skapas?"
		)
		IfMsgBox Yes
		{	FileCreateDir %ZipDir%
			If ErrorLevel
			{	MsgBox 16, Rad %A_LineNumber% -> %A_ScriptName%,
				( LTrim 
				 %	"Okänt fel! `n
					Misslyckades att skapa katalog!`n
					Katalognamn .: " ZipDir "`n
					Kontakta .: " Support "`n
					Detta program avslutas!"
				)
				ExitApp
			}
			; Kolla att katalogen verkligen skapades
			If !FileExist(ZipDir)
			{	MsgBox 20, Rad %A_LineNumber% -> %A_ScriptName%,
				( LTrim 
				 %	"Katalog saknas fortfarande!
					(Dit filer önskas packas upp)`n
					Katalognamn .: " ZipDir "`n
					Kontakta .: " Support "`n
					Detta program avslutas!"
				)
				ExitApp
			}
		}
		else
		{	MsgBox 16, Rad %A_LineNumber% -> %A_ScriptName%,
			( LTrim 
				Ingen katalog skapades! `n
				Detta program avslutas! `n
			), 3
			ExitApp
		}
	}	
	
	; Om zipfil (som försöker skapas) existerar - Radera
	If FileExist(ToZip)
	{	FileDelete %ToZip%
		If ErrorLevel
		{	SplitPath ToZip, ZipFileName, ZipDir
			MsgBox 16, Rad %A_LineNumber% -> %A_ScriptName%,
			( LTrim 
			 %	"Resultat-zip kunde inte raderas! `n
				Namn .: " ZipFileName "
				Sökväg .: " ZipDir "`n
				(förmodligen låst av annat program)
				Kontakta .: " Support "`n
				Detta program avslutas!"
			)
			ExitApp
		}
	}
	; - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^ - ^
	
	
	; Manual - online - https://sevenzip.osdn.jp/chm/cmdline/index.htm
	; -w 			- Arbetskatalog under körning
	; -t7z 		- Anger vilket pack-format filen ska packas i (här 7z)
	; -stl		- Sätter tid och datum på zip-fil till tid och datum på den senast modifierade filen i arkivet
	; -spf		- Skriver hela sökvägen i logfilerna
	; -mx=1		- Komprimeringsmetod 0=ingen 1=lägst (1,3,5,7,9)
	; -p			- Sätta Password på filen
	; -mhe=on	- Krypterar även filnamnen i den packade filen (fungerar inte med zip-filer)
	; -scsUTF-8	- Mjlighgör en logfil i UTF-8 format - för att visa åäö i logfilen (även efter ex. PipeSplit)
	; -sccUTF-8 - Skapar en logfil i UTF-8 format (för att visa åäö i logfilen)
	; -bb3		- Anger vilken information som ska ingå
	; -bsp1		- Progress informationen skickas till "kanal 1"
	; -bso1		- Output skickas till "kanal 1"
	; -bse2	 	- Felmeddelanden (error) skickas till "kanal 2"
	RunArgs := " a -w" WorkPath " -t7z -stl -spf -mx=" CompLevel " -p" PassWd " -mhe=on -scsUTF-8 -sccUTF-8 -bb3 -bsp1 -bso1 -bse2 "
	RunWait %comspec% /c ""%exeFile%" %RunArgs% "%ToZip%" "%SourceFile%" 2> "%ErrFile%" | "%TeeFile%" "%InfoFile%"",, UseErrorLevel %vShow%, ZipPID
	If ( ErrorLevel = 1 )
	{	StatErr := True
		MsgBox 16, Rad %A_LineNumber% -> %A_ScriptName%,
		( LTrim 
		 %	"Varning! (Exit kod .: " ErrorLevel ")
			Inte allvarligt fel`n
			Till exempel,
			En eller flera filer låstes av något annat program.
			De kommer inte att komprimeras."
		)
	}
	If ( ErrorLevel = 2 )
	{	MsgBox 16, Rad %A_LineNumber% -> %A_ScriptName%,
		( LTrim
		 %	"Alvarligt fel! (Exit kod .: " ErrorLevel ")`n
			Kontakta .: " Support "`n
			Detta program avslutas!"
		)
		ExitApp
	}
	If ( ErrorLevel = 7 )
	{	MsgBox 16, Rad %A_LineNumber% -> %A_ScriptName%,
		( LTrim 
		 %	"Command line - problem!
			`t(Exit kod .: " ErrorLevel ")`n
			Kontakta .: " Support "`n
			Detta program avslutas!"
		)
		ExitApp
	}
	If ( ErrorLevel = 8 )
	{	MsgBox 16, Rad %A_LineNumber% -> %A_ScriptName%,
		( LTrim 
		 %	"Minne saknas för drift!
			`t(Exit kod .: " ErrorLevel ")`n
			Kontakta .: " Support "`n
			Detta program avslutas!"
		)
		ExitApp
	}
	If ( ErrorLevel = 255 )
	{	MsgBox 16, Rad %A_LineNumber% -> %A_ScriptName%,
		( LTrim 
		 %	"Processen avbröts av användaren!
			`t(Exit kod .: " ErrorLevel ")`n
			(Kan inträffa ifall programmet Mtee har fel struktur - sökväg saknas?)
			(Kan inträffa ifall lösenordet har ogiltiga tecken)
			(Kan inträffa ifall resultatkatalog saknas)
			Kontakta .: " Support "`n
			Detta program avslutas!"
		)
		ExitApp
	}
	If ErrorLevel and !StatErr
	{	MsgBox 16, Rad %A_LineNumber% -> %A_ScriptName%,
		( LTrim 
		 %	"Okänt fel! (Exit kod .: " ErrorLevel ")`n
			Kontakta .: " Support "`n
			Detta program avslutas!"
		)
		ExitApp
	}
	
	; Kontrollera om fil med "Error" (felmeddelanden) har skapats - Är den tom skall den raderas.
	If FileExist(ErrFile)	; (finns förmodligen alltid)
	{	FileGetSize ErrFileSize, %ErrFile% 
		; ErrFile saknar innehåll - Radera!
		if (ErrFileSize < 5)
		{	FileDelete %ErrFile%
			If ErrorLevel
			{	SplitPath ErrFile, OutFileName, OutDir
				MsgBox 16, Rad %A_LineNumber% -> %A_ScriptName%,
				( LTrim 
				 %	"Errorfil (nyss skapad - är tom) kunde inte raderas! `n
					Namn .: " OutFileName "
					Sökväg .: " OutDir "`n
					(Orsak - okänd!)
					Kontakta .: " Support "`n
					Detta program avslutas!"
				)
				ExitApp
			}
		}
	}
	
	FileRead Result, *p65001 %InfoFile%
	FileDelete %InfoFile%
	If FileExist(InfoFile)
	{	FileDelete %InfoFile%
		If ErrorLevel
		{	SplitPath InfoFile, OutFileName, OutDir
			MsgBox 16, Rad %A_LineNumber% -> %A_ScriptName%,
			( LTrim 
			 %	"Informationsfil kunde inte raderas! `n
				Namn .: " OutFileName "
				Sökväg .: " OutDir "`n
				(förmodligen låst av annat program)
				Kontakta .: " Support "`n
				Detta program avslutas!"
			)
			ExitApp
		}
	}
	
	; FileAppend % "RunArgs `n" RunArgs "`n`nRuntime .: " A_TickCount - StartTime "ms`n`n - - - - - - - - - -`n`n" Result, %InfoFile%, UTF-8
	
	
	; Skriv in intressant data till Resultatfilen
	FormatTime RunDate, A_Now, d MMMM yyyy  (HH:mm:ss)
	RunTime := Round(( A_TickCount - StartTime ) / 1000, 2)
	If ( RunTime < 1 )
		RunTime := "Conversion time .: " RunTime " seconds"
	else
		RunTime := "Conversion time .: " FormatSeconds( Round(RunTime,0) ) " [h:mm:ss]"
	
	FileAppend,
	( LTrim Commands
	 %	"`nCreate Zip date .: " RunDate "
		" RunTime "
		Zip-program .: " exeFile "
		Tee-program .: " TeeFile "
		; Created from file .: " A_ScriptFullPath "
		Created from file .: " A_ScriptName "
		Compress level .: " CompLevel "
		RunArgs for 7z .: `n`t" RunArgs "`n`n
		" Result
	), %InfoFile%, UTF-8
	If ErrorLevel
	{	SplitPath InfoFile, OutFileName, OutDir
		MsgBox 16, Rad %A_LineNumber% -> %A_ScriptName%,
		( LTrim 
		 %	"Could not append information to a file!`n
			File .: " OutFileName "
			Path .: " OutDir "`n
			ErrorLevel .: " ErrorLevel "`n
			Contact .:  " Support "`n
			This program ends!"
		)
		ExitApp
	}
}


FormatSeconds(NumberOfSeconds)  ; Convert the specified number of seconds to hh:mm:ss format.
{	; From AHK-manual
	; MsgBox % FormatSeconds(7384)  ; 7384 = 2 hours + 3 minutes + 4 seconds. It yields: 2:03:04
    time = 19990101  ; *Midnight* of an arbitrary date.
    time += %NumberOfSeconds%, seconds
    FormatTime, mmss, %time%, mm:ss
    Return NumberOfSeconds//3600 ":" mmss
}

This version is the beginning of a result to manage zip files. (unfortunately in Swedish). Some can probably be simplified and other things should be added. (Requires external software to be installed).
The function() above, is only to compress files with 7-zip.
The strategy is to try prevent problems before the 7-zip program is run - Passwords and exe-files are checked, result files are deleted, etc. (instead of 7-zip handling any problems.)
After 7-zip has been runned, the errors, as may have occurred during program execution, is checked and handled.
Finally, the result / error file / logfile should be handled.

One thing, I don't like (right now) is the end of the function() ( the result handling )
Now 7-zip is create a result-file and an error-file like this.
- If the error file is empty - remove the file (directly).
- Read the resultfile
- Delete the resultfile
- Add run information to the result file (in the beginning)
- Create the new resultfile

Missing information
- Number of files and the sum of the original files size.

I think the best way (right now) is to test the zip result with 7-zip.
- Create a separate result file (with more customized information)
- Read the file (with all compressed file names) and get the number of files and total size.
- Delete these files
- Add this information (and maybe some statistic) to the result file above.

Examples of analyzing one 7-zip file

Code: Select all

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%

SetBatchLines -1 
#SingleInstance Force

StartTime := A_TickCount
CountFile = 0
; InfoFile := "c:\Test Temp\7-Zip-TestResult mod.csv"
InfoFile := "c:\Test Temp\7-Zip-TestResult.txt"
FileRead Result, *t *p65001 %InfoFile%
Loop Parse, Result, `n`r
{	; If (SubStr(A_LoopField,1,1) = """")
	;	chkName := SubStr(A_LoopField, 2, StrLen(A_LoopField)-2)
	chkName := SubStr(A_LoopField, InStr(A_LoopField, " ")+1, StrLen(A_LoopField)-InStr(A_LoopField, " "))
	If (chkName < 3)	; Empty rows!
		Continue

	If (FileExist(chkName) and (FileExist(chkName) <> "D"))
	{	CountFile += 1
		FileGetSize, Size, %chkName%
		TotSize += Size
	}
}
RunTime := (A_TickCount - StartTime) / 1000
MsgBox ,, Rad %A_LineNumber% -> %A_ScriptName%, % "Number of files .: " CountFile " pcs.`nTotal Size .: " TotSize " bytes `n`n" RunTime " Seconds."

(Here too, problems can be created that should be dealt with)
What I do not like about this solution, is to create and delete a lot of files to achieve the result I want.

Have found some solutions, but not really known that I have any idea of how these could work together with 7-zip / Mtee.
One is (as works!) .:

The function CMDret()

Code: Select all

Res := CmdRet("""" . exeFile . """ " . RunArgs . " """ . ToZip . """ """ . SourceFile . """")

CmdRet(sCmd, callBackFuncObj := "", encoding := "CP0")
{
   static HANDLE_FLAG_INHERIT := 0x00000001, flags := HANDLE_FLAG_INHERIT
        , STARTF_USESTDHANDLES := 0x100, CREATE_NO_WINDOW := 0x08000000
   
   DllCall("CreatePipe", "PtrP", hPipeRead, "PtrP", hPipeWrite, "Ptr", 0, "UInt", 0)
   DllCall("SetHandleInformation", "Ptr", hPipeWrite, "UInt", flags, "UInt", HANDLE_FLAG_INHERIT)
   
   VarSetCapacity(STARTUPINFO , siSize :=    A_PtrSize*4 + 4*8 + A_PtrSize*5, 0)
   NumPut(siSize              , STARTUPINFO)
   NumPut(STARTF_USESTDHANDLES, STARTUPINFO, A_PtrSize*4 + 4*7)
   NumPut(hPipeWrite          , STARTUPINFO, A_PtrSize*4 + 4*8 + A_PtrSize*3)
   NumPut(hPipeWrite          , STARTUPINFO, A_PtrSize*4 + 4*8 + A_PtrSize*4)
   
   VarSetCapacity(PROCESS_INFORMATION, A_PtrSize*2 + 4*2, 0)

   if !DllCall("CreateProcess", "UInt", 0, "Str", sCmd, "UInt", 0, "UInt", 0, "UInt", true, "UInt", CREATE_NO_WINDOW
                              , "UInt", 0, "UInt", 0, "Ptr", &STARTUPINFO, "Ptr", &PROCESS_INFORMATION)
   {
      DllCall("CloseHandle", "Ptr", hPipeRead)
      DllCall("CloseHandle", "Ptr", hPipeWrite)
      throw Exception("CreateProcess is failed")
   }
   DllCall("CloseHandle", "Ptr", hPipeWrite)
   VarSetCapacity(sTemp, 4096), nSize := 0
   while DllCall("ReadFile", "Ptr", hPipeRead, "Ptr", &sTemp, "UInt", 4096, "UIntP", nSize, "UInt", 0) {
      sOutput .= stdOut := StrGet(&sTemp, nSize, encoding)
      ( callBackFuncObj && callBackFuncObj.Call(stdOut) )
   }
   DllCall("CloseHandle", "Ptr", NumGet(PROCESS_INFORMATION))
   DllCall("CloseHandle", "Ptr", NumGet(PROCESS_INFORMATION, A_PtrSize))
   DllCall("CloseHandle", "Ptr", hPipeRead)
   Return sOutput
}

Another (old one) is .: StdoutToVar (but I don't find the AHK-program)

The Result from function
From the zip-function() .: Information about the AHK program / date and time / run time / compression etc. should be returned to the main program, to save in a "main-logfile" (maybe in an object)

---

When the 7zip-compress program is work as desired, it is time to unzip compressed files, (probably in a separate function() - or if it might be possible to insert in the same function()) - but I'm not sure it will work. (and maybe look at 7-zip test / list and so on...)

[thebbandit]

just want to acknowledge how helpful this thread was to zip the contents of a folder into an archive, while skipping the folder that contains the backups. I will be working on further improving this version of the code by converting it into a function... but nonetheless, I have not done that yet so here is this for anyone who might find this useful, while I remember!

Code: Select all

ExeFile = %A_ScriptDir%\7za.exe
RunArgs = a -w"%A_ScriptDir%" -t7z -x!Backup\
ToZip = %A_ScriptDir%\Backup\%A_Now%.7z
SourceFile = .\*
Output = %A_ScriptDir%\7zip.txt
Mtee = %A_ScriptDir%\Mtee.exe

RunWait %comspec% /c " "%ExeFile%" %RunArgs% "%ToZip%" "%SourceFile%" | "%Mtee%" /+ "%Output%" ",, UseErrorLevel, ZipPID
RunWait, %Output%

The files are just placed in the script folder for portability

Edit:
Here is the quick class I made to handle backup & restore of a script to Backup folder.
It also will install the script from source from w/e repository you assign in the static values

Code: Select all

Class 7za {
	Static ExeFile := A_ScriptDir "\data\7za.exe"
	Static AddArgs := "a -w""" A_ScriptDir """ -t7z -x!Backup\"
	Static SourceFile := ".\*"
	Static LogOutput := A_ScriptDir "\logs\Archive.log"
	Static Mtee := A_ScriptDir "\data\Mtee.exe"
	Static Source := A_ScriptDir "\data\source.zip"
	backup(){
		ToZip := A_ScriptDir "\Backup\" A_Now ".7z"
		RunWait % comspec " /c "" """ This.ExeFile """ " This.AddArgs " """ ToZip """ """ This.SourceFile """ | """ This.Mtee """ /D/T/+ """ This.LogOutput """ """,, hide UseErrorLevel, ZipPID
	}
	restore(date){
		loc := A_ScriptDir "\Backup\" date ".7z"
		If FileExist(loc){
			ExtArgs := "x """ loc """ -o""" A_ScriptDir """ -y"
			RunWait % comspec " /c "" """ This.ExeFile """ " ExtArgs " | """ This.Mtee """ /D/T/+ """ This.LogOutput """ """,, hide UseErrorLevel, ZipPID
		}
	}
	install(branch){
		Static Acc := "BanditTech"
		Static Proj := "WingmanReloaded"
		Link := "https://github.com/" Acc "/" Proj "/archive/refs/heads/" branch ".zip"
		; UrlDownloadToFile,% Link,% This.Source
		ExtArgs := "x """ This.Source """ -o""" A_ScriptDir """ -y"

		subfolder := Proj "-" branch
		RunWait % comspec " /c "" """ This.ExeFile """ " ExtArgs " | """ This.Mtee """ /D/T/+ """ This.LogOutput """ """,, hide UseErrorLevel, ZipPID

		MoveArgs := "ROBOCOPY " subfolder " /S /IS """ A_ScriptDir """ /MOVE"
		RunWait % comspec " /c " MoveArgs,,hide

		RemoveArgs := "rmdir /s /q " subfolder
		RunWait % comspec " /c " RemoveArgs,,hide

	}
}

edit2: Even found out you can hide the console window popup as well with AHK