热键之组合键与序列键

供新手入门和老手参考的教程和相关资料,包括中文帮助

Moderators: tmplinshi, arcticir

Post Reply
User avatar
amnesiac
Posts: 186
Joined: 22 Nov 2013, 03:08
Location: Egret Island, China
Contact:

热键之组合键与序列键

Post by amnesiac » 17 Aug 2014, 23:13

在系统中热键是一种有限资源,如何安排热键让它的高效真正发挥出来,可能需要进行多方面的思考和操作,例如对热键进行规划、对需求分类,以最方便的按键实现最需要热键实现的功能,同时适当兼顾热键的记忆问题。舒适便捷的按键及组合非常稀缺,除了系统和程序自带热键(是否覆盖需依实际情况而定),如何利用这些按键更好地实现较多常用操作呢?下面提供实现热键的一些常见方式。

组合键

修饰键符号

Code: Select all

#n::WinMinimize, A ; 最小化活动窗口。
这个组合键中,# 是修饰键,表示 Windows 键。除了这个外,其他修饰键还有 ^(表示 Ctrl 键)、+(表示 Shift 键)、!(表示 Alt 键)。这四个修饰键有何共同点?它们都使用单个符号表示(方便热键编写),且这几个符号都是上档字符(下档字符表示自身按键)。

这四个修饰键本身还可组合,可增加舒适按键组合的数量。对于目标操作,一般建议有某种暗示含义的行为,如 Windows 键,我们会想起什么?除了系统功能,一般会想到窗口了,而在窗口的系统菜单中,n 就是那个快捷键,上面这个例子记忆成本(覆盖系统原热键时建议考虑这点)接近于零。

Code: Select all

^+n::Run, Notepad.exe  ; 打开记事本。
它们构成的组合键一般单手或左右手操作都比较方便,应优先考虑。

自定义组合键

仅有四个修饰键是不够的:一方面很多修饰键组合已被利用,第二有些组合用起来也麻烦,如包含了三个修饰键的组合键。不过 AutoHotkey 把修饰键的范围从这四个扩大到了几乎每个按键甚至鼠标和游戏杆按钮(普通按键或鼠标按钮作为修饰键使用时会自动使用钩子,可从 ListHotkeys 界面中观察验证):

Code: Select all

a & k::MsgBox 您在按住 a 时按下了 k 键。
这里字母 a 成了修饰键,这个组合相对而言还是较为方便的。不过成为修饰键后单独按 a 则不再会输入 a 了,怎么办?

Code: Select all

a::Send, a ; 发送模拟按键 a。
这样 a 还是 a,不会影响我们的输入,尽管与原来有细微差别(在弹起时触发)。

按键修饰符

在实际情况中,通常需要对热键进行某种限制,例如上面的热键 a,由于发送的模拟按键 a 还会触发这个热键,这样后果可能很严重。为了避免这种情况:

Code: Select all

$a::Send, a ; 发送模拟按键 a。
$ 表示使用钩子创建这个热键,这样避免了循环激发(上面的例子有人实际操作了吗)。更多修饰符请参阅帮助。

序列键

Code: Select all

::btw::by the way ; 输入 btw 后替换为 by the way。
依次按下 b、t、w 三个按键后,输入了 by the way。当然,实际上还需要个终止符(如空格)才行,不过也可避免:

Code: Select all

:*:r@::[email protected] ; 输入 r@ 后自动替换为邮件地址。
这里的选项在第一对引号的两个中间,更多选项请参阅帮助中热字串和自动替换部分。这里的热字串实现了自动替换,实际中可用于扩展缩写、纠正拼写错误等。不过,热字串也可以执行命令:

Code: Select all

::btw::
MsgBox, 您刚刚输入了“btw”。
return
通过序列键我们又多了许多热键的选择,尤其是常用且方便的字母键。
使用 Vim 的朋友可能注意到,这里的序列键和 Vim 中的热键很相似,但它们是有区别的:这里的序列键都必须是按键,而 Vim 中的序列热键可以包含大写字母或上档字符(需通过 CapsLock 或 Shift 输入),如复制热键 "+y

原理

每一次按键,在系统中包含了两次的按键事件:
20140805000.png
按键历史
红色背景区域的内容表示我按了一次 h 键:先按下,后松开。为了方便,暂且表示为 {h down}{h up}。这说明什么?

在组合键 a & k:: 中,可以表示为:{a down}{k down}{k up}{a up}

而序列键 ::ak:: 中,可以表示为:{a down}{a up}{k down}{k up}

所以序列键的含义是,有序按下的热键组合。所以尽管热键和热字串在语法形式上有所区别,实际上原理类似的,可统一理解。

而且,一个按键有两个事件,那么两个按键能实现多少种热键呢?动手排列组合吧(注:一个按键的按下事件总是在弹起事件之前)。如果对这方面有较大兴趣,请搜索“小仙并击”,这里不进一步引申。
AutoHotkey 学习指南(Beauty of AutoHotkey)
I do not make codes, and only a porter of AutoHotkey: from official to Chinese, from other languages to AutoHotkey, and show AutoHotkey to ordinary users sometimes.
snail09
Posts: 1
Joined: 11 Jun 2021, 23:40

Re: 热键之组合键与序列键

Post by snail09 » 11 Jun 2021, 23:44

Code: Select all

#IfWinActive ahk_class Notepad++
space & m::
WinMinimize ahk_class Notepad++
space::Send, {Space}

#IfWinNotActive ahk_class Notepad++
space & m::
Run, Notepad++
WinRestore ahk_class Notepad++
space::Send, {Space}
有2个bug:
每次空格+m后,会触发一个多余的空格。应该是“space::Send, {Space}”的问题,但不加这个的话,空格本来的功能就受到影响了
任务管理器在前台的时候,空格+m失效了,无法将notepad++置为前台

麻烦大佬帮忙看看怎么修改才好
User avatar
Zach47
Posts: 13
Joined: 15 Nov 2021, 10:05

Re: 热键之组合键与序列键

Post by Zach47 » 13 Apr 2022, 11:35

@snail09
我看你的例子,应该是想通过组合键「Space+M」来实现打开或最小化一个记事本软件。以下是一段代码,以供参考。

Code: Select all

Space::Space ;维持空格键的功能。

#IfWinActive ahk_class Notepad ;如果记事本已打开,则最小化它。
Space & m::
    WinMinimize ahk_class Notepad
    return

#IfWinNotActive ahk_class Notepad ;如果记事本处于非活动状态,则打开它或最大化它。
Space & m::
    if not WinExist("ahk_class Notepad")
    {
        run, notepad.exe ;打开记事本。
        return       
    }
    WinRestore ahk_class Notepad  ;最大化记事本。
    return
Post Reply

Return to “教程资料”