Start and Stop Buttons in GUI Topic is solved

[leofabian]

Hello to all!
I have written a script here with GUI that should start when the "Start" button is pressed and should be interrupted with the "Stop" button.
The script works the first time I press the "Start" button.
When I press "Stop" the script stops.
But when I press "Start" again, nothing happens.
What am I doing wrong?
I appreciate your answer!

Code: Select all

#SingleInstance, Force

Gui, Add, Button, x0 y21 w121 h29 gagain, Start
Gui, Add, Button, x130 y21 w121 h29 gstop, St&op
Gui, Add, Button, x260 y21 w121 h29 gover, E&xit

gui, show, w381 h50

stop:
Pause

again:
MouseMove, 20, 30, 50, R
sleep, 2000
MouseMove, -20, -30, 50, R
sleep, 2000
goto again

over:
ExitApp

GuiClose:
GuiEscape:
ExitApp

[boiler]

You are missing return statements in various places. Starting again won't undo a Pause. If you really want to use Pause to stop, then you should make it a start/stop toggle button. But to make it work using your arrangement, try this:

Code: Select all

#SingleInstance, Force

Gui, Add, Button, x0 y21 w121 h29 gagain, Start
Gui, Add, Button, x130 y21 w121 h29 gstop, St&op
Gui, Add, Button, x260 y21 w121 h29 gover, E&xit

gui, show, w381 h50
return

stop:
	stopped := 1
return

again:
	stopped := 0
	loop {
		MouseMove, 20, 30, 50, R
		sleep, 2000
		if stopped
			return
		MouseMove, -20, -30, 50, R
		sleep, 2000
		if stopped
			return
	}
return

over:
ExitApp

GuiClose:
GuiEscape:
ExitApp

[leofabian]

Thank you, that does the job

I admit that I am confused about "return".
I have seen many examples sometimes without and sometimes with.
I'll have to read up more on this.

[boiler]

By the way, if you are going to have separate start and stop buttons, it would make sense to disable the one that wouldn't make sense to choose:

Code: Select all

#SingleInstance, Force

Gui, Add, Button, x0 y21 w121 h29 gagain vStart, Start
Gui, Add, Button, x130 y21 w121 h29 gstop vStop Disabled, St&op
Gui, Add, Button, x260 y21 w121 h29 gover, E&xit

gui, show, w381 h50
return

stop:
	GuiControl, Enable, Start
	GuiControl, Disable, Stop
	stopped := 1
return

again:
	GuiControl, Enable, Stop
	GuiControl, Disable, Start
	stopped := 0
	loop {
		MouseMove, 20, 30, 50, R
		sleep, 2000
		if stopped
			return
		MouseMove, -20, -30, 50, R
		sleep, 2000
		if stopped
			return
	}
return

over:
GuiClose:
GuiEscape:
ExitApp

[leofabian]

Boiler you're great.
Thank's a lot!

[boiler]

No problem. Perhaps you'd like this better, where it uses one button for starting and stopping:

Code: Select all

#SingleInstance, Force

Gui, Add, Button, x0 y21 w121 h29 gstartstop vsstoggle, Start
Gui, Add, Button, x160 y21 w121 h29 gover, E&xit

gui, show, w281 h50

loop {
	while toggle {
		MouseMove, 20, 30, 50, R
		sleep, 2000
		if !toggle
			break
		MouseMove, -20, -30, 50, R
		sleep, 2000
	}
}
return

startstop:
	toggle := !toggle
	GuiControl,, sstoggle, % toggle ? "Stop" : "Start"
return

over:
GuiClose:
GuiEscape:
ExitApp

[leofabian]

Yes, even better.
I love short code
Thanks a lot!