[v2] Example #1 in the ComObjQuery page Topic is solved

[iPhilip]

Example #1 in the ComObjQuery documentation page should be changed as follows (look for the <--- mark):

Code: Select all

obj := ComObjCreate("Scripting.Dictionary")

MsgBox "Interface name: " ComObjType(obj, "name")

IID_IProvideClassInfo := "{B196B283-BAB4-101A-B69C-00AA00341D07}"

; Request the object's IProvideClassInfo interface.
try
    pci := ComObjQuery(obj, IID_IProvideClassInfo)
catch
{
    MsgBox "IProvideClassInfo interface not supported."
    return
}

; Call GetClassInfo to retrieve a pointer to the ITypeInfo interface.
ComCall(3, pci, "ptr*", &ti := 0)  ; <--- changed ti to &ti

; Wrap ti to ensure automatic cleanup.
ti := ComObject(13, ti)

; Call GetDocumentation to get the object's full type name.
ComCall(12, ti, "int", -1, "ptr*", &pname := 0, "ptr", 0, "ptr", 0, "ptr", 0)  ; Parameter #2 of ComCall is invalid.  <--- changed pname to &pname

; Convert the BSTR pointer to a usable string.
name := StrGet(pname, "UTF-16")

; Clean up.
DllCall("oleaut32\SysFreeString", "ptr", pname)
pci := ti := ""

; Display the type name!
MsgBox "Class name: " name

[iPhilip]

Below are links to additional pages that have similar issues:

https://github.com/Lexikos/AutoHotkey_L-Docs/blob/4bf827d226e75cb1e1aa44643318c2d6caa3d4c0/docs/commands/ComObjQuery.htm#L109
https://github.com/Lexikos/AutoHotkey_L-Docs/blob/4bf827d226e75cb1e1aa44643318c2d6caa3d4c0/docs/commands/DllCall.htm#L236-L239
https://github.com/Lexikos/AutoHotkey_L-Docs/blob/4bf827d226e75cb1e1aa44643318c2d6caa3d4c0/docs/commands/DllCall.htm#L258
https://github.com/Lexikos/AutoHotkey_L-Docs/blob/4bf827d226e75cb1e1aa44643318c2d6caa3d4c0/docs/commands/DllCall.htm#L300
https://github.com/Lexikos/AutoHotkey_L-Docs/blob/4bf827d226e75cb1e1aa44643318c2d6caa3d4c0/docs/commands/DllCall.htm#L316
?? https://github.com/Lexikos/AutoHotkey_L-Docs/blob/4bf827d226e75cb1e1aa44643318c2d6caa3d4c0/docs/commands/DriveEject.htm#L78
https://github.com/Lexikos/AutoHotkey_L-Docs/blob/4bf827d226e75cb1e1aa44643318c2d6caa3d4c0/docs/commands/Process.htm#L60
https://github.com/Lexikos/AutoHotkey_L-Docs/blob/4bf827d226e75cb1e1aa44643318c2d6caa3d4c0/docs/commands/Process.htm#L62
https://github.com/Lexikos/AutoHotkey_L-Docs/blob/4bf827d226e75cb1e1aa44643318c2d6caa3d4c0/docs/commands/Process.htm#L77
?? https://github.com/Lexikos/AutoHotkey_L-Docs/blob/4bf827d226e75cb1e1aa44643318c2d6caa3d4c0/docs/commands/WinSetRegion.htm#L72-L77

[Ragnar]

Thanks for reporting. The changes are included in PR #473. Note that ComObjQuery.htm#L109 and WinSetRegion.htm#L72-L77 are still functional without &.

[iPhilip]

Thank you, @Ragnar.