How Is This Variable Being Used For More Than One Control? Topic is solved

[Mulsiphix]

I found an old script in this thread (by SKAN, post #3). I edited it slightly and it is producing an error. I am really new to playing with GUI stuff. I don't understand how to overcome this error. Can anyone explain it to me? Here is the script.

Code: Select all

d::
SetWorkingDir, %A_ScriptDir%
   
Gui +Toolwindow +AlwaysOnTop -Caption +LastFound
Gui1 := WinExist()
WinSet, TransColor, EEAA99
Gui, Margin, 0, 0
Gui, Add, Picture, x0 y0 w128 h128 Hide vMute0 , mute0.png
Gui, Add, Picture, x0 y0 w128 h128 Hide vMute1 , mute1.png
Gui, Show, x100 y100 Hide
Return

HideGUI:
 Gui, Hide
Return

#Esc::
  SoundSet, +1,  , MUTE
  SoundGet, Mute,, MUTE
  If ( MUTE="On" ) {
     GuiControl,Hide,Mute0
     GuiControl,Show,Mute1
  } Else {   
     GuiControl,Hide,Mute1
     GuiControl,Show,Mute0
  }
  SetTimer, HideGUI, -2000
  Gui, Show
Return

The error it returns is:

[mikeyww]

Every time you press the hotkey, you add the same controls, but the previously added ones are already there. Instead, build your GUI in the auto-execute section. You can use your hotkey to show the GUI that was built.

[flyingDman]

or just add gui, 1:new, or gui, destroy at the top.

[mikeyww]

An example is below.

Code: Select all

Gui, +ToolWindow +AlwaysOnTop -Caption +LastFound
WinSet, TransColor, EEAA99
Gui, Margin, 0, 0
Gui, Add, Picture,       w128 h128      , mute0.png
Gui, Add, Picture, xm ym wp   hp   vmute, mute1.png

#Esc::
SoundSet, +1,  , MUTE
SoundGet, mute,, MUTE
GuiControl, % mute = "On" ? "Show" : "Hide", mute
SetTimer, HideGUI, -2000
d::Gui, Show, x100 y100
HideGUI:
Gui, Hide
Return

[Mulsiphix]

I see. Thank you very much for your help guys.