Where could I get somebody to make me a simple program or code. Or does anybody know if this exists
What I want is a Icon that has a timer on it that resets only if I click in a chosen area of my screen.
- Reset area (customizable)
-Icon changes colour e.g. red default and goes green when a certain time(m/s) has elapsed (colours customizable) (time customizable)
-Icon size (customizable if possible)
-Unminimizable function (stays on top)
-continuous
**Icon doesn't have to show time, just change colours and reset when I last click in chosen area of screen**
**program does not have to look good** just have the functions
Does anybody know where I can go to get this software made
-
- Posts: 1
- Joined: 23 Mar 2023, 13:28
Re: Does anybody know where I can go to get this software made
[Moved to 'Ask For Help']
Windows 10 x64 Professional, Intel i5-8500, NVIDIA GTX 1060 6GB, 2x16GB Kingston FURY Beast - DDR4 3200 MHz | [About Me] | [About the AHK Foundation] | [Courses on AutoHotkey]
[ASPDM - StdLib Distribution] | [Qonsole - Quake-like console emulator] | [LibCon - Autohotkey Console Library]
Re: Does anybody know where I can go to get this software made
Welcome to this AutoHotkey forum!
A bunch of timer scripts have already been posted. That could be a good starting point, providing one or more scripts that you could adapt.
A bunch of timer scripts have already been posted. That could be a good starting point, providing one or more scripts that you could adapt.
Re: Does anybody know where I can go to get this software made
As mikey mentioned, there are plenty of timer scripts that have been setup on these forums. However if you would like some specific work done, I moonlight as an AHK freelancer, writing and providing scripts to people all over the world. If you are interested in taking me up on my services then please send me a DM and I would be happy to help out.
- FanaticGuru
- Posts: 1906
- Joined: 30 Sep 2013, 22:25
Re: Does anybody know where I can go to get this software made
bossdeane2 wrote: ↑23 Mar 2023, 13:50What I want is a Icon that has a timer on it that resets only if I click in a chosen area of my screen.
- Reset area (customizable)
-Icon changes colour e.g. red default and goes green when a certain time(m/s) has elapsed (colours customizable) (time customizable)
-Icon size (customizable if possible)
-Unminimizable function (stays on top)
-continuous
This is not really what you asked for but I already had it in v1 so converted it to v2.
A Stopwatch that can be dragged to move.
Code: Select all
Running := false, Start := A_TickCount, Stop := A_TickCount
MyGui := Gui('+LastFound +E0x02000000 +E0x00080000 -Caption +AlwaysOnTop') ; Double Buffer Style WS_EX_COMPOSITED = True & WS_EX_LAYERED = true
MyGui.BackColor := 'Red'
MyGui.SetFont('s12')
Header := MyGui.Add('Text', 'w225', 'F12 Start/Stop | F11 Reset')
Header.OnEvent('Click', (*) => PostMessage(0xA1, 2))
Header.SetFont('cBlack')
MyGui.SetFont('s36')
Display := MyGui.Add('Text', 'xp+20 yp+25 w225', '0:00:00')
Display.OnEvent('Click', (*) => PostMessage(0xA1, 2))
Display.SetFont('cBlack')
MyGui.Show('w225 h100')
Loop
{
If Running
Display.Text := FormatSeconds(Round((A_TickCount - Start) / 1000, 0))
Sleep 200 ; not used for timing just how often the display is updated
}
F12::
{
Global Running, Start, Stop
If !(Running := !Running)
{
Stop := A_TickCount
MyGui.BackColor := 'Red'
Header.SetFont('cBlack')
Display.SetFont('cBlack')
}
Else
{
Start := Start + (A_TickCount - Stop)
MyGui.BackColor := 'Green'
Header.SetFont('cWhite')
Display.SetFont('cWhite')
}
}
F11::
{
Global Running, Start, Stop
Running := false, Start := A_TickCount, Stop := A_TickCount
MyGui.BackColor := 'Red'
Header.SetFont('cBlack')
Display.SetFont('cBlack')
Display.Text := '0:00:00'
}
FormatSeconds(NumberOfSeconds) ; Convert the specified number of seconds to hh:mm:ss format up to 24 hours.
{
time := 19990101 ; *Midnight* of an arbitrary date.
time := DateAdd(time, NumberOfSeconds, 'seconds')
mmss := FormatTime(time, "mm:ss")
Return NumberOfSeconds // 3600 ":" mmss
}
FG
Hotkey Help - Help Dialog for Currently Running AHK Scripts
AHK Startup - Consolidate Multiply AHK Scripts with one Tray Icon
Hotstring Manager - Create and Manage Hotstrings
[Class] WinHook - Create Window Shell Hooks and Window Event Hooks
AHK Startup - Consolidate Multiply AHK Scripts with one Tray Icon
Hotstring Manager - Create and Manage Hotstrings
[Class] WinHook - Create Window Shell Hooks and Window Event Hooks
- FanaticGuru
- Posts: 1906
- Joined: 30 Sep 2013, 22:25
Re: Does anybody know where I can go to get this software made
Another unasked for timer.
FG
Code: Select all
CountDown(15, 500, 300, 500, "Green", "Red")
Esc::ExitApp
; Original code by Rohwedder
; https://www.autohotkey.com/boards/viewtopic.php?p=315155#p315155
; 2020 09 25 - modified by FanaticGuru to add colors to parameters
; 2023 03 23 - converted to v2
CountDown(No, X:=0, Y:=0, Dia:=100, Color1:="Blue", Color2:="Yellow", Time_No:=1000)
{ ; StartNumber(<1000), Position X,Y, Diameter, Time(>300)/(ms Number)
Static N, SF:= [.60,.44,.31], YF:= [-.06,.08,.22], Guis := ["",""], Text := ["",""]
Colors := [Color1, Color2]
NL := StrLen(N:=Round(No)), Flip := 1, Rad := Dia//2, V := 3*Time_No//100
dP := 8*Atan(1)/V++, T := A_TickCount + Time_No*N
Loop 2
{
Guis[A_Index] := Gui('-DPIScale +LastFound -Caption -SysMenu')
Guis[A_Index].MarginX := 0, Guis[A_Index].MarginY := 0
Guis[A_Index].SetFont('s' Dia * SF[NL] ' c' Colors[A_Index])
Text[A_Index] := Guis[A_Index].Add('Text', 'Center X0 Y' Dia*YF[NL] ' w' Dia ' h' 2*Dia ' vN', N)
Guis[A_Index].BackColor := Colors[3-A_Index]
WinSetRegion('2-2 W' Dia-4 ' H' Dia-4 ' E')
Guis[A_Index].Show('NA w' Dia ' h' Dia ' x' X ' y' Y)
}
While N
{
Guis[(Flip^=3)].Opt('+AlwaysOnTop +LastFound')
Edge:= Rad '-' Rad, P:= -dP
Loop V
{
WinSetRegion(Edge.=' ' Rad*(1+sin(P+=dP)) '-' Rad*(1-cos(P)))
Sleep (T-A_TickCount)//(1+N*V-A_Index)
}
Text[1].Text := --N
Text[2].Text := N
IF StrLen(N) < NL
{
Text[1].SetFont('s' Dia * SF[--NL])
Text[1].Move(, Dia*YF[NL])
Text[2].SetFont('s' Dia * SF[NL])
Text[2].Move(, Dia*YF[NL])
}
}
Guis[1].Destroy()
Guis[2].Destroy()
}
FG
Hotkey Help - Help Dialog for Currently Running AHK Scripts
AHK Startup - Consolidate Multiply AHK Scripts with one Tray Icon
Hotstring Manager - Create and Manage Hotstrings
[Class] WinHook - Create Window Shell Hooks and Window Event Hooks
AHK Startup - Consolidate Multiply AHK Scripts with one Tray Icon
Hotstring Manager - Create and Manage Hotstrings
[Class] WinHook - Create Window Shell Hooks and Window Event Hooks