[V2-β7](Gui) How to bind variables to callback function inside a loop Topic is solved

[hoangthi]

Hi, I've just added a couple of text fields into my GUI using a Loop function.
Each text field has a OnEvent Callback function to retrieve its value whenever I click on it.

The issue is, that I can't bind variables inside the Loop to the call back function. No matter what is it in the Loop, it will only return 0 inside the callback.

The only workaround so far is to pass a Ctrl Object to the call-back function, then retrieve each Text Control Name and Text

Could you please tell me a way to bind variables (sorry for lack of a better word) from the Loop to the CallBackFunc()?

Here is my example:

image.png (38.2 KiB) Viewed 960 times

Code: Select all

myGui := Gui()

loop 10 
{

myText := myGui.Add("Text", "h33 w100 Left BackgroundTrans 0x201 vTextCtrl" . A_Index, "Hello world" . A_Index)


myText.OnEvent("Click", CallBackFunc)

	CallBackFunc(CtrlObj, *)
	{
		MsgBox("Ctrl Name (correct): " . CtrlObj.Name . "`r`n Variables inside the loop (wrong): " . A_Index)
	
	}

}

myGui.Title := "Testing Callback function"

myGui.Show("AutoSize")

[AHK_user]

Simple, just bind the variable to the callback function.

Code: Select all

#SingleInstance force
#Requires Autohotkey v2.0-a+

myGui := Gui()

loop 10 
{

myText := myGui.Add("Text", "h33 w100 Left BackgroundTrans 0x201 vTextCtrl" . A_Index, "Hello world" . A_Index)


myText.OnEvent("Click", CallBackFunc.Bind(A_Index))

	CallBackFunc(Index, GuiCtrlObj, Info)
	{
		MsgBox("Ctrl Name (correct): " . GuiCtrlObj.Name . "`r`n Variables inside the loop (correct): " . Index)
	
	}

}

myGui.Title := "Testing Callback function"

myGui.Show("AutoSize")

[AHK_user]

you actually do not need the function, I would advice a fat arrow function, but maybe it is less readable:

Code: Select all

#SingleInstance force
#Requires Autohotkey v2.0-a+

myGui := Gui()

loop 10 {
    myText := myGui.Add("Text", "h33 w100 Left BackgroundTrans 0x201 vTextCtrl" . A_Index, "Hello world" . A_Index)
    myText.OnEvent("Click", ((Index, GuiCtrlObj, Info) => (MsgBox("Ctrl Name (correct): " . GuiCtrlObj.Name . "`r`n Variables inside the loop (correct): " . Index))).Bind(A_Index))
}

myGui.Title := "Testing Callback function"
myGui.Show("AutoSize")

[hoangthi]

Simple, just bind the variable to the callback function.

Great! I didn't think it was that simple. I am very grateful!

instead of

Code: Select all

myText.OnEvent("Click", CallBackFunc.Bind(A_Index))

I tried (wrong way)

Code: Select all

myText.OnEvent("Click", CallBackFunc(A_Index))

and also tried (wrong way)

Code: Select all

myText.OnEvent("Click", CallBackFunc.Bind(A_Index))

CallBackFunc(A_Index, GuiCtrlObj, *) 
{
	MsgBox(A_Index)
}

For a newbie to Autohotkey like me, it is a bit complicated to use vControl & Control, A_Index & Index, ...