OnExit reason is always "0" (v2.0.15)

[smrt1]

[Moderator's note: Topic moved from Bug Reports.]

Hello,

Because I couldn't retrieve the exit reason, I've wrote this little exit function which reveal some kind of bug in "OnExit".
Whatever method used to terminate the script (reload, system shutdown, etc.) it always produce a single value: 0

Code: Select all

OnExit(DoExit)
DoExit(o*) {
	for k, v in o
		fileappend(k "=" v "`n", "why.txt")
}

[Ragnar]

When I run this script, I get the following output:

Code: Select all

1=Exit
2=0

As expected, the exit reason is "Exit" and the exit code is 0. The exit code is always 0 unless specified otherwise via Exit or ExitApp.

[just me]

Code: Select all

#Requires AutoHotkey v2.0
OnExit(DoExit)
DoExit(o*) {
	for k, v in o
		MsgBox(v, k)
}
ExitApp 999

[smrt1]

When I run this script, I get the following output:

Code: Select all

1=Exit
2=0

As expected, the exit reason is "Exit" and the exit code is 0. The exit code is always 0 unless specified otherwise via Exit or ExitApp.

I have several OnExit(f) in my script - maybe it has something to do - and when I call ExitApp(999) I get this, nothing else:

Code: Select all

1=999

.

[Ragnar]

Then show us your script. If it is too large or contains sensitive data, reduce it to a minimum where this supposed bug still occurs.

[smrt1]

Then show us your script. If it is too large or contains sensitive data, reduce it to a minimum where this supposed bug still occurs.

Same behavior with this:

Code: Select all

class runbox {

	static __New() {
		OnExit(runbox.Exit)
	}

	static Exit(*) {
	}
}


class runbox2 {

	static __New() {
		OnExit(runbox2.Exit)
	}

	static Exit(o*) {
		for k, v in o
				fileappend(k "=" v "`n", "why.txt")
	}
}




Loop
	Sleep 1000

[Ragnar]

Thanks, but it's not a bug. The exit reason is stored in the hidden first parameter named this. See https://www.autohotkey.com/docs/v2/Objects.htm#Custom_Classes_method

[smrt1]

Thanks, but it's not a bug. The exit reason is stored in the hidden first parameter named this. See https://www.autohotkey.com/docs/v2/Objects.htm#Custom_Classes_method

Ok, thank you.
I'll never understand this "this" thing

[lexikos]

I'll never understand this "this" thing

It's just a parameter, not difficult to understand. These are basically equivalent:

Code: Select all

class runbox {
	static Exit(o*) {
	}
}

Code: Select all

runbox.DefineProp("Exit", {call: runbox_Exit})
class runbox {
}
runbox_Exit(this, o*) {
}

... and not much different to:

Code: Select all

runbox := {Exit: runbox_Exit}
runbox_Exit(this, o*) {
}

In all of these cases, runbox.Exit is just a reference to a function which has a parameter named this, and puts all of the remaining parameters in o.

[smrt1]

@lexikos Thank you.