Using Error and OSError objects

[JnLlnd]

I'm just begining the transition to v2. Could someone explain how to use the OSError object?

This is the v1.1 code. The error test is normally to wait until a busy file becomes writable but you can test it here with a read-only file.

Code: Select all

#requires AutoHotkey v1.1
#NoEnv
loop
{
	FileAppend % A_Now . "`n", %A_ScriptDir%\read-only.txt
	if ErrorLevel
		Sleep 20
}
until !ErrorLevel or (A_Index > 50) ; after 1 second (20ms x 50), we have a problem
MsgBox, % (ErrorLevel ? "Error" : "OK")
ExitApp

This is my attempt to convert it to v2 so far. How can I use the OSError object in this context? The doc did not really help me in this case. So far, I've been only able to manage the error with try/catch.

Code: Select all

#requires AutoHotkey v2
err := ""
Loop
{
	Try
		FileAppend(A_Now . "`n", A_ScriptDir . "\read-only.txt")
	catch Error as err
		Sleep(20)
	else
		Break
}
until (A_Index > 50) ; after 1 second (20ms x 50), we have a problem	
if IsObject(err)
	MsgBox(err.Message)
else
	MsgBox("OK")
ExitApp

Any suggestion would be appreciated.

[teadrinker]

Code: Select all

	Try
		FileAppend(A_Now . "`n", A_ScriptDir . "\read-only.txt")
	catch Error as err

Error actually is the OSError object in this case.

[JnLlnd]

Thank for the reply, teadrinker. This could be clarified in the doc. Maybe with an example. I'll post it to the Doc suggestion forum.

So the properties of the Error object are the same as any other Error object (Message, File, Line, etc.)? And my code does not need changes.

[teadrinker]

the properties of the Error object are the same as any other Error object (Message, File, Line, etc.)?

No, the OSError has an additional Number property which contains the error code:

Code: Select all

try FileAppend '', 'S:\nonexistent.file'
catch Error as err {
    MsgBox err.Message . '`n' . err.Number
}

[JnLlnd]

Thanks. I updated my post on the doc suggestion forum.