5 replies to this topic

[Verdlin]

First and foremost, this method requires Autohotkey_H. Second, the most important thing to be sure of is to use the right dll. If you are using AHK 32 Unicode, then use that version of the dll; the dll type should match the executable.

 

Although when you look at Autohotkey_H this seems like something you can obviously do, I haven't seen any specific examples on how to accomplish this; on the contrary, I have only seen posts claiming that this is impossible or extremely difficult to script.

 

So here's a very basic example of how to accomplish this.

Spoiler

^+5::
{
    g_hThread := AhkDllThread()

    Gui, Add, Hotkey, x112 y50 w130 h30 vsHK
    Gui, Add, Edit, x2 y110 w350 h70 Multi r3 vsAHKScript
    Gui, Add, ListView, x2 y190 w350 h150 AltSubmit gLVProc, ListView, Hotkey|Script
    Gui, Add, Button, x2 y160 w350 h30 gAddHK, &Add Hotkey

    GUI, Font, s12 cBlue
    Gui, Add, Text, x2 y22 w350 h28 Center, Record a Hotkey
    Gui, Add, Text, x2 y82 w350 h28 Center, Raw AHK script to be executed
    Gui, Add, Text, x2 y132 w350 h28 Center, Add to the ListView
    Gui, Add, Text, x2 y350 w350 h28 Center, Now try the hotkey!

    Gui, Show, w356

    aHKInfo := {}
    return
}

AddHK:
{
    GUIControlGet, sHK,, sHK
    GUIControlGet, sAHKScript,, sAHKScript

    if (aHKInfo.HasKey(sHK))
        LV_Delete()

    LV_Add("", sHK, sAHKScript)
    aHKInfo[sHK] := sAHKScript

    ; Update the thread
    for k, v in aHKInfo
    {
        sHotkeys .= A_Index == 1 ? k : "|" k
        sLabels .="
            (LTrim

            " A_Index ":
            {
                Critical
                " v "
                return
            }

        )"
    }

    sScript .="
        (LTrim

        sHotkeys := """ sHotkeys """
        Loop, Parse, sHotkeys, |
            Hotkey, %A_LoopField%, %A_Index%
    )"

        g_hThread.ahktextdll["#Persistent`n" sScript "`nreturn`n" sLabels]
        sScript:=sLabels:=sHotkeys:=A_Blank
    return
}

LVProc:
{
    GUIControl,, sAHKScript, % aHKInfo[LV_GetSelText()]
    return
}

LV_GetSelText(iCol=1)
{
    LV_GetText(sCurSel, LV_GetSel(), iCol)
    StringReplace, sCurSel, sCurSel, `r, , All ; Sometimes, characters are retrieved with a carriage-return.
    return sCurSel
}

LV_GetSel()
{
    return LV_GetNext(0, "Focused") == 0 ? 1 : LV_GetNext(0, "Focused")
}

 

Currently, the way I like to implement this is to create a function that dynamically creates the code for the label, loads that up into a variable, and then passed that variable into ahktextdll.

 

I like using the hotkey label simply as a wrapper back to a function (or label) in Autohotkey.exe so that I can keep the brunt of my code in my main script. This is a cleaner approach, IMHO, and it leaves less room for error.

 

Note: the dll thread is not multi-thread safe. For those of you who need to ensure multi-threading safety, use the CriticalObject function

[guest3456]

cool, thanks for sharing

[Verdlin]

Sure thing!

[Verdlin]

Updated example with a GUI that clearly demonstrates this.

[HotKeyIt]

You forgot to include LV_GetSel().

You also don't need to call AhkDllThread over and over again, run the second line only once at the top of the script!

        g_hThread :=
        g_hThread := AhkDllThread()

you can also show the script in second column so user knows what the code was and why did you limit edit to one line?

...
Gui, Add, Edit, x2 y110 w350 h70 Multi r3 vsAHKScript
...
Gui, Add, ListView, x2 y190 w350 h150 AltSubmit gLVProc, Hotkey|Script
...
LV_Add("", sHK,sAHKScript)
...

[Verdlin]

Thanks, HotKeyIt! I made all of those changes.

 

The Edit was limited to one row because I thought it was causing errors in the continuation section where I build the labels.