Select next party member hotkey DDO

[jesseb]

I've always thought this should be a hotkey in the game, So I wrote a pretty simple script to do it.

This is very simple script to use. First log in to the game, Join a party, ALT-TAB out of the game, Open the GUI (run as admin) select the two keys you want to use for next and previous party member, and insert the party size (so that it isn't trying to select people who aren't there). Click "Done" and then ALT-TAB back into DDO. Then have fun selecting everyone in your party with one button

Requirements:
AHK installed
The two files from this thread, in the same folder.
F1-F12 Key mapped to select party members 1-12 (this is default in game)

This is the GUI file, Click download and put this where you can find it.

Code: Select all

DropDownListPart1 = 1|2|3|4|5|6|7|8|9|0|a|b|c|d|e|f|g|h|i|j|k|l|m|n|o|p|q|r|s|t|u|v|w|x|y|z
DropDownListPart2 = ``|-|=|[|]|\|,|.|/
DropDownListPart3 = Space|Tab|Enter|Escape|Backspace|Delete|Insert|Home|End|PgUp|PgDn
DropDownListPart4 = Up|Down|Left|Right|ScrollLock|CapsLock|NumLock
DropDownListPart5 = Click Left|Click Right|Click Middle|NumpadDiv|NumpadMult|NumpadAdd|NumpadSub|NumpadEnter|NumpadDel|NumpadIns|NumpadClear
DropDownListPart6 = NumpadUp|NumpadDown|NumpadLeft|NumpadRight|NumpadHome|NumpadEnd|NumpadPgUp|NumpadPgDn
DropDownListPart7 = Numpad0|Numpad1|Numpad2|Numpad3|Numpad4|Numpad5|Numpad6|Numpad7|Numpad8|Numpad9|NumpadDot
DropDownListPart8 = F1|F2|F3|F4|F5|F6|F7|F8|F9|F10|F11|F12
DropDownListPart9 = AppsKey|LWin|RWin|Alt|Control|LControl|RControl|Shift|LShift|RShift|LAlt|RAlt|PrintScreen|CtrlBreak|Pause
DropDownListPart0 = Joy1|Joy2|Joy3|Joy4|Joy5|Joy6|Joy7|Joy8|Joy9|Joy10|Joy11|Joy12
DropDownListHalf1 = %DropDownListPart1%|%DropDownListPart0%|%DropDownListPart3%|%DropDownListPart4%|%DropDownListPart2%
DropDownListHalf2 = %DropDownListPart8%|%DropDownListPart7%|%DropDownListPart6%|%DropDownListPart9%|%DropDownListPart5%
DropDownListList = %DropDownListHalf1%|%DropDownListHalf2%
DropDownListParty = 2|3|4|5|6|7|8|9|10|11|12
FileRead, Source, SNPMsource.txt

Gui,Add,Text,x40 y10 w100 h15 Center,Next Party Member
Gui,Add,Text,x40 y70 w100 h15 Center,Prev Party Member
Gui,Add,Text,x40 y130 w100 h15 Center,Party Size
Gui,Add,DropDownList,x30 y30 w120 vNPMB gClick,]|>|%DropDownListList%
Gui,Add,DropDownList,x30 y90 w120 vPPMB gClick,[|<|%DropDownListList%
Gui,Add,DropDownList,x30 y150 w120 vPSDN gClick,%DropDownListParty%
Gui,Add,Button,x30 y190 w43 h23 gHelp,Help
Gui,Add,Button,x110 y190 w43 h23 gDone,Done
Gui,Show,x429 y99 w180 h230 ,
Return

Click:
Gui, Submit , NoHide
Return

Help:
MsgBox, 64, Select Next Party Member Help, Once you open the SNMP Gui there are 3 fields you must fill out.`nSet "Next Party Member" to the key you want to press to select next party member.`nSet "Prev Party Member" to the respective key`, this can NOT be the same as Next key.`nParty Size is to be set to how many members are in your party. (I can't get game variables so I can't really make this auto-detect.)
Return

Done:
StringReplace, Source, Source, NEXTBUTTON , %NPMB%, A
StringReplace, Source, Source, PREVBUTTON , %PPMB%, A
StringReplace, Source, Source, PARTYSIZE , %PSDN%, A
FileDelete, hotkeySNPM.ahk
FileAppend, %Source%, hotkeySNPM.ahk
Sleep 1000
Run, hotkeySNPM.ahk
ExitApp
Return

GuiClose:
ExitApp
Return

This is the source script, Download this and put it in the SAME folder as the GUI

Code: Select all

PartyKey = 1
#IfWinActive, ahk_class Turbine Device Class
#SingleInstance force

NEXTBUTTON::
{
	PartyKey:=PartyKey+1
	if (PartyKey > PARTYSIZE)
	{
		PartyKey = 1
	}
	Send , {f%PartyKey%}
	Return
}

PREVBUTTON::
{
	PartyKey:=PartyKey-1
	if (PartyKey < 1)
	{
		PartyKey = PARTYSIZE
	}
	Send , {f%PartyKey%}
	Return
}

If you have any errors or suggestions or just want to say hello feel free to leave a comment below.