ControlGet List Selected returns all items

[Penguin]

This code returns all the items in the listbox, even if I try Count Selected, Selected, Focused

I only want the selected items. I'm I doing something wrong or is this not possible for some controls?

Code: Select all

ControlGet, SelectedItems, List, Selected, Listbox1, jb search
msgbox, %SelectedItems%
Loop, Parse, SelectedItems, `n  ; Rows are delimited by linefeeds (`n).
{
    RowNumber := A_Index
    Loop, Parse, A_LoopField, %A_Tab%  ; Fields (columns) in each row are delimited by tabs (A_Tab).
        MsgBox Row #%RowNumber% Col #%A_Index% is %A_LoopField%.
}

[Mod edit: [code][/code] tags added.]

[mikeyww]

ListBox, ComboBox, DropDownList: All the text is retrieved from the control (that is, the ListView options above such as Count and Selected are not supported).

[Penguin]

Ho do I get just the selected items then?

[mikeyww]

Well, hmm, wish I knew that! Someone here on the forum will know.

[just me]

LB_GETSEL message ?

Code: Select all

ControlGet, Items, List, Selected, Listbox1, jb search
SelectedItems := ""
Loop, Parse, Items, `n ; Rows are delimited by linefeeds (`n).
{
   SendMessage, 0x0187, % (A_Index - 1), 0, Listbox1, jb search ; LB_GETSEL
   If (ErrorLevel <> "FAIL") && ((ErrorLevel << 32 >> 32) > 0)
      SelectedItems .= (SelectedItems <> "" ? "`n" : "") . A_LoopField
}
MsgBox, %SelectedItems%

*not tested*

[mikeyww]

It worked here. Thanks!

Code: Select all

Gui, Add, ListBox, Multi, A|B|C|D
Gui, Show,, jb search

F3::
ControlGet, Items, List, Selected, Listbox1, jb search
SelectedItems := ""
Loop, Parse, Items, `n ; Rows are delimited by linefeeds (`n). ; From just me
{
   SendMessage, 0x0187, % (A_Index - 1), 0, Listbox1, jb search ; LB_GETSEL
   If (ErrorLevel <> "FAIL") && ((ErrorLevel << 32 >> 32) > 0)
      SelectedItems .= (SelectedItems <> "" ? "`n" : "") . A_LoopField
}
MsgBox, %SelectedItems%
Return

[Penguin]

Thanks everyone for your help