How to call JS code in a script?

afe · 21 Apr 2019, 12:50

Hello,

If a JS function source code is assigned to a variable, how to call this JS function in a script?

For example, the JS (x, y) function is JS code, how to call it?

Code: Select all

JS := "JS(x, y){          JS code here            }"

Thanks.

wolf_II · 21 Apr 2019, 13:40

check out: https://www.autohotkey.com/boards/viewtopic.php?p=25831#p25831
I hope that helps.

afe · 21 Apr 2019, 14:39

This is too complicated, I don't understand at all. Is there a simple line of code to do this?

A_AhkUser · 21 Apr 2019, 14:56

You can follow teadrinker (Using Google Translate to automate text translation) and use a function that returns a bound func obj binding the eval method to a dummy window object that contains a html document:

Code: Select all

jsObj := CreateScriptObj(), %jsObj%("alert('Привет, мир!')")
CreateScriptObj() {
   static doc := ComObjCreate("htmlfile")
   doc.write("<meta http-equiv='X-UA-Compatible' content='IE=9'>")
return ObjBindMethod(doc.parentWindow, "eval")
}

wolf_II · 21 Apr 2019, 15:01

here is an example script, which uses ActiveX:

Code: Select all

JS = function JS(x, y) { alert("x: " + x + "\ny: " + y) }

HTML := "<script>" JS "</script>"
Gui, Add, ActiveX, w200 h200 vWB, about:<!DOCTYPE html>
WB.Document.Open(), WB.Document.Write(HTML), WB.Document.Close()
HTMLWindow := WB.Document.parentWindow ; <<< we use this to run js code

F1:: HTMLWindow.JS(10, 20) ; hotkey to call JS function

afe · 22 Apr 2019, 01:44

Thank you very much. If do not display a interface, how to achieve it?

Such as this example,
Find the value of
a := s(a1, a2)

Code: Select all

a1 := 1
a2 := 2
a3 := "function s(a,b){return a+b};"

afe · 22 Apr 2019, 03:03

Where is the following code wrong?

Code: Select all

a1 := "1"
a2 := "2"
a3 := "function s(a,b){return a+b};"

JS := GetJScripObject(a3)
msgbox % JS.("s(a1, a2)")
return

GetJScripObject(a3)
{
    FileAppend, 
    (
    <component>
    <public><method name='eval'/></public>
    <script>%a3%</script>
    </component>
    ), tmpFile

    JS := ObjBindMethod(ComObjGet("script:tmpFile"), "eval")
    Return JS
}

wolf_II · 22 Apr 2019, 06:21

Code: Select all

a1 := 1
a2 := 2
a3 := "function s(a,b){return a+b};"

HTML := "<script>" a3 "</script>"
Gui, Add, ActiveX, vWB, about:<!DOCTYPE html>
WB.Document.Open(), WB.Document.Write(HTML), WB.Document.Close()
MsgBox, % WB.Document.parentWindow.s(a1, a2)

teadrinker · 22 Apr 2019, 06:35

Code: Select all

JS := GetJScripObject()
code := "function s(a,b){return a+b}; var a1 = 1, a2 = 2; s(a1, a2)"
MsgBox, % JS.(code)

JS := CreateScriptObj()
MsgBox, % JS.(code)

GetJScripObject()  {   ; Here we create the temp file to get the custom COM server using Windows Script Components (WSC) technology.
   VarSetCapacity(tmpFile, ((MAX_PATH := 260) - 14) << !!A_IsUnicode, 0)
   DllCall("GetTempFileName", Str, A_Temp, Str, "AHK", UInt, 0, Str, tmpFile)
   
   FileAppend,
   (
   <component>
   <public><method name='eval'/></public>
   <script language='JScript'></script>
   </component>
   ), % tmpFile
   
   JS := ObjBindMethod( ComObjGet("script:" . tmpFile), "eval" ) ; ComObjGet("script:" . tmpFile) is the way to invoke com-object without registration in the system
   FileDelete, % tmpFile
   Return JS
}

CreateScriptObj() {
   static doc := ComObjCreate("htmlfile")
   doc.write("<meta http-equiv='X-UA-Compatible' content='IE=9'>")
   return ObjBindMethod(doc.parentWindow, "eval")
}

wolf_II, you don't need to create the window. You get WebBrowser object which is more heavy than htmlfile object.

wolf_II · 22 Apr 2019, 06:42

teadrinker wrote: ↑
22 Apr 2019, 06:35
wolf_II, you don't need to create the window. You get WebBrowser object which is more heavy than htmlfile object.

OK, I see, thanks. I will change my approach. Currently I am tempted by "ease-of-use" maybe caused by habit. (Never used JS outside of canvas)
@afe: please ignore my posts.

afe · 24 Apr 2019, 02:08

Thank you all.

How to call JS code in a script? Topic is solved

How to call JS code in a script?

Re: How to call JS code in a script?

Re: How to call JS code in a script?

Re: How to call JS code in a script?

Re: How to call JS code in a script?

Re: How to call JS code in a script?

Re: How to call JS code in a script?

Re: How to call JS code in a script?

Re: How to call JS code in a script? Topic is solved

Re: How to call JS code in a script?

Re: How to call JS code in a script?

Who is online