I need a Randomized AC Topic is solved

[CR3ALITY]

I need a Randomized auto clicker that clicks between 10-20cps (Approx.)
toggled on/off using R
If possible, It can be switched to right clicking by pressing ( ` )
Can anyone help?

[Spawnova]

Code: Select all

#if toggle   ;these hotkeys are only active if toggle = 1
~*esc::      ;remove the ~ from these hotkeys if you want to block the original function
~*t::
~*e::
~*enter::
toggle := 0
settimer,clicker,off
return
#if  ;all hotkeys below are  active regardless

*r::
toggle := !toggle ;toggles clicking on and off
rclick := 0 ;do not perform right clicks
settimer,clicker,% (toggle ? 10 : "off") ;set a timer on if toggled of off if not
return

*`::rclick := !rclick  ;change from left clicks to right clicks, or back to left


clicker:
if (nextClick < a_tickcount) {
	click % (rclick ? "right" : "left") ;click either left or right
	nextClick := a_tickcount + random(50,100) ;the next click will happen between 50-100ms after this
}
return

Random(min,max:=100) {
	random,r,% min,% max
	return r
}

f8::exitapp  ;remove these if you don't need them
f9::reload

[CR3ALITY]

It works perfectly. I want it to be toggled off when I press Esc, T, E, or Enter. How can I add it to this code?

[Spawnova]

I've updated my earlier post with a new script which can do that.

I've added hotkeys with a ~ symbol which means when you press the hotkeys the original function of that key is NOT blocked, if you do not want this then delete the ~ from the hotkeys

[CR3ALITY]

Thank you for helping me out, I truly appreciate the help