Getting the coordinates of the tray icon? Topic is solved

[william_ahk]

I found TrayIcon_GetPos but it no longer seems to work as it crashes the Explorer. The newest TrayIcon lib doesn't seem to have this function.

[iPhilip]

@william_ahk, would this work for you?

Code: Select all

#Requires AutoHotkey v2.0

RECT := GetTrayIconRECT(A_ScriptHwnd)
MsgBox 'Notification icon`nscreen coordinates:`n`nLeft:`t' RECT.Left '`nTop:`t' RECT.Top '`nRight:`t' RECT.Right '`nBottom:`t' RECT.Bottom

GetTrayIconRECT(hwnd) {
   static AHK_NOTIFYICON := 0x0404
   static Size := 16 + 3 * A_PtrSize
   NOTIFYICONIDENTIFIER := Buffer(Size, 0)
   NumPut 'UInt', Size, NOTIFYICONIDENTIFIER, 0
   NumPut 'Ptr',  hwnd, NOTIFYICONIDENTIFIER, A_PtrSize
   NumPut 'UInt', AHK_NOTIFYICON, NOTIFYICONIDENTIFIER, 2 * A_PtrSize
   if !DllCall('Shell32\Shell_NotifyIconGetRect', 'Ptr', NOTIFYICONIDENTIFIER, 'Ptr', RECT := Buffer(16), 'HRESULT')
      return {Left: NumGet(RECT, 0, 'Int'), Top: NumGet(RECT, 4, 'Int'), Right: NumGet(RECT, 8, 'Int'), Bottom: NumGet(RECT, 12, 'Int')}
}

[william_ahk]

@iPhilip It says unspecified error at this line if !DllCall('Shell32\Shell_NotifyIconGetRect', 'Ptr', NOTIFYICONIDENTIFIER, 'Ptr', RECT := Buffer(16), 'HRESULT')

[iPhilip]

@william_ahk, Thank you for reporting the error. I fixed the issue by initializing the NOTIFYICONIDENTIFIER buffer to zero so that the requirement

Use GUID_NULL if the icon is not identified by a GUID.

is always met. It should work more reliably now.

Cheers!

[william_ahk]

@iPhilip Thank you so much! Works great. I incorporated a TrayIcon version:

Code: Select all

TrayIcon_GetPos(hwnd, uID) {
  static Size := 16 + 3 * A_PtrSize
  NID := Buffer(Size, 0)
  NumPut("UInt", Size, NID, 0)
  NumPut("Ptr", hWnd, NID, A_PtrSize)
  NumPut("UInt", uID, NID, A_PtrSize * 2)
  if !DllCall("Shell32\Shell_NotifyIconGetRect", "Ptr", NID, "Ptr", RECT := Buffer(16), "HRESULT")
    return {Left: NumGet(RECT, 0, "Int"), Top: NumGet(RECT, 4, "Int"), Right: NumGet(RECT, 8, "Int"), Bottom: NumGet(RECT, 12, "Int")}
}