Register Hotkey Inside Class Topic is solved

[murataygun]

Is there any way to write that in one line or get it shortened?

Code: Select all

        eldivenBF := this.MalzemeGir.Bind(this, this.Malzemeler.eldiven)
        Hotkey, MButton & 1, % eldivenBF, On

I tried

Code: Select all

Hotkey, MButton & 1, % eldivenBF := this.MalzemeGir.Bind(this, this.Malzemeler.eldiven), On

No luck.

I have almost 30 shortcuts. Is it have to be 2 lines of code?

[teadrinker]

You can use this way:

Code: Select all

Inst := new MyClass
Inst.SetHotkeys()

class MyClass
{
   SetHotkeys() {
      handler := ObjBindmethod(this, "HotkeyHandler")
      Hotkey, MButton & 1, % handler, On
      Hotkey, MButton & 2, % handler, On
      Hotkey, MButton & 3, % handler, On
   }
   HotkeyHandler() {
      Switch A_ThisHotkey {
         Case "MButton & 1": MsgBox, MButton & 1
         Case "MButton & 2": MsgBox, MButton & 2
         Case "MButton & 3": MsgBox, MButton & 3
      }
   }
}

[swagfag]

Is it have to be 2 lines of code?

yes. dont like it? its fixed in v2

make a function wrapper and use that

Code: Select all

Hotkey(KeyName, Label := "", Options := "") {
	Hotkey % KeyName, % Label, % Options
}

[murataygun]

Thank you. @Threadrinker

[murataygun]

Is it have to be 2 lines of code?

yes. dont like it? its fixed in v2

make a function wrapper and use that

Code: Select all

Hotkey(KeyName, Label := "", Options := "") {
	Hotkey % KeyName, % Label, % Options
}

That is the cleanest. Thank you