Help Using InputBox Text As a ListBox Choice

Get help with using AutoHotkey (v1.1 and older) and its commands and hotkeys
Forum rules
Post Reply
AlFlo
Posts: 345
Joined: 29 Nov 2021, 21:46

Help Using InputBox Text As a ListBox Choice

Post by AlFlo » 22 Jan 2022, 21:01

I have a listbox with a bunch of choices. But I want to be able to add another choice using a inputbox.

Here's the relevant part of my code:

Code: Select all


#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.

Gui Add, ListBox, wp   hp  Multi VCalendar  ,  Sam Smith|John Doe|Sammy Sosa|Alex Brown|INPUT
    
Gui, Show,, Test

Gui Font

Gui Add, Button, x1300 y560 w75 h23 gCalendarRun, Calendar

Calendar:
if A_GuiControlEvent <> DoubleClick
	return
GuiControlGet, Client  ; Retrieve the ListBox's current selection.

Sleep, 200
SendInput, %Calendar%
 Gui, Submit, Hide
Sleep, 200
SendInput, %Calendar%
Gui, Hide
Return

CalendarRun:
Gui, Submit, Hide 

{ 
If (Calendar=INPUT)
tempVar:=Listbox
}

Else
  tempVar:=%Calendar%

Sleep, 1000

Run, Chrome.exe "https://calendar.google.com/calendar/u/1/r/search?q="%tempVar%

Reload
Return
Top
User avatar
mikeyww
Posts: 26848
Joined: 09 Sep 2014, 18:38

Re: Help Using InputBox Text As a ListBox Choice

Post by mikeyww » 22 Jan 2022, 21:24

Code: Select all

Gui, Font, s10
Gui, Add, ListBox, w250 r6 Multi vname, Sam Smith|John Doe|Sammy Sosa|Alex Brown
Gosub, Show
InputBox, add, Add a row, Enter new listing.,, 300, 125
If (ErrorLevel || add = "")
 Return
GuiControl,, name, %add%
Show:
Gui, Show, x200 y400, Test
Return
Top
AlFlo
Posts: 345
Joined: 29 Nov 2021, 21:46

Re: Help Using InputBox Text As a ListBox Choice

Post by AlFlo » 22 Jan 2022, 23:39

I'm getting errors wherever I type

Code: Select all

Gosub, Show
Am I supposed to break up your code and put it in different parts of the script? If so, where do I put it?

Thanks in advance!
Top
User avatar
mikeyww
Posts: 26848
Joined: 09 Sep 2014, 18:38

Re: Help Using InputBox Text As a ListBox Choice

Post by mikeyww » 23 Jan 2022, 08:58

Before you change your own script, try the script that I posted by itself, to see whether it works. After that, you can report your findings from that test, and then post your revised script if it is not working.
Top
garry
Posts: 3758
Joined: 22 Dec 2013, 12:50

Re: Help Using InputBox Text As a ListBox Choice

Post by garry » 23 Jan 2022, 11:47

an idea for listbox , add names, when close GUI then save names
maybe a better idea for fileappend > file.write

Code: Select all

Gui,1:default
F1=%a_scriptdir%\ListboxNames.txt
ifnotexist,%f1%
  gosub,a1
fileread,aa,%f1%
Gui,Font,s12,Lucida Console
Gui Add, ListBox,x10  y10  w250  h230  Multi vListbox1  ,%aa%
Gui Add, Button, x10  y260 w120  h23 gCalendarRun, Calendar
Gui,add,Edit,    x140 y260 w250  h25 hwndHED11 vED1
SetEditCueBanner(HED11, "ADD NAME")
Gui, Show,x10 y10 w400 h300 , TEST
GuiControl,1: Focus,ed1
return
;------------
Guiclose:
;Gui,1:submit,nohide
Guicontrolget,Listbox1
ControlGet, Items, List,,Listbox1,TEST
e:=""
Loop, Parse, Items, `n
  e .= a_loopfield . "|"
ifexist,%f1%
  filedelete,%f1%
Fileappend,%e%,%f1%,utf-8
e=
exitapp
;------------
Calendarrun:
return
;------------
$enter::
Gui,1:submit,nohide
GuiControl,1:,Listbox1, %ed1%
GuiControl,1:,ed1
GuiControl,1: Focus,ed1
return
;------------
A1:
e5=
(Ltrim join|
Sam Smith
John Doe
Sammy Susa
Alex Brown
INPUT
)
Fileappend,%e5%,%f1%,utf-8
e5=
return
;---------------

SetEditCueBanner(HWND, Cue) {
   Static EM_SETCUEBANNER := (0x1500 + 1)
   Return DllCall("User32.dll\SendMessageW", "Ptr", HWND, "Uint", EM_SETCUEBANNER, "Ptr", True, "WStr", Cue)
}
;=====================================
Top
amateur+
Posts: 655
Joined: 09 Oct 2021, 15:43

Re: Help Using InputBox Text As a ListBox Choice

Post by amateur+ » 23 Jan 2022, 12:20

mikeyww's example with Edit instead of Inputbox:

Code: Select all

Gui, Font, s10
Gui, Add, ListBox, w250 r10 Multi Section vname, Sam Smith|John Doe|Sammy Sosa|Alex Brown
Gui, Add, Text,ys, Type a new name to add below then press "Enter" or push "Add" button.
Gui, Add, Edit, w320 vAdded, 
Gui, Add, Button,Default Center, Add
Gui, Show, x200 y400, Test
return

ButtonAdd:
Gui, Submit, NoHide
GuiControl,, name, % Added
GuiControl,, Added, 
return

GuiClose:
ExitApp
Have found any drawback in my code or approach? Please, point it out. /The moderator ordered to remove the rest of the signature, I had obeyed.
And I really apologize for our russian president. Being a citizen of an aggressor country is very shameful. Personally I tried to avoid this trying to defend elections from fraud being a member of the election commission of one of the precincts but only was subjected to a hooligan attack and right before the vote count was illegally escorted from the polling station and spent the night behind bars (in jail) in a result of illegal actions of corrupt policemen.
Top
AlFlo
Posts: 345
Joined: 29 Nov 2021, 21:46

Re: Help Using InputBox Text As a ListBox Choice

Post by AlFlo » 23 Jan 2022, 13:40

Thanks, mikeyww, I get it now! And thanks amateur+ and garry!

I assume the script to DELETE list entries from the ListBox would be quite different - and much more complicated - then ADDING entries?
Top
User avatar
mikeyww
Posts: 26848
Joined: 09 Sep 2014, 18:38

Re: Help Using InputBox Text As a ListBox Choice

Post by mikeyww » 23 Jan 2022, 13:52

Code: Select all

Gui, Font, s10
Gui, Add, ListBox, w250 r6 Multi vname, % str := "Sam Smith|John Doe|Sammy Sosa|Alex Brown"
Gosub, Show
InputBox, del, Delete a row, Enter the listing to delete.,, 300, 125
If (ErrorLevel || del = "")
 Return
GuiControl,, name, % "|" Trim(StrReplace(StrReplace(str, del, ""), "||", "|"), "|")
Show:
Gui, Show, x200 y400, Test
Return
To learn more, click "GuiControl" in the posted script.
Top
amateur+
Posts: 655
Joined: 09 Oct 2021, 15:43

Re: Help Using InputBox Text As a ListBox Choice

Post by amateur+ » 23 Jan 2022, 14:19

And for deleting in "Edit instead of Inputbox" realization:

Code: Select all

Gui, Font, s10
Gui, Add, ListBox, w250 r10 Multi Section vname, Sam Smith|John Doe|Sammy Sosa|Alex Brown
Gui, Add, Text,ys, Type a new name to add below then press "Enter" or push "Add" button.
Gui, Add, Edit, w320 vAdded, 
Gui, Add, Button,Default Center, Add
Gui, Add, Button, gDelete Center, Delete item
Gui, Show, x200 y400, Test
return

ButtonAdd:
Gui, Submit, NoHide
GuiControl,, name, % Added
GuiControl,, Added, 
return

Delete:
Gui, Submit, NoHide
GuiControl, +AltSubmit, name
GuiControlGet, toDelete, ,NAme
Control, Delete, % toDelete, ListBox1
GuiControl, Choose, name, % toDelete
GuiControl, -AltSubmit, name
return

GuiClose:
ExitApp
EDIT: fixed two mistakes: removed AitSubmit from ListBox creation line and Deled fixed to Delete.
Last edited by amateur+ on 23 Jan 2022, 17:41, edited 1 time in total.
Have found any drawback in my code or approach? Please, point it out. /The moderator ordered to remove the rest of the signature, I had obeyed.
And I really apologize for our russian president. Being a citizen of an aggressor country is very shameful. Personally I tried to avoid this trying to defend elections from fraud being a member of the election commission of one of the precincts but only was subjected to a hooligan attack and right before the vote count was illegally escorted from the polling station and spent the night behind bars (in jail) in a result of illegal actions of corrupt policemen.
Top
garry
Posts: 3758
Joined: 22 Dec 2013, 12:50

Re: Help Using InputBox Text As a ListBox Choice

Post by garry » 23 Jan 2022, 16:41

thank you for the examples , I added a text to keep settings for the script from @amateur+

Code: Select all

#NoEnv 
SendMode Input 
SetWorkingDir %A_ScriptDir%
SetTitleMatchMode 2
SetBatchLines, -1
Gui,1: -dpiscale
Gui,1:default
Filename:="TEST_LB"
F1=%a_scriptdir%\ListboxNames20.txt
ifnotexist,%f1%
  gosub,a1
fileread,aa,%f1%
Gui, Font, s12
Gui, Add, ListBox, w250 r10 AltSubmit Multi Section vname,%aa%
Gui, Add, Text,ys, Type a new name to add below then press "Enter" or push "Add" button.
Gui, Add, Edit, w320 vAdded, 
Gui, Add, Button,Default Center, Add
Gui, Add, Button, gDelete Center, Deled item
Gui, Add, Button, gShow,Show Selected
Gui, Show, x200 y400,%filename%
return
;-----------------------
ButtonAdd:
Gui, Submit, NoHide
GuiControl,, name, % Added
GuiControl,, Added, 
return
;----------------------
Show:
Gui,submit,nohide
GuiControl, -AltSubmit, name
GuiControlGet,vr, ,Name
msgbox,NAME=%vr%
return
;----------------------
Delete:
Gui, Submit, NoHide
GuiControl, +AltSubmit, name
GuiControlGet, toDelete, ,NAme
Control, Delete, % toDelete, ListBox1
GuiControl, Choose, name, % toDelete
GuiControl, -AltSubmit, name
return
;------------------------
Guiclose:
Guicontrolget,Name
ControlGet, Items, List,,Listbox1,%filename%
e:=""
Loop, Parse, Items, `n
  e .= a_loopfield . "|"
ifexist,%f1%
  filedelete,%f1%
Fileappend,%e%,%f1%,utf-8
e=
exitapp
;----------------------
A1:
e5=
(Ltrim join|
Sam Smith
John Doe
Sammy Susa
Alex Brown
INPUT
)
Fileappend,%e5%,%f1%,utf-8
e5=
return
;---------------
;=========================
Top
amateur+
Posts: 655
Joined: 09 Oct 2021, 15:43

Re: Help Using InputBox Text As a ListBox Choice

Post by amateur+ » 23 Jan 2022, 17:33

We should fix some my mistakes:

Code: Select all

#NoEnv 
SendMode Input 
SetWorkingDir %A_ScriptDir%
SetTitleMatchMode 2
SetBatchLines, -1
Gui,1: -dpiscale
Gui,1:default
Filename:="TEST_LB"
F1=%a_scriptdir%\ListboxNames20.txt
ifnotexist,%f1%
  gosub,a1
fileread,aa,%f1%
Gui, Font, s12
Gui, Add, ListBox, w250 r10 Multi Section vname,%aa%
Gui, Add, Text,ys, Type a new name to add below then press "Enter" or push "Add" button.
Gui, Add, Edit, w320 vAdded, 
Gui, Add, Button,Default Center, Add
Gui, Add, Button, gDelete Center, Delete item
Gui, Add, Button, gShow,Show Selected
Gui, Show, x200 y400,%filename%
return
;-----------------------
ButtonAdd:
Gui, Submit, NoHide
GuiControl,, name, % Added
GuiControl,, Added, 
return
;----------------------
Show:
Gui,submit,nohide
GuiControlGet,vr, ,Name
msgbox,NAME=%vr%
return
;----------------------
Delete:
Gui, Submit, NoHide
GuiControl, +AltSubmit, name
GuiControlGet, toDelete, ,NAme
Control, Delete, % toDelete, ListBox1
GuiControl, Choose, name, % toDelete
GuiControl, -AltSubmit, name
return
;------------------------
Guiclose:
Guicontrolget,Name
ControlGet, Items, List,,Listbox1,%filename%
e:=""
Loop, Parse, Items, `n
  e .= a_loopfield . "|"
ifexist,%f1%
  filedelete,%f1%
Fileappend,%e%,%f1%,utf-8
e=
exitapp
;----------------------
A1:
e5=
(Ltrim join|
Sam Smith
John Doe
Sammy Susa
Alex Brown
INPUT
)
Fileappend,%e5%,%f1%,utf-8
e5=
return
;---------------
;=========================
Have found any drawback in my code or approach? Please, point it out. /The moderator ordered to remove the rest of the signature, I had obeyed.
And I really apologize for our russian president. Being a citizen of an aggressor country is very shameful. Personally I tried to avoid this trying to defend elections from fraud being a member of the election commission of one of the precincts but only was subjected to a hooligan attack and right before the vote count was illegally escorted from the polling station and spent the night behind bars (in jail) in a result of illegal actions of corrupt policemen.
Top
garry
Posts: 3758
Joined: 22 Dec 2013, 12:50

Re: Help Using InputBox Text As a ListBox Choice

Post by garry » 23 Jan 2022, 18:04

@amateur+ thank you for the correction , I was confused about 'altsubmit'
Top
AlFlo
Posts: 345
Joined: 29 Nov 2021, 21:46

Re: Help Using InputBox Text As a ListBox Choice

Post by AlFlo » 24 Jan 2022, 00:40

Thanks, guys ... these are super-helpful scripts! My listbox script actually has about 20 listboxes in it, including 2 using AltSubmit functions ... so it's going to take me a little while to integrate the add/delete functions.
Top
garry
Posts: 3758
Joined: 22 Dec 2013, 12:50

Re: Help Using InputBox Text As a ListBox Choice

Post by garry » 24 Jan 2022, 02:03

example works with altsubmit
;-- LISTBOX , ADD new or DELETE row , keep settings
;-- Focus is on ADD NAME

Code: Select all

;- Help Using InputBox Text As a ListBox Choice 
;- https://www.autohotkey.com/boards/viewtopic.php?f=76&t=99215

;-- MODIFIED=20220124
;-- Listbox add new or delete row
;-- Focus is on ADD NAME
;--
#NoEnv 
SendMode Input 
SetWorkingDir %A_ScriptDir%
SetTitleMatchMode 2
SetBatchLines, -1
Gui,1: -dpiscale
Gui,1:default
Filename:="TEST_LB"
F1=%a_scriptdir%\ListboxNames.txt
ifnotexist,%f1%
  gosub,a1
fileread,aa,%f1%
Gui,Font,s12,Lucida Console
Gui Add, ListBox,x10  y10  w250  h230 altsubmit vVar1  ,%aa%
Gui Add, Button, x270 y30  w260  h37 gShow,Show_Selected
Gui,add,Edit,    x10  y260 w400  h37 hwndHED11 vED1
Gui Add, Button, x270 y100 w160  h37 gDEL,DELETE
SetEditCueBanner(HED11, "ADD NAME")
Gui, Show,x10 y10 w550 h350 ,%filename%
GuiControl,1: Focus,ed1
return
;------------

#IfWinActive,TEST_LB ahk_class AutoHotkeyGUI
$enter::
Gui,1:submit,nohide
GuiControl,1:,Var1, %ed1%
GuiControl,1:,ed1
GuiControl,1: Focus,ed1
#Ifwinactive
return
;----------------------------
Guiclose:
Guicontrolget,Var1
ControlGet, Items, List,,Listbox1,%filename%
e:=""
Loop, Parse, Items, `n
  e .= a_loopfield . "|"
ifexist,%f1%
  filedelete,%f1%
Fileappend,%e%,%f1%,utf-8
e=
exitapp
;------------
Show:
Gui,1:submit,nohide
GuiControl, -AltSubmit,var1
GuiControlGet,vr, ,var1
if (vr="")
  msgbox, 262208,SHOW_LB_ROW ,NAME NOT SELECTED,1.5
else
  msgbox, 262208,SHOW_LB_ROW ,NAME=%vr%
GuiControl, +AltSubmit,var1
GuiControl,1: Focus,ed1
return
;------------
DEL:
lb=listbox1
vr=var1
GuiControlGet,   TheSelectedLine,,%vr%      ; get the focused item Number
Control, Delete, %TheSelectedLine%, %lb%    ; delete the focused item
;ControlGet, Wholex, List,,%lb%              ;- get the whole listbox1
;Fileappend,%wholex%,%f1%,utf-8
GuiControl,1: Focus,ed1
return
;-----------
A1:
e5=
(Ltrim join|
Sam Smith
John Doe
Sammy Susa
Alex Brown
INPUT
)
Fileappend,%e5%,%f1%,utf-8
e5=
return
;---------------
SetEditCueBanner(HWND, Cue) {
   Static EM_SETCUEBANNER := (0x1500 + 1)
   Return DllCall("User32.dll\SendMessageW", "Ptr", HWND, "Uint", EM_SETCUEBANNER, "Ptr", True, "WStr", Cue)
}
;=====================================
Top
AlFlo
Posts: 345
Joined: 29 Nov 2021, 21:46

Re: Help Using InputBox Text As a ListBox Choice

Post by AlFlo » 25 Jan 2022, 13:53

Thank you!
Top
amateur+
Posts: 655
Joined: 09 Oct 2021, 15:43

Re: Help Using InputBox Text As a ListBox Choice

Post by amateur+ » 25 Jan 2022, 14:16

@garry, could you, please, tell me more about SetEditCueBanner()? It seems like I can't get any effect from it at my computer, look at a screenshot in attach.
Spoiler
Have found any drawback in my code or approach? Please, point it out. /The moderator ordered to remove the rest of the signature, I had obeyed.
And I really apologize for our russian president. Being a citizen of an aggressor country is very shameful. Personally I tried to avoid this trying to defend elections from fraud being a member of the election commission of one of the precincts but only was subjected to a hooligan attack and right before the vote count was illegally escorted from the polling station and spent the night behind bars (in jail) in a result of illegal actions of corrupt policemen.
Top
garry
Posts: 3758
Joined: 22 Dec 2013, 12:50

Re: Help Using InputBox Text As a ListBox Choice

Post by garry » 25 Jan 2022, 14:35

I use a cheap small 4K computer (12*12*2-cm) WIN10 PRO
must ask specialist ... :)

https://cse.google.com/cse?cx=003825578684429028588:oved6rfvrlq
start this ahk-search above and search for > EM_SETCUEBANNER



another example from user @teadrinker
( I just used EM_SETCUEBANNER and removed function SetEditCueBanner ) from last script above

Code: Select all

;....
Gui,add,Edit,    x10  y260 w400  h37 hwndHED11 vED1
Gui Add, Button, x270 y100 w160  h37 gDEL,DELETE
;SetEditCueBanner(HED11, "ADD NAME")
SendMessage, EM_SETCUEBANNER := 0x1501, true, "ADD NAME",, ahk_id %HED11%
;.....
viewtopic.php?style=19&t=85648

Code: Select all

;-------- saved at 星期二 一月 2022-01-25  19:29 UTC --------------
;- Modal Windows 
;- https://www.autohotkey.com/boards/viewtopic.php?style=19&t=85648

Gui, Add, Edit, w300 hwndhEdit
SendMessage, EM_SETCUEBANNER := 0x1501, true, "Enter some text here and click OK",, ahk_id %hEdit%
Gui, Add, Button, x120 w80 Default, OK
Gui, Show
WinWaitClose, ahk_id %hEdit%
MsgBox, You entered:`n %Edit1%
ExitApp
ButtonOK:
   GuiControlGet, Edit1
   Gui, Destroy
   Return
   
GuiClose:
   Gui, Destroy
   Return
;esc::exitapp
this is the same like last script above , used EM_SETCUEBANNER

Code: Select all

;-- MODIFIED=20220125
;-- Listbox add new or delete row
;-- Focus is on ADD NAME
;--
#NoEnv 
SendMode Input 
SetWorkingDir %A_ScriptDir%
SetTitleMatchMode 2
SetBatchLines, -1
Gui,1: -dpiscale
Gui,1:default
Filename:="TEST_LB"
F1=%a_scriptdir%\ListboxNames22.txt
ifnotexist,%f1%
  gosub,a1
fileread,aa,%f1%
Gui,Font,s12,Lucida Console
Gui Add, ListBox,x10  y10  w250  h230 altsubmit vVar1  ,%aa%
Gui Add, Button, x270 y30  w260  h37 gShow,Show_Selected
Gui,add,Edit,    x10  y260 w400  h37 hwndHED11 vED1
Gui Add, Button, x270 y100 w160  h37 gDEL,DELETE
SendMessage, EM_SETCUEBANNER := 0x1501, true, "ADD NAME",, ahk_id %HED11%
Gui, Show,x10 y10 w550 h350 ,%filename%
GuiControl,1: Focus,ed1
return
;------------
#IfWinActive,TEST_LB ahk_class AutoHotkeyGUI
$enter::
Gui,1:submit,nohide
GuiControl,1:,Var1, %ed1%
GuiControl,1:,ed1
GuiControl,1: Focus,ed1
#Ifwinactive
return
;----------------------------
Guiclose:
Guicontrolget,Var1
ControlGet, Items, List,,Listbox1,%filename%
e:=""
Loop, Parse, Items, `n
  e .= a_loopfield . "|"
ifexist,%f1%
  filedelete,%f1%
Fileappend,%e%,%f1%,utf-8
e=
exitapp
;------------
Show:
Gui,1:submit,nohide
GuiControl, -AltSubmit,var1
GuiControlGet,vr, ,var1
if (vr="")
  {
  ;msgbox, 262208,SHOW_LB_ROW ,NAME is NOT SELECTED
  GuiControl, +AltSubmit,var1
  GuiControl,1: Focus,ed1
  return
  }
else
  msgbox, 262208,SHOW_LB_ROW ,NAME=%vr%
GuiControl, +AltSubmit,var1
GuiControl,1: Focus,ed1
return
;------------
DEL:
lb=listbox1
vr=var1
GuiControlGet,   TheSelectedLine,,%vr%      ; get the focused item Number
Control, Delete, %TheSelectedLine%, %lb%    ; delete the focused item
;ControlGet, Wholex, List,,%lb%              ;- get the whole listbox1
;Fileappend,%wholex%,%f1%,utf-8
GuiControl,1: Focus,ed1
return
;-----------
A1:
e5=
(Ltrim join|
Sam Smith
John Doe
Sammy Susa
Alex Brown
INPUT
)
Fileappend,%e5%,%f1%,utf-8
e5=
return
;=====================================
Top
amateur+
Posts: 655
Joined: 09 Oct 2021, 15:43

Re: Help Using InputBox Text As a ListBox Choice

Post by amateur+ » 25 Jan 2022, 19:00

@garry, thanks a lot, buddy! I even didn't know about those cue things.
You know, I can't say why, but SendMessage, 0x1501, true, "ADD NAME",, ahk_id %HED11% doesn't work for me in your script, but it works in teadrinker's scripts you gave links to. I'm already have broken my head, it is just totally misterious for me. For example this is the output of your last script in your last post:
Spoiler
The only way I've managed to get that cue in your Edit - it is to use @Drugwash's function CueBanner. And it allows to create really nice cues. I'll even go to that topic and say thanks to him for it.
Here is what I got:
Spoiler
And here is a code (it requires that Drugwash's function):
Spoiler
Btw, about that custom google search. Does It just use "site:AutoHotkey.com" or maybe something else?
Have found any drawback in my code or approach? Please, point it out. /The moderator ordered to remove the rest of the signature, I had obeyed.
And I really apologize for our russian president. Being a citizen of an aggressor country is very shameful. Personally I tried to avoid this trying to defend elections from fraud being a member of the election commission of one of the precincts but only was subjected to a hooligan attack and right before the vote count was illegally escorted from the polling station and spent the night behind bars (in jail) in a result of illegal actions of corrupt policemen.
Top
garry
Posts: 3758
Joined: 22 Dec 2013, 12:50

Re: Help Using InputBox Text As a ListBox Choice

Post by garry » 28 Jan 2022, 04:38

@amateur+ thank you for the examples , dont know why it works for me
( now I have a new minicomputer with WIN11 ( size is 2-cm bigger ) , have more capacity at drive C:\ )
Btw, about that custom google search. Does It just use "site:AutoHotkey.com" or maybe something else?
https://cse.google.com/cse?cx=003825578684429028588:oved6rfvrlq
Someone has customized this for search in autohotkey.com ( I didn't tried )
Google customized search : https://programmablesearchengine.google.com/about/

or run with known parameter
example google search with time > cd_min:01.21.2021,cd_max:01.28.2022 search for 'EM_Setcuebanner' at site autohotkey.com

https://www.google.com/search?&tbs=cdr:1,cd_min:01.21.2021,cd_max:01.28.2022&as_sitesearch=autohotkey.com&as_dt=i&q=EM_setcuebanner&num=100
https://www.google.com/search?&tbs=cdr% ... er&num=100
Top
Post Reply

Return to “Ask for Help (v1)”