Creating Folders in Windows Explorer

[Gorpis]

What I am doing wrong here, I want to create these folders when I am in Windows Explorer and it does not work

Code: Select all

;----------------------------------------------------------------------------------
; Generates folder structure for new Projects in Google Drive via Windows Explorer
; Date created: 1/26/2023
; Date of last edit: 1/26/2023
;---------------------------------------------------------------------------------

#HotIf WinActive("ahk_class CabinetWClass")

^F9::

{

CreateFolder("Bid Docs")
CreateFolder("Equipment Scopes")
CreateFolder("Order Acknowledgements")
CreateFolder("Pricing")
CreateFolder("Purchase Orders")
CreateFolder("Selections")
CreateFolder("Submittals")

CreateFolder(FolderName) {

	Send("{^+n}")
	Sleep(500)
	Send(FolderName)
	Send("{Enter}")
	Sleep(500)

	}

}

[Mod edit: [code][/code] tags added.]

[boiler]

Rather than interacting with a File Explorer window, it would be faster and much more reliable for your script to have you select your project folder using DirSelect and then create your new folders within the selected folder using DirCreate.

[andymbody]

I agree with @boiler...

also... I dont see anything in the v2 docs about using parenthesis...

should this
Send("{Enter}")

be this?
Send "{Enter}"

as well as removing parentheses from the other Send's?

[mikeyww]

It makes no difference, but I think that this would also be clear by calling those functions.

Code: Select all

#Requires AutoHotkey v2.0
Send 54  ; Send is a function
Send(54) ; Send is still a function

Send("{^+n}") => Send("^+n")

---

Code: Select all

#Requires AutoHotkey v2.0

#HotIf WinActive("ahk_class CabinetWClass")
^F9:: {
 Static dirList := ["test1", "test2", "test3"]
 curPath := explorerGetPath()
 For each, dir in dirList
  DirCreate curPath '\' dir
 SoundBeep 1500
}
#HotIf

explorerGetPath(hwnd := 0) { ; https://www.autohotkey.com/boards/viewtopic.php?p=387113#p387113
 Static winTitle := "ahk_class CabinetWClass"
 hWnd ?    explorerHwnd := WinExist(winTitle " ahk_id " hwnd)
      : ((!explorerHwnd := WinActive(winTitle)) && explorerHwnd := WinExist(winTitle))
 If explorerHwnd
  For window in ComObject("Shell.Application").Windows
   Try If window && window.hwnd && window.hwnd = explorerHwnd
    Return window.Document.Folder.Self.Path
 Return False
}

[boiler]

From the documentation:

If the return value of the function is not needed and the function name is written at the start of the line (or in other contexts which allow a statement, such as following else or a hotkey), the parentheses can be omitted. In this case, the remainder of the line is taken as the function's parameter list. For example:

Code: Select all

result := MsgBox("This one requires parentheses.",, "OKCancel")
MsgBox "This one doesn't. The result was " result "."

…and:

Removed "command syntax". There are no "commands", only function call statements, which are just function or method calls without parentheses. That means:

• All former commands are now functions (excluding control flow statements).
• All functions can be called without parentheses if the return value is not needed (but as before, parentheses cannot be omitted for calls within an expression).

[andymbody]

Thanks for the clarification @mikeyww and @boiler

do you guys ever sleep?

[Gorpis]

When I ran the code I got this error, what do you think needs to be done to fix it:

Error: This variable has not been assigned a value.

Specifically: local curPath

006: curPath := explorerGetPath()
007: For each, dir in dirList
▶ 008: DirCreate(curPath '\' dir)
009: SoundBeep(1500)
010: }

[Gorpis]

I got my original code to work by changing

Send("{^+n}")

to

Send("^+n")

I did not understand the curly brackets are for specific keys like {Enter} rather than combinations of keys which do not get the curly brackets

[boiler]

For one thing, braces go around a key name. You surrounded a group keys including the modifiers with them (i.e., ^+n is not a key — it’s three keys). They generally are only needed for key names that have multiple letters like Tab to distinguish it from sending the letters T, a, and b. Also, there is a list of key names found at the Send documentation.

[Gorpis]

Yes, I figured that out a few days ago, as I mentioned new to this so drinking from the firehose at this point, thanks for your help. Any ideas why the code above does not work? Its does not like this line: curPath := explorerGetPath()

[mikeyww]

If you are seeing an error message, then post your script, a screenshot of the error window, and all of the steps that you take to generate the error.

[boiler]

Its does not like this line: curPath := explorerGetPath()

I'm going to guess that you did not copy mikeyww's entire script -- only the part that is visible in the code box without scrolling or expanding it -- so you did not copy the function itself into the script. The reason it's important to share the actual error message with us is that it gives much more detail about what the problem is, where telling us "it does not like this line..." tells us almost nothing.

[Gorpis]

I didn't copy it all, now I am really feeling like an idiot, thank you for your help again and not roasting me!

[mikeyww]

You're not the first to miss the hidden text in a post!