Daten aus editfeldern und checkboxen in Ausgabe kopieren Topic is solved

Stelle Fragen zur Programmierung mit Autohotkey

Moderator: jNizM

tschammay

Daten aus editfeldern und checkboxen in Ausgabe kopieren

Post by tschammay » 28 Jan 2023, 11:23

Ich möchte Daten zusammen tragen um sie dann weiter zu kopieren. Aber ich komme nicht so richtig weiter.
Die gesammelten Daten sollen in das Ausgabe feld geschrieben werden.

bisher hab ich folgendes:
bei zeile 46 meckert er dass wegen der variablen ein prozentzeichen fehlt, das geht bei den checkboxen dann bestimmt weiter

Code: Select all

Gui, Font, S12 CDefault Bold, Verdana
Gui, Add, Text, x61 y105 w110 h20 , Wohnort
Gui, Add, Text, x231 y75 w100 h50 , Vitbikes Standort
Gui, Add, Text, x231 y5 w140 h20 , Nachname
Gui, Add, Text, x61 y5 w140 h20 , Vorname
Gui, Add, Edit, x61 y35 w150 h30 , vorname
Gui, Add, Edit, x231 y35 w190 h30 , nachname
Gui, Add, Edit, x231 y135 w190 h30 , wohnort
Gui, Add, Edit, x61 y135 w150 h50 , vitbikesstandort
Gui, Add, Edit, x801 y55 w380 h630 , Ausgabe
Gui, Add, Text, x61 y225 w110 h30 , Größe
Gui, Add, Edit, x231 y225 w190 h30 , groesse
Gui, Add, Text, x61 y265 w110 h30 , Alter
Gui, Add, Edit, x231 y265 w190 h30 , alter
Gui, Add, Text, x61 y305 w110 h30 , Gewicht
Gui, Add, Edit, x231 y305 w190 h30 , gewicht
Gui, Add, Text, x61 y345 w140 h30 , Beschwerden
Gui, Add, Edit, x231 y345 w190 h30 , beschwerden
Gui, Add, CheckBox, x51 y385 w70 h20 , Knie
Gui, Add, CheckBox, x131 y385 w110 h20 , Rücken
Gui, Add, CheckBox, x241 y385 w180 h50 , Einschlafende Hände
Gui, Add, Text, x61 y455 w120 h30 , Text
Gui, Show, x378 y141 h844 w1339, New GUI Window

Gui, Submit, NoHide
vorname := GuiControlGet(vorname)
nachname := GuiControlGet(nachname)
wohnort := GuiControlGet(wohnort)
vitbikesstandort := GuiControlGet(vitbikesstandort)
groesse := GuiControlGet(groesse)
alter := GuiControlGet(alter)
gewicht := GuiControlGet(gewicht)
beschwerden := GuiControlGet(beschwerden)
knie := GuiControlGet(knie)
ruecken := GuiControlGet(ruecken)
einschlafende_haende := GuiControlGet(einschlafende_haende)

GuiControl,, Ausgabe, % "Vorname: " vorname "n" "Nachname: " nachname "n" "Wohnort: " wohnort "n" "Vitbikes Standort: " vitbikesstandort "n" "Größe: " groesse "n" "Alter: " alter "n" "Gewicht: " gewicht "n" "Beschwerden: " beschwerden "n"

; CheckBox abfragen


if knie {
GuiControl,, Ausgabe, % "Knie: Ja" % } else { GuiControl,, Ausgabe, % "Knie: Nein" %
}

if rücken {
GuiControl,, Ausgabe, % "Rücken: Ja" } else { GuiControl,, Ausgabe, % "Rücken: Nein" %
}

GuiControl,, Ausgabe, % "Einschlafende Hände: Ja" } else { GuiControl,, Ausgabe, % "Einschlafende Hände: Nein" %
}
Return
gui close
ExitApp

[Moderator-Edit: Code-Tags hinzugefügt.]

Rohwedder
Posts: 7551
Joined: 04 Jun 2014, 08:33
Location: Germany

Re: Daten aus editfeldern und checkboxen in Ausgabe kopieren  Topic is solved

Post by Rohwedder » 29 Jan 2023, 03:00

Hallo,
versuche:

Code: Select all

JaNein := {0:" Nein", 1:" Ja"}
Gui, Font, S12 CDefault Bold, Verdana
Gui, Add, Text, x61 y105 w110 h20 , Wohnort
Gui, Add, Text, x231 y75 w100 h50 , VitbikesStandort
Gui, Add, Text, x231 y5 w140 h20 , Nachname
Gui, Add, Text, x61 y5 w140 h20 , Vorname
Gui, Add, Edit, x61 y35 w150 h30 vvorname gOK, vorname
Gui, Add, Edit, x231 y35 w190 h30 vnachname gOK, nachname
Gui, Add, Edit, x231 y135 w190 h30 vwohnort gOK, wohnort
Gui, Add, Edit, x61 y135 w150 h50 vvitbikesstandort gOK, vitbikesstandort
Gui, Add, Edit, x801 y55 w380 h630 vAusgabe, Ausgabe
Gui, Add, Text, x61 y225 w110 h30 , Größe
Gui, Add, Edit, x231 y225 w190 h30 vgroesse gOK, groesse
Gui, Add, Text, x61 y265 w110 h30 , Alter
Gui, Add, Edit, x231 y265 w190 h30 valter gOK, alter
Gui, Add, Text, x61 y305 w110 h30 , Gewicht
Gui, Add, Edit, x231 y305 w190 h30 vgewicht gOK, gewicht
Gui, Add, Text, x61 y345 w140 h30 , Beschwerden
Gui, Add, Edit, x231 y345 w190 h30 vbeschwerden gOK, beschwerden
Gui, Add, CheckBox, x51 y385 w70 h20 vKnie gOK, Knie
Gui, Add, CheckBox, x131 y385 w110 h20 vRücken gOK, Rücken
Gui, Add, CheckBox, x241 y385 w180 h50 vEinschlafendeHände gOK, EinschlafendeHände
Gui, Add, Text, x61 y455 w120 h30 , Text
Gui, Show, x378 y141 h844 w1339, New GUI Window
Return
OK:
Gui, Submit ,NoHide
Ausgabe := "Vornname: " vorname "`r`nNachname: " nachname "`r`nWohnort: " wohnort "`r`nVitbikes Standort: " vitbikesstandort "`r`nGröße: " groesse "`r`nAlter: " alter "`nGewicht: " gewicht "`nBeschwerden: " beschwerden "`n"
; CheckBox abfragen
Ausgabe .= "`r`nKnie:" JaNein[Knie]
Ausgabe .= "`r`nRücken:" JaNein[Rücken]
Ausgabe .= "`r`nEinschlafende Hände:" JaNein[EinschlafendeHände]
GuiControl,, Ausgabe, %Ausgabe% ; aktualisieren
Gui, Show
Return

tschammay

Re: Daten aus editfeldern und checkboxen in Ausgabe kopieren

Post by tschammay » 29 Jan 2023, 05:24

Danke !!!!
das passt schonmal und ist relativ simpel im vergleich zu meinem script

Jetzt würde ich das ganze noch erweitern Meine Frage hierzu:
Hast du das alles von Hand geändert oder gibts da nen Tip ? Ich hab noch etliche Felder mehr.
Habe es mit Chat gpt probiert aber die Ki ist zu doof das zu erledigen ;-)

tschammay

Re: Daten aus editfeldern und checkboxen in Ausgabe kopieren

Post by tschammay » 29 Jan 2023, 07:40

Ich hab es jetzt von Hand gemacht..und das ganze einigermaßen verstanden.
Die Ausgabe der Checkboxen soll allerdings so gestaltet sein, dass wenn diese angehakt sind nur der text erscheint in der ausgabe
Also Trail ist angehakt dann soll einfach nur Trail stehen ohne ja oder 1
Ich habe die Ausgabe der checkboxen einfach so gemacht wie bei den editfeldern aber jetzt steht halt 1 dahinter oder 0
Aber es soll eben Trail dran stehen oder eben nicht, wenn nicht angehakt.

Dann habe ich noch schwierigkeiten mit den dropdownfeldern. Hier ist mir die Syntax zum befüllen nicht klar

Gui, Add, DropDownList, x551 y105 w140 h30 vJobrad gOK, Jobrad `nBusinessbike

funktioniert so nicht die Beschriftung ist wohl das was ich geändert habe aber nicht die Auswahldaten

Schon mal besten Dank für die Mühe !

Rohwedder
Posts: 7551
Joined: 04 Jun 2014, 08:33
Location: Germany

Re: Daten aus editfeldern und checkboxen in Ausgabe kopieren

Post by Rohwedder » 29 Jan 2023, 08:18

Ich verwende zum Editieren Notepad++. Dieser kann zwar “Suchen und Ersetzen” mittels regulären Ausdrücken, siehe: https://medtech-ingenieur.de/wildcards-in-notepad-effizient-suchen-und-ersetzen+
Mir reichten hier jedoch Wildcards und etwas Handarbeit.

Also Trail ist angehakt dann soll einfach nur Trail stehen ohne ja oder 1

Code: Select all

Ausgabe = BlaBla
Trail = 0 ; (nicht angehakt)
Ausgabe .= [" Trail"][Trail]
MsgBox,% Ausgabe ; BlaBla
Trail = 1  ; (angehakt)
Ausgabe .= [" Trail"][Trail]
MsgBox,% Ausgabe ; BlaBla Trail
Zur DropDownList, da müßte ich mich auch erst einlesen.
https://ahkde.github.io/docs/v1/lib/GuiControls.htm#DropDownList

tschammay

Re: Daten aus editfeldern und checkboxen in Ausgabe kopieren

Post by tschammay » 29 Jan 2023, 08:50

Also das Dropdownlist hab ich mittlerweile gelöst da müssen so striche I dazwischen ;-)

aber mit deiner erklärung komm ich nicht ganz zurecht
Ausgabe .= "`r`nRuecken:" JaNein[Ruecken]
war ja bisher
Ausgabe .= "`r`n["Knie"][Knie]
wäre dann jetzt richtig aber da fehlt mir der wo ich nicht verstehe wie ich das schreiben soll

GuiControl,, Ausgabe, %Ausgabe% ; aktualisieren
Gui, Show

kommt dann nach den ganzen checkboxen einmal für alle

Könntest du mir bitte eine korrekte Zeile schreiben ? dann kann ich die anderen schon umbauen.

tschammay

Re: Daten aus editfeldern und checkboxen in Ausgabe kopieren

Post by tschammay » 29 Jan 2023, 09:43

Hab es hinbekommen ;-)
if (Knie)
Ausgabe .= "`nKnie"

das ist der ganze Zauber :D

Post Reply

Return to “Ich brauche Hilfe”