Using AutoHotkey from Python

[songdg]

@songdg, there are a couple of ways at least that you can do that. See the ahk github page, my post here.
Regards,
burque505

Thanks for your help

[chango]

I'm shifting to a combination of AHK and python atm so I'll watch this thread

[blue83]

Hi @blue83, one simple way (not using @Pythonic's ahk, though you could easily do so) is here, using RunCmd.ahk by @SKAN. Assumes 'varfrompy.py' is in the script directory. By the way, the ahk github page has examples for passing info from AHK to python.

Code: Select all

#Include RunCmd.ahk

avar := RunCmd("python .\varfrompy.py")
msgbox %avar%

/* varfrompy.py:

myvar = "Hello, AHK!"
print(myvar)
*/

Regards,
burque505

Hi,

Your code is great for normal purposes.

But I have also a code with python on different path and this code bellow doesnt work, can you help me?
What I am doing wrong?

Code: Select all

avar := RunCmd("C:/Users/%A_UserName%/Desktop/WPy64-3760/python-3.7.6.amd64/python.exe %A_ScriptDir%/varfrompy.py", A_ScriptDir, "UTF-8")
msgbox %avar%

I have found it.

Code: Select all

avar := RunCmd("C:/Users/" A_UserName "/Desktop/WPy64-3760/python-3.7.6.amd64/python.exe .\varfrompy.py", A_ScriptDir, "UTF-8")

[burque505]

I am really liking @Pythonic's ahk lib! I've been creating some AHK (v1) GUIs that pass dictionaries and lists to Python. I soon discovered I need to massage them into a string to have Python read them using ahk.py.

I started off with obj2str.ahk by @errorseven (many thanks!) but it choked for my purposes on multiline strings and other things. My mod of obj2str (Obj2PyStr.ahk) is below.
(Tested with Python 3.10.4 on Windows 10 Pro 64-bit only, latest ahk.py)

Spoiler

Code: Select all

; Modified from obj2str.ahk by errorseven.
; burque505 Feb 14 2023
; (No, I'm not thrilled about the name of my script :))

; The motivating factor for this mod was a desire to export AHK v1 objects to stdout via 'FileAppend, % obj2str(YourObjectHere), *'
; and process the result in Python, using the library 'ahk'

; https://github.com/spyoungtech/ahk
; https://www.autohotkey.com/boards/viewtopic.php?f=6&t=63184&p=270111&hilit=spyoungtech#p270111

; A requirement is the ability to process multiline strings in both AHK and Python,
; which meant jumping through some hoops with continuation sections and StrReplace().
; I also need to be able to process underscores in key names in dictionaries.

; AHK Script 'your_script_here5.ahk'
/*
#Include obj2pystr.ahk

hughes = 
(
John James Hughes
as Trusteee
of the J.J. Hughes Revocable Living Trust
)

MyStuff := [1, 2, 3, 5, hughes]
;MsgBox % Obj2PyStr(MyDict)
FileAppend, % Obj2PyStr(MyStuff), *
*/

; python to read the output of that script
/*
from ahk import AHK
from ast import literal_eval

ahk = AHK()

with open(r"your_script_here5.ahk", 'r') as f:
    my_script =  f.read()

result = ahk.run_script(my_script)
print(result)  
NewStuff = literal_eval(result)
print(type(NewStuff))
print(NewStuff[4])
*/

; Result:
/*
[1, 2, 3, 5, '''John James Hughes
as Trusteee
of the J.J. Hughes Revocable Living Trust''']
<class 'list'>
John James Hughes
as Trusteee
of the J.J. Hughes Revocable Living Trust
*/

; Now for a 'Dictionary' (associative array in AHK v1)
; AHK Script 'your_script_here4.ahk'
/*
#Include obj2pystr.ahk

hughes = 
(
John James Hughes
as Trusteee
of the J.J. Hughes Revocable Living Trust
)

MyDict := {borrowers:[{1_FullName:"James Roberts", 2_Street:"346 Cage St", 3_City:"Tarzana", 4_State:"CA", 5_Zip:90111}]
, lenders:[{1_FullName:hughes, 2_Street:"123 Anywhere", 3_City:"Albacore", 4_State:"NT", 5_Zip:80111}]}

;MsgBox % Obj2PyStr(MyDict)
FileAppend, % Obj2PyStr(MyDict), *

*/

; Python script to process this:
/*
from ahk import AHK
#import json
from ast import literal_eval

ahk = AHK()

with open(r"your_script_here4.ahk", 'r') as f:
    my_script =  f.read()

result = ahk.run_script(my_script)
print(result)  
NewStuff = literal_eval(result)
print(type(NewStuff))
print(NewStuff["lenders"][0]["1_FullName"])
*/

; Result:
/*
{"borrowers":[{"1_FullName":'''James Roberts''', "2_Street":'''346 Cage St''', "3_City":'''Tarzana''', "4_State":'''CA''', "5_Zip":90111}], "lenders":[{"1_FullName":'''John James Hughes
as Trusteee
of the J.J. Hughes Revocable Living Trust''', "2_Street":'''123 Anywhere''', "3_City":'''Albacore''', "4_State":'''NT''', "5_Zip":80111}]}
<class 'dict'>
John James Hughes
as Trusteee
of the J.J. Hughes Revocable Living Trust
*/

; NOTE:
; Use ast (from ast import )
; Other AHK objects remain untested


Obj2PyStr(obj) { 
 
    Linear := True
    
    While (A_Index != obj.MaxIndex()) {
        if !(obj.hasKey(A_Index)) {
            Linear := False
            break
        }
    }

    For e, v in obj {
        if (Linear == False) {
            if (IsObject(v)) 
               r .= """" e """" ":" Obj2PyStr(v) ", "        
            else {                  
                r .= """" e """" ":"  
                if v is number 
                    r .= v ", "
                else {
                    v = 
                    (join`n
                        %v%
                    )
                    v := StrReplace(v, "\n", "``n")
                    r .= "'''" . v . "'''" . ", "
                }
            }            
        } else {
            if (IsObject(v)) 
                r .= Obj2PyStr(v) ", "
            else {          
                if v is number 
                    r .= v ", "
                else {
                    v = 
                    (join`n
                        %v%
                    )
                    v := StrReplace(v, "\n", "``n")
                    r .= "'''" . v . "'''" . ", "
                }
            }
        }
    }
    return Linear ? "[" trim(r, ", ") "]" 
                 : "{" trim(r, ", ") "}"
}

There are examples for use in the script, and at the obj2pystr GitHub page.
One for dictionaries (i.e. associative arrays in AHK) is below.
AHK:

Code: Select all

#Include obj2pystr.ahk

hughes = 
(
John James Hughes
as Trusteee
of the J.J. Hughes Revocable Living Trust
)

MyDict := {borrowers:[{1_FullName:"James Roberts", 2_Street:"346 Cage St", 3_City:"Tarzana", 4_State:"CA", 5_Zip:90111}]
, lenders:[{1_FullName:hughes, 2_Street:"123 Anywhere", 3_City:"Albacore", 4_State:"NT", 5_Zip:80111}]}

;MsgBox % Obj2PyStr(MyDict)
FileAppend, % Obj2PyStr(MyDict), *

Python to process that:

Code: Select all

from ahk import AHK
from ast import literal_eval

ahk = AHK()

with open(r"your_script_here4.ahk", 'r') as f:
    my_script =  f.read()

result = ahk.run_script(my_script)
print(result)  
NewStuff = literal_eval(result)
print(type(NewStuff))
print(NewStuff["lenders"][0]["1_FullName"])

Result:

Code: Select all

{"borrowers":[{"1_FullName":'''James Roberts''', "2_Street":'''346 Cage St''', "3_City":'''Tarzana''', "4_State":'''CA''', "5_Zip":90111}], "lenders":[{"1_FullName":'''John James Hughes
as Trusteee
of the J.J. Hughes Revocable Living Trust''', "2_Street":'''123 Anywhere''', "3_City":'''Albacore''', "4_State":'''NT''', "5_Zip":80111}]}
<class 'dict'>
John James Hughes
as Trusteee
of the J.J. Hughes Revocable Living Trust

NOTE: The Python creates a really ugly object because of the single quotes and triple single quotes, but I ended up doing it that way so ast.literal_eval() can process the object.

Regards,
burque505

[songdg]

How to use it in Anaconda with spyder, I place the library(ahk_main) in the directory(C:\ProgramData\Anaconda3\Lib\site-packages) that I can use the code import ahk_main, but when I try ahk = AHK() it doesn't work.