7 replies to this topic

[joeyespo]

I'm sure the answer exists, but I can't seem to find it anywhere.

I essentially want to do the following to run "cmd" without args when on the desktop. Unfortunately, there's two desktop windows on Windows XP.

; This is the desktop window
#IfWinActive ahk_class Progman
#c::Run, cmd
#IfWinActive

; WorkerW gets input when you "show desktop" by press Win+D
#IfWinActive ahk_class WorkerW
#c::Run, cmd
#IfWinActive

How can I combine the above to something like this? I feel like I'm close.

; This works, but only for the "ahk_class WorkerW" part
#IfWinActive ahk_class Progman || ahk_class WorkerW
#c::Run, cmd
#IfWinActive

Thanks!

[nimda]

#IfWinActive ahk_class Progman
#c::
#IfWinActive ahk_class WorkerW
#c::
Run cmd
return

To have the same hotkey subroutine executed by more than one variant, the easiest way is to create a stack of identical hotkeys, each with a different #IfWin directive above it.

Although this is actually longer than

#IfWinActive ahk_class Progman
#c::run cmd
#IfWinActive ahk_class WorkerW
#c::run cmd
#IfWinActive ; <<<< Optional

[joeyespo]

Ok, well let's just pretend that Run cmd is a long script (so that it's not shorter to do your 2nd example).

#IfWinActive ahk_class Progman
#c::
#IfWinActive ahk_class WorkerW
#c::
Run cmd
return

Ahh, ok, I thought doing it this way would add scope, not replace it. In other words, I thought doing it this way would require the user to be over both windows. Guess this way is easy enough. There's no way to combine them into a single expression though, huh?

Thanks for the reply, it helps!

[None]

Ahk_l supports #If (expresion)

#If WinActive("ahk_class Progman") || WinActive("ahk_class WorkerW")
#c::Run cmd

Or (this works in basic)

GroupAdd, GroupName, ahk_class Progman
GroupAdd, GroupName, ahk_class WorkerW
#IfWinActive ahk_group GroupName
#c::Run cmd

[parkour86]

I know this topic is old but searching google this was the first result it found. The way I got it working was like this:

#IfWinActive ahk_class Progman || ahk_class WorkerW

[Oldman]

 

I know this topic is old but searching google this was the first result it found. The way I got it working was like this:

#IfWinActive ahk_class Progman || ahk_class WorkerW

 

Are you sure it works for the Progman class ?

[Aquinax]

#IfWinActive ahk_class Progman || ahk_class WorkerW

Thanks parkour86, this - the || handle - worked fine for me. I used it in the 'IfWinActive' statement with Notepad++ and WinWord.

IfWinActive, ahk_class TFormPowerGREP || ahk_class  OpusApp

[Synetech]

 

Thanks parkour86, this - the || handle - worked fine for me. I used it in the 'IfWinActive' statement with Notepad++ and WinWord.

IfWinActive, ahk_class TFormPowerGREP || ahk_class  OpusApp

 

Are you sure it worked? When I tested it, it only worked for the second class, not the first.