AutoHotkey script to open video files using timestamp information with PotPlayer

[wretina]

I'm hoping a AutoHotkey script can do the following:

1.Ask me to input the name of a video file (including file extension) and a timestamp (in seconds).
2.Open the specified video file in PotPlayer.
3.Jump to the specified timestamp in the video.

I'm a liberal arts student who is new to AutoHotkey and don't have much experience writing scripts.English is not my native language. I think if this function could be achieved, it would be enormously helpful when it comes to language learning. You can do something like sentence mining with much more detailed context. Much thanks!

[mikeyww]

Welcome to this AutoHotkey forum!

Wow. Thanks for that clear notification about liberal arts. We are now forewarned!

Code: Select all

; This script uses PotPlayer to play a video from a specific timestamp
#Requires AutoHotkey v2.0
MsgBox 'Press F3 to start.', 'Instructions', 64

F3::playMedia

playMedia() {
 Static app    := A_ProgramFiles '\DAUM\PotPlayer\PotPlayerMini64.exe'
 playBtn_Click := (*) => (gui1.Submit(), Run(app ' "' media.Value '" /seek=' startSeconds.Value))
 vidBtn_Click  := (*) => (media.Value := FileSelect(3)) && (startSeconds.Focus(), playBtn.Opt('+Default'))
 gui1          := Gui(, 'Play video'), gui1.SetFont('s10')
 vidBtn        := gui1.AddButton('w100 Default', 'Media file:'), vidBtn.OnEvent('Click', vidBtn_Click)
 gui1.AddText('wp', 'Start (seconds):')
 media         := gui1.AddEdit('w365 ym+2')
 startSeconds  := gui1.AddEdit('w50')
 playBtn       := gui1.AddButton('xm w500', 'Play'), playBtn.OnEvent('Click', playBtn_Click)
 gui1.Show
}

PotPlayer command line:

Code: Select all

Usage: PotPlayerMini64.exe ["content"] [/switch]

"content"	:You can specify a file, folder or URL as content.
                -You can specify multiple contents by separating them with a space.
		-You can specify titles for URLs by separating them with a backslash (\) at the end of URLs. ("http://...\title of this url")
            	-Wildcards (*,?) are allowed.
              	-The setting "Misc > When Files Opened" affects this when a file is specified.

- 		:Plays streaming media from stdin
                -Example usage: youtube-dl.exe -o - -f best[ext=webm] https://www.youtube.com/watch?v=l22sS8DEiVU | PotPlayerMini64.exe -

/filedlg	:Opens the open file dialog box.
/urldlg        	:Opens the open URL dialog box.
/folderdlg	:Opens the open folder dialog box.
/simple	   	:Opens file navigator.
/cap	   	:Runs screen capture.
/cam	   	:Runs webcam/Other devices.
/atv[:ch]	:Runs Analog TV device from the specified channel.
/dtv[:ch[-idx]]	:Runs Digital TV device from the specified channel.
/dvd       	:Runs DVD device.
/cd[:drive]	:Runs the specified drive.
/add		:Appends the specified content(s) into playlist.
/insert		:Inserts the specified content(s) just below the item being played in playlist.(Or adds at the end of playlist if there is nothing playing at the time)
/autoplay 	:Plays the last played item.
/same	   	:Loads and plays the specified contents as multiple streams.
            	-You can independently select loaded video and audio streams under Video/Audio/Filters context menus.
/sort		:Sorts the specified contents by name before adding them into playlist.
/randomize	:Sorts the specified contents by randomly before adding them into playlist.
/new 		:Plays the specified content(s) within a new instance of the program.
                -The setting "F5 > General > Multiple instances" does not affect this.
/current 	:Plays the specified content(s) within an existing instance of the program.
                -The setting "F5 > General > Multiple instances" does not affect this.
/clipboard      :Appends content(s) from clipboard into playlist and starts playback immediately.
/seek=time      :Starts playback of the specified/last played content from the specified time point.
                -time format is: hh:mm:ss.ms (OR specify seconds only e.g. /seek=1800 to start at 30th min)
/sub="subfile"  :Loads the specified subtitle(s) from the specified paths or URLs.
/user_agent="ua":Sets user agent header for HTTP(S) requests.
/referer="ref"  :Sets referer header for HTTP(S) requests.
/headers="hdrs" :Appends the specified header(s) to HTTP(S) requests.
/title="title"  : Use title
config="name"	:Activates the specified preset.