Array mit Schlüsselvariable wird nicht aufgelöst,... Topic is solved

[BoBo]

...nun, eigentlich nach Fahrzeugblinker-Prinzip. Geht mal, geht mal nicht.

Ziel, Dateien sollen abhängig von deren Dateiendungen mit einem zugewiesenen Programm gestartet werden. Quasi ein registry-unabhängiges file-extension-assignment.
Verwaltet werden die Extension-Application-Paarungen in einem assoziativen Array.
Anwendung: im Windows Explorer werden beliebige Dateien ausgewählt (eine *.txt,*.ahk-Datei sollte schon dabei sein!).
Hotkey betätigen: F12.
Im Ergebnis wird interessanterweise für *.txt wie erwartet Run notepad.exe <dateipfad> angezeigt, für *.ahk, *.csv jedoch ausschließlich der Dateipfad Run <dateipfad>!?

Was übersehe ich hier?

Code: Select all

#SingleInstance, Force

fIndex:= {"xls":"excel.exe"
         ,"txt":"notepad.exe"
         ,"bmp":"paint.exe"
         ,"ahk":"autohotkey.exe"
         ,"csv":"notepad.exe"}

F12::
   clipboard:=""
   Send +{F10}p                                             ; ruft explorer kontextmenü auf und kopiert die pfade von ausgewählten dateien 
   ClipWait                                                 ; ...in die Zwischenablage
   files := StrReplace(clipboard,"""","")                   ; entfernt alle Anführungszeichen aus den (multiplen) pfadangaben
   file := StrSplit(files,"`n")                             ; (multiple) pfade in array transferieren
   Loop % file.Count()                                      ; einzelne Pfade prozessieren
         {  SplitPath,% file[A_Index],,, ext                ; liefert die ext (z.B. 'ahk') aus dem dateipfad
            MsgBox % ext "`nRun " . fIndex[ext] . " " . file[A_Index]
         }
Return

[KHA]

file := StrSplit(files,"`n", "`r") ; Beachten Zeilenumbrüche in Windows bestehen aus `r`n

Code: Select all

#SingleInstance, Force

fIndex:= {"xlsx":"excel.exe"
         ,"txt":"notepad.exe"
         ,"jpg":"paint.exe"
         ,"ahk":"autohotkey.exe"
         ,"csv":"notepad.exe"}

F12::
   clipboard:=""
   Send +{F10}p                                             ; ruft explorer kontextmenü auf und kopiert die pfade von ausgewählten dateien 
   ClipWait                                                 ; ...in die Zwischenablage
   files := StrReplace(clipboard,"""","")                   ; entfernt alle Anführungszeichen aus den (multiplen) pfadangaben
   file := StrSplit(files,"`n", "`r")                             ; Beachten Zeilenumbrüche in Windows bestehen aus `r`n
   Loop % file.Count()                                      ; einzelne Pfade prozessieren
         {  SplitPath,% file[A_Index],,, ext                ; liefert die ext (z.B. 'ahk') aus dem dateipfad
            MsgBox % ext "`nRun " . fIndex[ext] . " " . file[A_Index]
         }
Return

[BoBo]

Merci. Hab’s noch nicht ausprobiert (da tablet mit iOS), …doch stellt sich mir ad-hoc die Frage: "warum war das fehlende `r für die *.txt Dateiendung kein Problem, doch für *.csv schon, wo doch beide mit "notepad.exe" retourniert werden sollten?!
Wie in der subject line/dem Titel bereits angesagt, das Problem besteht nicht wenn das array statisch abgefragt wird:

Code: Select all

MsgBox % file.ahk ; gibt korrekt autohotkey.exe aus
MsgBox % file[ext] ; wobei ext = ahk, scheitert

Erklärt sich mir aus dem Hinzufügen des "`r" (bisher) nicht

[just me]

Moin @BoBo,

starte mal das folgende Skript, markiere ein paar Dateien im einem Explorerfenster und drücke F12.

Code: Select all

#NoEnv
#SingleInstance, Force

F12::
   clipboard:=""
   Send +{F10}p                                             ; ruft explorer kontextmenü auf und kopiert die pfade von ausgewählten dateien
   ClipWait                                                 ; ...in die Zwischenablage
   files := StrReplace(clipboard,"""","")                   ; entfernt alle Anführungszeichen aus den (multiplen) pfadangaben
   files := StrReplace(files,"`r","#")
   MsgBox, %files%
return

An der letzten Datei im Clipboard hängt kein Zeilenwechsel (`r`n). Deshalb kann nach Deinem StrSplit(files,"`n") auch kein `r übrig bleiben. Soll heißen, für die letzte Datei klappt es.

[BoBo]

@just me & @KHA - Danke Euch. Das "Enttarnen" der CR's macht's dann tatsächlich greifbar(er) Und es funzt jetzt