Variable aus String (Edit) mit Dezimalstellen erzeugen Topic is solved

[Optimus Prime]

Hallo Zusammen,

nun stolpere ich gerade über das Komma bei AHK. Ich möchte gerne aus einem String, der in ein Edit (vEingabe) eingegeben werden sollte, eine Dezimalzahl herausholen.
Der String lautet z.B.: 12345
Die Variable soll nun aber die Dezimalzahl 123,45 enthalten, um damit weiter rechnen zu können.

Ich habe mal begonnen im Skript ersteinmal 2 Variablen zu erstellen und diese mit " . " verbunden.

Code: Select all

Var1 := Substr(Eingabe, 1, 3)
Var2 := Substr(Eingabe, 4, 2)

Var3 := Var1 . Var2

Dies führt dazu dass, die komplette Zahl wieder zusammengefügt wird, ein Komma lässt sich dort nicht einfügen!
Welche Möglichkeiten gibt es hier eine Dezimalzahl aus dem String zu erzeugen?

[jNizM]

Warum schreibst du nicht die Zahl mit Dezimaltrenner ins Edit-Feld?
Desweiteren brauchst du, um in AHK mit Zahlen zu rechnen den "." als Trenner.

Ich mach das, indem ich die Zahl dann mit StrReplace von , auf . switche. So kann man oben im Edit-Feld beides benutzen, aber das Rechnen geht mit AHK.

ZahlNeu := StrReplace(ZahlAlt, "`,", ".")


z.B.

Code: Select all

Gui, Margin, 10, 10
Gui, Add, Text, xm ym   w200, % "Mit StrReplace von , auf ."
Gui, Add, Edit, xm y+5  w200 gCALC1 vEdt1
Gui, Add, Edit, xm y+5  w200 gCALC1 vEdt2
Gui, Add, Edit, xm y+10 w200 vEdt3

Gui, Add, Text, x+10 ym w200, % "Ohne StrReplace von , auf ."
Gui, Add, Edit, xp y+5  w200 gCALC2 vEdt4
Gui, Add, Edit, xp y+5  w200 gCALC2 vEdt5
Gui, Add, Edit, xp y+10 w200 vEdt6

Gui, Show, AutoSize
return

GuiClose:
GuiEscape:
ExitApp

CALC1:
	Gui, Submit, NoHide
	Edt1 := StrReplace(Edt1, "`,", ".")
	Edt2 := StrReplace(Edt2, "`,", ".")
	GuiControl,, Edt3, % Edt1 + Edt2
return

CALC2:
	Gui, Submit, NoHide
	GuiControl,, Edt6, % Edt4 + Edt5
return

Bei beiden kannst du zwar die Zahl mit Komma eintragen, aber nur mit StrReplace zu Punkt kannst du dann in AHK rechnen.

[KHA]

Ich weiß nicht, ob ich dich richtig verstehe, aber ein Komma zwischen 2 Variable, erzeugst du so:

Code: Select all

Eingabe := 12345
Var1 := Substr(Eingabe, 1, 3)
Var2 := Substr(Eingabe, 4, 2)

Var3 := Var1 . "," . Var2
MsgBox, % var3

[jNizM]

Aber falls es wirklich so ist, dass du eine Zahl ohne Dezimaltrenner kopierst und die letzten zwei Zahlen getrennt werden, dann ja so wie KHA es gezeigt hat.

[Optimus Prime]

Danke ihr 2. So funktioniert es bestens. Der Tip mit StrReplace passt mir da sehr gut rein.
Das Komma ist beim Kopieren des Strings leider nicht vorhanden, deshalb will ich es in die Anwendung basteln

[effel]

Code: Select all

Eingabe := 32145
Eingabe := StrReplace(Eingabe, Substr(Eingabe, 4, 2), "," Substr(Eingabe, 4, 2))
MsgBox, % Eingabe ; 321,45

Code: Select all

Eingabe := 1234567890
Eingabe := StrReplace(Eingabe, Substr(Eingabe, -1), "," Substr(Eingabe, -1))
MsgBox, % Eingabe ; 12345678,90

[just me]

@effel, schau mal:

Code: Select all

#NoEnv
Str := 123123123
Dez := SubStr(Str, 1, -2) . "," . SubStr(Str, -1)
MsgBox, %Dez%

Eingabe := 123123123
Eingabe := StrReplace(Eingabe, Substr(Eingabe, -1), "," Substr(Eingabe, -1))
MsgBox, %Eingabe%

[haichen]

Der String lautet z.B.: 12345
Die Variable soll nun aber die Dezimalzahl 123,45 enthalten, um damit weiter rechnen zu können.

Ich hab vielleicht irgendwas nicht verstanden, aber für mich wäre das hier die Lösung:

Code: Select all

str := 123123123
zahl:=str/100

[effel]

Danke Just Me

so?

Code: Select all

Eingabe := 123456 ; 1234,56
Eingabe := Substr(Eingabe, 1, StrLen(Eingabe)-2) "," Substr(Eingabe, StrLen(Eingabe)-1, 2)
MsgBox, % Eingabe
Eingabe := 123123123123 ; 1231231231,23
Eingabe := Substr(Eingabe, 1, StrLen(Eingabe)-2) "," Substr(Eingabe, StrLen(Eingabe)-1, 2)
MsgBox, % Eingabe

oder mit BoBo`s Thousand/Tausend Separator:

Code: Select all

Eingabe := 1234567890
Eingabe := Substr(Eingabe, 1, StrLen(Eingabe)-2) "," Substr(Eingabe, StrLen(Eingabe)-1, 2)
MsgBox, % ts(Eingabe) ; 12.345.678,90

ts(number) { ; https://www.autohotkey.com/boards/viewtopic.php?f=10&t=77399
	Static E, UD													; muß static oder global deklariert werden 
	dcpl:=	InStr(number,",") ? (StrSplit(number,","), del := ",")	; evtl vorhandene nachkommastellen ermitteln
		:	InStr(number,".") ?	(StrSplit(number,"."), del := ".")	; ... decimal place (anglo-american style). 
		:	""
	Gui, Add, Edit, vE												; 'buddy-control' des folgenden UD. Diese variable enthält den ts-formatierten wert.
	Gui, Add, UpDown, Range-2147483648-2147483647 vUD, % number		; vUD = unformatierter wert: https://ahkde.github.io/docs/commands/GuiControls.htm#UpDown  
	GuiControlGet, ConvNo,, E										; abfrage des ts-formatierten wertes 
	Gui, Destroy													; Nero-Befehl
	Return ConvNo . del . dcpl[2]									; rückgabe des ts-formatierten wertes (mit ggf nachkommastellen)
	}

[haichen]

Hi Effel,
würde mich mal interessieren, warum man den Eingabewert nicht einfach durch 100 teilen kann?
Im Eingang steht doch sogar, dass man mit dem Ergebnis weiterrechnen will. Das geht mit keiner der anderen Varianten.
Autohotkey behandelt den Zahlenstring der Eingabe als Zahl.
In der Hilfe steht: "Numerische Zeichenketten: Eine Kette von Zahlen (oder von anderen unterstützten Zahlenformaten) wird automatisch als Zahl interpretiert, wenn eine mathematische Operation oder ein Vergleich dies erfordert."

Code: Select all

Eingabe := 123456
Eingabe:= Eingabe/100
MsgBox, % Eingabe ; =>1234.560000
;Formatiert:
MsgBox, %  "Formatiert: " Format("{:.2f}", Eingabe) " oder gerundet: " Round(Eingabe, 2) ; =>1234.56

[haichen]

Um ins deutsche Format mit Punkt als Tausendertrenner und dem Komma für die Dezimalstellen zu formatieren hier noch der Link zu einer von jNizM wunderbaren Funktionen:
https://www.autohotkey.com/boards/viewtopic.php?p=56006#p56006