Table of Contents

Introduction and Simple Examples

A function is similar to a subroutine (Gosub) except that it can accept parameters (inputs) from its caller. In addition, a function may optionally return a value to its caller. Consider the following simple function that accepts two numbers and returns their sum:

Add(x, y)
    return x + y   ; "Return" expects an expression.

The above is known as a function definition because it creates a function named "Add" (not case-sensitive) and establishes that anyone who calls it must provide exactly two parameters (x and y). To call the function, assign its result to a variable with the := operator. For example:

Var := Add(2, 3)  ; The number 5 will be stored in Var.

Also, a function may be called without storing its return value:

Add(2, 3)

But in this case, any value returned by the function is discarded; so unless the function produces some effect other than its return value, the call would serve no purpose.

Since a function call is an expression, any variable names in its parameter list should not be enclosed in percent signs. By contrast, literal strings should be enclosed in double quotes. For example:

if InStr(MyVar, "fox")
    MsgBox The variable MyVar contains the word fox.

Finally, functions may be called in the parameters of any command (except OutputVar and InputVar parameters such as those of StringLen). However, parameters that do not support expressions must use the "% " prefix as in this example:

MsgBox % "The answer is: " . Add(3, 2)

The "% " prefix is also permitted in parameters that natively support expressions, but it is simply ignored.


When a function is defined, its parameters are listed in parentheses next to its name (there must be no spaces between its name and the open-parenthesis). If a function does not accept any parameters, leave the parentheses empty; for example: GetCurrentTimestamp().

ByRef Parameters: From the function's point of view, parameters are essentially the same as local variables unless they are defined as ByRef as in this example:

Swap(ByRef Left, ByRef Right)
    temp := Left
    Left := Right
    Right := temp

In the example above, the use of ByRef causes each parameter to become an alias for the variable passed in from the caller. In other words, the parameter and the caller's variable both refer to the same contents in memory. This allows the Swap function to alter the caller's variables by moving Left's contents into Right and vice versa.

By contrast, if ByRef were not used in the example above, Left and Right would be copies of the caller's variables and thus the Swap function would have no external effect.

Since return can send back only one value to a function's caller, ByRef can be used to send back extra results. This is achieved by having the caller pass in a variable (usually empty) in which the function stores a value.

When passing large strings to a function, ByRef enhances performance and conserves memory by avoiding the need to make a copy of the string. Similarly, using ByRef to send a long string back to the caller usually performs better than something like Return HugeString.

[AHK_L 60+]: If something other than a modifiable variable is passed to a ByRef parameter, the function behaves as though the keyword "ByRef" is absent. For example, Swap(A_Index, i) stores the value of A_Index in i, but the value assigned to Left is discarded once the Swap function returns.

[v1.1.01+]: The IsByRef() function can be used to determine whether the caller supplied a variable for a given ByRef parameter.

Known limitations:

Optional Parameters

When defining a function, one or more of its parameters can be marked as optional. This is done by appending := (in [v1.1.09+]) or =, followed by the parameter's default value, which must be one of the following: true, false, a literal integer, a literal floating point number, or a quoted/literal string such as "fox" or "" (but strings in versions prior to [v1.0.46.13] support only "").

The use of = (without a colon) is permitted for backward-compatibility, but not recommended, and will not be permitted by AutoHotkey v2. Regardless of which operator is used, default values which are strings must always be enclosed in quote marks.

The following function has its Z parameter marked optional:

Add(X, Y, Z:=0) {
    return X + Y + Z

When the caller passes three parameters to the function above, Z's default value is ignored. But when the caller passes only two parameters, Z automatically receives the value 0.

It is not possible to have optional parameters isolated in the middle of the parameter list. In other words, all parameters that lie to the right of the first optional parameter must also be marked optional. [AHK_L 31+]: Optional parameters may be omitted from the middle of the parameter list when calling the function, as shown below. For dynamic function calls and method calls, this requires [v1.1.12+].

MyFunc(1,, 3)
MyFunc(X, Y:=2, Z:=0) {  ; Note that Z must still be optional in this case.
    MsgBox %X%, %Y%, %Z%

[v1.0.46.13+]: ByRef parameters also support default values; for example: MyFunc(ByRef p1 = ""). Whenever the caller omits such a parameter, the function creates a local variable to contain the default value; in other words, the function behaves as though the keyword "ByRef" is absent.

Returning Values to Caller

As described in introduction, a function may optionally return a value to its caller.

Test := returnTest()
MsgBox % Test

returnTest() {
    return 123

If you want to return extra results from a function, you may also use ByRef:

MsgBox % A "," B "," C

returnByRef(ByRef val1, ByRef val2, ByRef val3)
    val1 := "A"
    val2 := 100
    val3 := 1.1

[v1.0.97+]: Objects and Arrays can be used to return multiple values or even named values:

Test1 := returnArray1()
MsgBox % Test1[1] "," Test1[2]

Test2 := returnArray2()
MsgBox % Test2[1] "," Test2[2]

Test3 := returnObject()
MsgBox % "," Test3.val

returnArray1() {
    Test := [123,"ABC"]
    return Test

returnArray2() {
    x := 456
    y := "EFG"
    return [x, y]

returnObject() {
    Test := {id: 789, val: "HIJ"}
    return Test

Variadic Functions [AHK_L 60+]

When defining a function, write an asterisk after the final parameter to mark the function as variadic, allowing it to receive a variable number of parameters:

Join(sep, params*) {
    for index,param in params
        str .= param . sep
    return SubStr(str, 1, -StrLen(sep))
MsgBox % Join("`n", "one", "two", "three")

When a variadic function is called, surplus parameters can be accessed via an object which is stored in the function's final parameter. The first surplus parameter is at params[1], the second at params[2] and so on. As with any standard object, params.MaxIndex() can be used to determine the highest numeric index (in this case the number of parameters). However, if there are no parameters, MaxIndex returns an empty string.


Variadic Function Calls

While variadic functions can accept a variable number of parameters, an array of parameters can be passed to any function by applying the same syntax to a function-call:

substrings := ["one", "two", "three"]
MsgBox % Join("`n", substrings*)


Known limitations:

Local and Global Variables

Local Variables

Local variables are specific to a single function and are visible only inside that function. Consequently, a local variable may have the same name as a global variable and both will have separate contents. Separate functions may also safely use the same variable names.

All local variables which are not static are automatically freed (made empty) when the function returns.

Built-in variables such as Clipboard, ErrorLevel, and A_TimeIdle are never local (they can be accessed from anywhere), and cannot be redeclared.

Functions are assume-local by default. Variables accessed or created inside an assume-local function are local by default, with the following exceptions:

The default may also be overridden as shown below (by declaring the variable or by changing the mode of the function).

Force-local mode [v1.1.27+]: If the function's first line is the word "local", all variable references (even dynamic ones) are assumed to be local unless they are declared as global inside the function. Unlike the default mode, force-local mode has the following behavior:

Global Variables

To refer to an existing global variable inside a function (or create a new one), declare the variable as global prior to using it. For example:

    global LogFileName  ; This global variable was previously given a value somewhere outside this function.
    FileAppend, %TextToLog%`n, %LogFileName%

Assume-global mode: If a function needs to access or create a large number of global variables, it can be defined to assume that all its variables are global (except its parameters) by making its first line either the word "global" or the declaration of a local variable. For example:

    global  ; This word may be omitted if the first line of this function will be something like "local MyVar".
    MyGlobal := 33  ; Assigns 33 to a global variable, first creating the variable if necessary.
    local x, y:=0, z  ; Local variables must be declared in this mode, otherwise they would be assumed global.

This assume-global mode can also be used by a function to create a global array, such as a loop that assigns values to Array%A_Index%.

Super-global variables [v1.1.05+]: If a global declaration appears outside of any function, it takes effect for all functions by default (excluding force-local functions). This avoids the need to redeclare the variable in each function. However, if a function parameter or local variable with the same name is declared, it takes precedence over the global variable. Variables created by the class keyword are also super-global.

Static Variables

Static variables are always implicitly local, but differ from locals because their values are remembered between calls. For example:

    static LoggedLines := 0
    LoggedLines += 1  ; Maintain a tally locally (its value is remembered between calls).
    global LogFileName
    FileAppend, %LoggedLines%: %TextToLog%`n, %LogFileName%

Static Initializers: In versions prior to 1.0.46, all static variables started off blank; so the only way to detect that one was being used for the first time was to check whether it was blank. [v1.0.46+]: A static variable may be initialized to something other than "" by following it with := or = followed by one of the following: true, false, a literal integer, a literal floating point number, or a literal/quoted string such as "fox". For example: static X:=0, Y:="fox". Each static variable is initialized only once (before the script begins executing).

[AHK_L 58+]: Static var := expression is supported. All such expressions are evaluated immediately before the script's auto-execute section in the order they are encountered in the script.

Assume-static mode [v1.0.48+]: A function may be defined to assume that all its variables are static (except its parameters) by making its first line the word "static". For example:

    static FirstCallToUs := true  ; A static declaration's initializer still runs only once (upon startup).
    if FirstCallToUs  ; Create a static array during the first call, but not on subsequent calls.
        FirstCallToUs := false
        Loop 10
            StaticArray%A_Index% := "Value #" . A_Index
    return StaticArray%WhichItemNumber%

In assume-static mode, any variable that should not be static must be declared as local or global (with the same exceptions as for assume-local mode, unless force-local mode is also in effect).

[v1.1.27+]: Force-local mode can be combined with assume-static mode by specifying local and then static, as shown below. This allows the function to use force-local rules but create variables as static by default.

global MyVar := "This is global"

    MyVar := "This is static"

More About Locals and Globals

Multiple variables may be declared on the same line by separating them with commas as in these examples:

global LogFileName, MaxRetries := 5
static TotalAttempts := 0, PrevResult

[v1.0.46+]: A local or global variable may be initialized on the same line as its declaration by following it with := or = followed by any expression (the = operator behaves the same as := in declarations). Unlike static initializers, the initializers of locals and globals execute every time the function is called, but only if/when the flow of control actually reaches them. In other words, a line like local x := 0 has the same effect as writing two separate lines: local x followed by x := 0.

Because the words local, global, and static are processed immediately when the script launches, a variable cannot be conditionally declared by means of an IF statement. In other words, a declaration inside an IF's or ELSE's block takes effect unconditionally for all lines between the declaration and the function's closing brace. Also note that it is not currently possible to declare a dynamic variable such as global Array%i%.

For commands that create pseudo-arrays (such as StringSplit), each variable in the resulting pseudo-array is local if the assume-global mode is not in effect or if the pseudo-array's first element has been declared as a local variable (this is also true if one of the function's parameters is passed -- even if that parameter is ByRef -- because parameters are similar to local variables). Conversely, if the first element has been declared global, a global array is created. However, the common source of confusion below applies even in these cases. The first element for StringSplit is ArrayName0. For other array-creating commands such as WinGet List, the first element is ArrayName (i.e. without the number). [v1.1.27+]: When force-local mode is in effect, these commands follow rules consistent with normal variable references; that is, any pseudo-array element not declared as global will be local even if other elements are declared global.

Within a function (unless force-local mode is in effect), any dynamic variable reference such as Array%i% always resolves to a local variable unless no variable of that name exists, in which case a global is used if it exists. If neither exists and the usage requires the variable to be created, it is created as a local variable unless the assume-global mode is in effect. Consequently, a function can create a global array manually (by means such as Array%i% := A_Index) only if it has been defined as an assume-global function.

Common source of confusion: Any non-dynamic reference to a variable creates that variable the moment the script launches. For example, when used outside a function, MsgBox %Array1% creates Array1 as a global the moment the script launches. Conversely, when used inside a function MsgBox %Array1% creates Array1 as one of the function's locals the moment the script launches (unless assume-global is in effect), even if Array and Array0 are declared global.

Dynamically Calling a Function

[v1.0.47.06+]: A function (even a built-in function) may be called dynamically via percent signs. For example, %Var%(x, "fox") would call the function whose name is contained in Var. Similarly, Func%A_Index%() would call Func1() or Func2(), etc., depending on the current value of A_Index.

[v1.1.07.00+]: Var in %Var%() can contain a function name or a function object. If the function does not exist, the default base object's __Call meta-function is invoked instead.

If the function cannot be called due to one of the reasons below, the evaluation of the expression containing the call stops silently and prematurely, which may lead to inconsistent results:

Finally, a dynamic call to a function is slightly slower than a normal call because normal calls are resolved (looked up) before the script begins running.

Short-circuit Boolean Evaluation

When AND, OR, and the ternary operator are used within an expression, they short-circuit to enhance performance (regardless of whether any function calls are present). Short-circuiting operates by refusing to evaluate parts of an expression that cannot possibly affect its final result. To illustrate the concept, consider this example:

if (ColorName != "" AND not FindColor(ColorName))
    MsgBox %ColorName% could not be found.

In the example above, the FindColor() function never gets called if the ColorName variable is empty. This is because the left side of the AND would be false, and thus its right side would be incapable of making the final outcome true.

Because of this behavior, it's important to realize that any side-effects produced by a function (such as altering a global variable's contents) might never occur if that function is called on the right side of an AND or OR.

It should also be noted that short-circuit evaluation cascades into nested ANDs and ORs. For example, in the following expression, only the leftmost comparison occurs whenever ColorName is blank. This is because the left side would then be enough to determine the final answer with certainty:

if (ColorName = "" OR FindColor(ColorName, Region1) OR FindColor(ColorName, Region2))
    break   ; Nothing to search for, or a match was found.

As shown by the examples above, any expensive (time-consuming) functions should generally be called on the right side of an AND or OR to enhance performance. This technique can also be used to prevent a function from being called when one of its parameters would be passed a value it considers inappropriate, such as an empty string.

[v1.0.46+]: The ternary conditional operator (?:) also short-circuits by not evaluating the losing branch.

Using Subroutines Within a Function

Although a function cannot contain definitions of other functions, it can contain subroutines. As with other subroutines, use Gosub to launch them and Return to return (in which case the Return would belong to the Gosub and not the function).

Known limitation: Currently, the name of each subroutine (label) must be unique among those of the entire script. The program will notify you upon launch if there are duplicate labels.

If a function uses Gosub to jump to a public subroutine (one that lies outside of the function's braces), all variables outside are global and the function's own local variables are not accessible until the subroutine returns. However, A_ThisFunc will still contain the name of the function.

Although Goto cannot be used to jump from inside a function to outside, it is possible for a function to Gosub an external/public subroutine and then do a Goto from there.

Although the use of Goto is generally discouraged, it can be used inside a function to jump to another position within the same function. This can help simplify complex functions that have many points of return, all of which need to do some clean-up prior to returning.

A function may contain externally-called subroutines such as timers, GUI g-labels, and menu items. This is generally done to encapsulate them in a separate file for use with #Include, which prevents them from interfering with the script's auto-execute section. However, the following limitations apply:

Return, Exit, and General Remarks

If the flow of execution within a function reaches the function's closing brace prior to encountering a Return, the function ends and returns a blank value (empty string) to its caller. A blank value is also returned whenever the function explicitly omits Return's parameter.

When a function uses the Exit command to terminate the current thread, its caller does not receive a return value at all. For example, the statement Var := Add(2, 3) would leave Var unchanged if Add() exits. The same thing happens if a function causes a runtime error such as running a nonexistent file (when UseErrorLevel is not in effect).

A function may alter the value of ErrorLevel for the purpose of returning an extra value that is easy to remember.

To call a function with one or more blank values (empty strings), use an empty pair of quotes as in this example: FindColor(ColorName, "").

Since calling a function does not start a new thread, any changes made by a function to settings such as SendMode and SetTitleMatchMode will go into effect for its caller too.

The caller of a function may pass a nonexistent variable or array element to it, which is useful when the function expects the corresponding parameter to be ByRef. For example, calling GetNextLine(BlankArray%i%) would create the variable BlankArray%i% automatically as a local or global (depending on whether the caller is inside a function and whether it has the assume-global mode in effect).

When used inside a function, ListVars displays a function's local variables along with their contents. This can help debug a script.

Style and Naming Conventions

You might find that complex functions are more readable and maintainable if their special variables are given a distinct prefix. For example, naming each parameter in a function's parameter list with a leading "p" or "p_" makes their special nature easy to discern at a glance, especially when a function has several dozen local variables competing for your attention. Similarly, the prefix "r" or "r_" could be used for ByRef parameters, and "s" or "s_" could be used for static variables.

The One True Brace (OTB) style may optionally be used to define functions. For example:

Add(x, y) {
    return x + y

Using #Include to Share Functions Among Multiple Scripts

The #Include directive may be used (even at the top of a script) to load functions from an external file.

Explanation: When the script's flow of execution encounters a function definition, it jumps over it (using an instantaneous method) and resumes execution at the line after its closing brace. Consequently, execution can never fall into a function from above, nor does the presence of one or more functions at the very top of a script affect the auto-execute section.

Libraries of Functions: Standard Library and User Library [v1.0.47+]

A script may call a function in an external file without having to use #Include. For this to work, a file of the same name as the function must exist in one of the following library directories:

%A_ScriptDir%\Lib\  ; Local library - requires [AHK_L 42+].
%A_MyDocuments%\AutoHotkey\Lib\  ; User library.
directory-of-the-currently-running-AutoHotkey.exe\Lib\  ; Standard library.

For example, if a script calls a nonexistent function MyFunc(), the program searches for a file named "MyFunc.ahk" in the user library. If not found there, it searches for it in the standard library. If a match is still not found and the function's name contains an underscore (e.g. MyPrefix_MyFunc), the program searches both libraries for a file named MyPrefix.ahk and loads it if it exists. This allows MyPrefix.ahk to contain both the function MyPrefix_MyFunc and other related functions whose names start with MyPrefix_.

[AHK_L 42+]: The local library is supported and is searched before the user library and standard library.

Only a direct function call such as MyFunc() can cause a library to be auto-included. If the function is only called dynamically or indirectly, such as by a timer or GUI event, the library must be explicitly included in the script. For example: #Include <MyFunc>

Although a library file generally contains only a single function of the same name as its filename, it may also contain private functions and subroutines that are called only by it. However, such functions should have fairly distinct names because they will still be in the global namespace; that is, they will be callable from anywhere in the script.

If a library file uses #Include, the working directory for #Include is the library file's own directory. This can be used to create a redirect to a larger library file that contains that function and others related to it.

The script compiler (ahk2exe) also supports library functions. However, it requires that a copy of AutoHotkey.exe exist in the directory above the compiler directory (which is normally the case). If AutoHotkey.exe is absent, the compiler still works but library functions are not automatically included.

Functions included from a library perform just as well as other functions because they are pre-loaded before the script begins executing.

Built-in Functions

Any optional parameters at the end of a built-in function's parameter list may be completely omitted. For example, WinExist("Untitled - Notepad") is valid because its other three parameters would be considered blank.

A built-in function is overridden if the script defines its own function of the same name. For example, a script could have its own custom WinExist() function that is called instead of the standard one. However, the script would then have no way to call the original function.

External functions that reside in DLL files may be called with DllCall().

To get more details about a particular built-in function below, simply click on its name.

Frequently-used Functions

Function Description
FileExist Checks for the existence of a file or folder and returns its attributes.
GetKeyState Returns 1 (true) or 0 (false) depending on whether the specified keyboard key or mouse/controller button is down or up.
InStr Searches for a given occurrence of a string, from the left or the right.
RegExMatch Determines whether a string contains a pattern (regular expression).
RegExReplace Replaces occurrences of a pattern (regular expression) inside a string.
StrLen Retrieves the count of how many characters are in a string.
StrReplace Replaces the specified substring with a new string.
StrSplit Separates a string into an array of substrings using the specified delimiters.
SubStr Retrieves one or more characters from the specified position in a string.
WinActive Checks if the specified window is active and returns its unique ID (HWND).
WinExist Checks if the specified window exists and returns the unique ID (HWND) of the first matching window.

Miscellaneous Functions

Function Description
Asc Returns the numeric value of the first byte or UTF-16 code unit in the specified string.
Chr Returns the string (usually a single character) corresponding to the character code indicated by the specified number.
DllCall Calls a function inside a DLL, such as a standard Windows API function.
Exception Creates an object which can be used to throw a custom exception.
FileOpen Opens a file to read specific content from it and/or to write new content into it.
Format Formats a variable number of input values according to a format string.
Func Retrieves a reference to the specified function.
GetKeyName/VK/SC Retrieves the name/text, virtual key code or scan code of a key.
Hotstring Creates, modifies, enables, or disables a hotstring while the script is running.
IL_XXX Functions to add icons/pictures to, create or delete ImageLists used by ListView or TreeView controls.
InputHook Creates an object which can be used to collect or intercept keyboard input.
IsByRef Returns a non-zero number if the specified ByRef parameter was supplied with a variable.
IsFunc Returns a non-zero number if the specified function exists in the script.
IsLabel Returns a non-zero number if the specified label exists in the script.
IsObject Returns a non-zero number if the specified value is an object.
IsSet Returns a non-zero number if the specified variable has been assigned a value.
LoadPicture Loads a picture from file and returns a bitmap or icon handle.
LV_XXX Functions to add, insert, modify or delete ListView rows/colums, or to get data from them.
NumGet Returns the binary number stored at the specified address+offset.
NumPut Stores a number in binary format at the specified address+offset.
ObjAddRef / ObjRelease Increments or decrements an object's reference count.
ObjBindMethod Creates a BoundFunc object which calls a method of a given object.
ObjGetBase Retrieves an object's base object.
ObjRawGet Retrieves a key-value pair from an object, bypassing the object's meta-functions.
ObjRawSet Stores or overwrites a key-value pair in an object, bypassing the object's meta-functions.
ObjSetBase Sets an object's base object.
ObjXXX Functions equivalent to the built-in methods of the Object type, such as ObjInsertAt. It is usually recommended to use the corresponding method instead.
OnClipboardChange Registers a function to be called automatically whenever the clipboard's content changes.
OnError Registers a function to be called automatically whenever an unhandled error occurs.
OnExit Registers a function to be called automatically whenever the script exits.
OnMessage Registers a function to be called automatically whenever the script receives the specified message.
Ord Returns the ordinal value (numeric character code) of the first character in the specified string.
SB_XXX Functions to add text/icons to or divide the bar of a StatusBar control.
StrGet Copies a string from a memory address, optionally converting it from a given code page.
StrPut Copies a string to a memory address, optionally converting it to a given code page.
RegisterCallback Creates a machine-code address that when called, redirects the call to a function in the script.
Trim / LTrim / RTrim Trims characters from the beginning and/or end of a string.
TV_XXX Functions to add, modify or delete TreeView items, or to get data from them.
VarSetCapacity Enlarges a variable's holding capacity or frees its memory.
VerCompare Compares two version strings.


Function Description
Abs Returns the absolute value of the specified number.
Ceil Returns the specified number rounded up to the nearest integer (without any .00 suffix).
Exp Returns the result of raising e (which is approximately 2.71828182845905) to the Nth power.
Floor Returns the specified number rounded down to the nearest integer (without any .00 suffix).
Log Returns the logarithm (base 10) of the specified number.
Ln Returns the natural logarithm (base e) of the specified number.
Max / Min Returns the highest/lowest number from a set of numbers.
Mod Modulo. Returns the remainder of a number (dividend) divided by another number (divisor).
Round Returns the specified number rounded to N decimal places.
Sqrt Returns the square root of the specified number.
Sin / Cos / Tan Returns the trigonometric sine/cosine/tangent of the specified number.
ASin / ACos / ATan Returns the arcsine/arccosine/arctangent (the number whose sine/cosine/tangent is the specified number) in radians.


Function Description
ComObjActive Retrieves a registered COM object.
ComObjArray Creates a SAFEARRAY for use with COM.
ComObjConnect Connects a COM object's event sources to functions with a given prefix.
ComObjCreate Creates a COM object.
ComObject Creates an object representing a typed value to be passed as a parameter or return value.
ComObjEnwrap / ComObjUnwrap Wraps/unwraps a COM object.
ComObjError Enables or disables notification of COM errors.
ComObjFlags Retrieves or changes flags which control a COM wrapper object's behaviour.
ComObjGet Returns a reference to an object provided by a COM component.
ComObjMissing Creates a "missing parameter" object to pass to a COM method.
ComObjParameter Wraps a value and type to pass as a parameter to a COM method.
ComObjQuery Queries a COM object for an interface or service.
ComObjType Retrieves type information from a COM object.
ComObjValue Retrieves the value or pointer stored in a COM wrapper object.

Other Functions

Polyethene's Command Functions: Provides a callable function for each AutoHotkey command that has an OutputVar. This library can be included in any script via #Include.