Using Google Translate to automate text translation

[rommmcek]

I was referring at oJSON array not Ahk array. Never mind, I did it for you. Please test script above. I edited it!
[Edit]: I made a third (unfunctional) edit.
P.s.: This has nothing to do with the knowledge it's pure logic. But obviously it was easier for me having some previous experience...
P.p.s.:

GoogleTranslate oJSON tutorial

Code: Select all

step1:= oJSON[0][0][8][0][0][1], step2:= oJSON[0][0][8][1][0][1] ; Google libraries/databases

loop, % lln:=oJSON[8][0].length
    lng1.= oJSON[8][0][A_Index-1] (A_Index<lln? ", ": "")
loop, % lln:=oJSON[8][0].length
    lng2.= oJSON[8][3][A_Index-1] (A_Index<lln? ", ": "")
    
ls:=oJSON[2], lng1, lng2 ; Google detection and guess?? of source language

Str ; This is actually source input (not oJSON data) out of simplicity (might not be always the same - didn't check)
Pr1:= oJSON[0][1][3] ; Transliteration for source
Dym:= oJSON[7][1] ; Google suggestion of the source input
Tof:= oJSON[7][5] ; Google detection?? of error in the source input (pre-alpha stage!!! still to be investigated)
-------------------
Loop % lln:= oJSON[0].length
    mTr .= oJSON[0][A_Index-1][0] (A_Index<lln? "": ((Pr2:= oJSON[0][1][2])? "`n[" Pr2 "]": ""))

mTr ; Google translation
Pr2:= oJSON[0][1][2] ; Transliteration for translation

loop, % oJSON[1].length
{
    trn.= "♦ " oJSON[1][cW:=A_Index-1][0] "`n"
    Loop, % oJSON[1][cW][2].length
    {
        Loop, % ln:=oJSON[1][cW][2][tW:=A_Index-1][1].length
            tr.= oJSON[1][cW][2][tW][1][A_Index-1] (A_Index<ln? ", ": "")
        trn.= "    ▪ " ((ar:=oJSON[1][cW][2][A_Index-1][4])? ar " ": "")
             . oJSON[1][cW][2][A_Index-1][0] "  ► " tr "`n",  tr:= ""
    }
}    trn:= (trn? "▬ Translations of  ▌" oJSON[1][0][3] "`n" RTrim(trn, "`n"): "")

oJSON[1][0][3] ; actual word beeing translated (not always the same as sorce word)
oJSON[1][cW:=A_Index-1][0] ; Gramatical word* e.g. (noun, pronoun, verb, adjective, attribute, ...)
ar ; artical e.g (der, die, das) for German language
tr ; Google "Translations of" line* (translation > synonyms)
trn ; Google "Translations of" cluster (of words* and lines*)

etc..

[kairushinjuu]

@rommmcek Thank you for all your hardwork! Sorry for basically making your write me a script. I really appreciate it though, going through all the versions and see what was changed to what effect ^_^ Its a great learning experience. Also Thank you so much for the GoogleTranslate oJSON tutorial <3 Going to make use of this.

[rommmcek]

@kairushinjuu: My hard work was just counting commans and brackets.
Now we have a funciton to avoid this!

Spoiler

Run script, Esc: next exemp, ^Esc or Close Gui: Exit script.

Code: Select all

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.

Gui add, Edit, w500 h500 vEdt
Gui show

json=
(
[[["schlank","slim",null,null,2]
,[null,null,null,"slim"]
]
,[["adjective",["schlank","schmal","gering"]
,[["schlank",["slim","slender"]
,null,0.10874496]
,["schmal",["narrow","small","slim","thin","slender","lean"]
,null,0.020754337]
,["gering",["low","small","slight","little","minor","slim"]
,null,0.009354713]
]
,"slim",3]
,["verb",["schrumpfen","schlank machen"]
,[["schrumpfen",["shrink","shrivel","dwindle","atrophy","slim","depreciate"]
,null,7.722788E-5]
,["schlank machen",["slim","slenderize"]
,null,7.485183E-5]
]
,"slim",2]
]
,"en",null,null,[["slim",null,[["schlank",1000,true,false]
]
,[[0,4]
]
,"slim",0,0]
]
,0.86985385,[]
,[["en"]
,null,[0.86985385]
,["en"]
]
,null,null,[["verb",[[["lose weight","get thinner","lose/shed some pounds","lose some inches","get into shape","shape up","reduce","diet","go on a diet","slenderize"]
,"m_en_gbus0955300.022"]
,[["reduce","cut","cut down/back","make cutbacks in","scale down","trim","decrease","diminish","pare down","whittle away","prune","rationalize","downsize"]
,"m_en_gbus0955300.029"]
]
,"slim"]
,["adjective",[[["narrow","slender","slimline"]
,"m_en_gbus0955300.012"]
,[["slender","lean","willowy","sylphlike","svelte","lissom","graceful","snake-hipped","rangy","clean-limbed","trim","slight","slightly built","thin","as thin as a reed","skinny","size-zero","spare","attenuated","lanky","spindly"]
,"m_en_gbus0955300.008"]
,[["gracile","attenuate"]
,"m_en_gbus0955300.008"]
,[["slight","small","slender","faint","feeble","poor","flimsy","tenuous","fragile","negligible","marginal","minimal","outside","remote","distant","unlikely","improbable"]
,"m_en_gbus0955300.016"]
]
,"slim"]
]
,[["verb",[["make oneself thinner, especially by dieting.","m_en_gbus0955300.022","I need to slim down a bit"]
]
,"slim"]
,["adjective",[["(of a person or their build) gracefully thin; slenderly built (used approvingly).","m_en_gbus0955300.008","her slim figure"]
,["(of something abstract, especially a chance or margin) very small.","m_en_gbus0955300.016","there was just a slim chance of success"]
]
,"slim"]
,["noun",[["a course or period of slimming.","m_en_gbus0955300.032","a sponsored slim"]
,["a term used in parts of Africa to refer to AIDS.","m_en_gbus0955300.035"]
]
,"slim"]
]
,[[["the evidence is \u003cb\u003eslim\u003c/b\u003e",null,null,null,3,"m_en_gbus0955300.016"]
,["the girls were tall and \u003cb\u003eslim\u003c/b\u003e",null,null,null,3,"m_en_gbus0955300.008"]
,["a pair of \u003cb\u003eslim\u003c/b\u003e, immaculately cut slacks",null,null,null,3,"m_en_gbus0955300.013"]
,["her \u003cb\u003eslim\u003c/b\u003e figure",null,null,null,3,"m_en_gbus0955300.008"]
,["I need to \u003cb\u003eslim\u003c/b\u003e down a bit",null,null,null,3,"m_en_gbus0955300.022"]
,["a sponsored \u003cb\u003eslim\u003c/b\u003e",null,null,null,3,"m_en_gbus0955300.032"]
,["how can I \u003cb\u003eslim\u003c/b\u003e down my hips?",null,null,null,3,"m_en_gbus0955300.028"]
,["there was just a \u003cb\u003eslim\u003c/b\u003e chance of success",null,null,null,3,"m_en_gbus0955300.016"]
,["a \u003cb\u003eslim\u003c/b\u003e gold band encircled her wrist",null,null,null,3,"m_en_gbus0955300.012"]
]
]
]
)

GuiControl,, Edt, % txtJsn(json)
;GuiControl,, Edt, % prnJsn(json)
KeyWait Esc, D
KeyWait Esc
;============================================================

; exemp for having no line breaks
json= [[["schlank os gut","slim os good",null,null,3,null,null,[[],[]],[[["1814a2c300f02f227bcb04312cd2671a","tea_pt_en_2019q4.md"]],[["4d5e201a34474a12730540dc3bfae9fd","tea_en_de_2020q1.md"]]]]],null,"pt",null,null,[["slim os good",null,[["schlank os gut",0,true,false]],[[0,12]],"slim os good",0,0]],0.6054487,[],[["pt"],null,[0.6054487],["pt"]]]

GuiControl,, Edt, % txtJsn(json)
;GuiControl,, Edt, % prnJsn(json)
KeyWait Esc, D
KeyWait Esc
;============================================================

json=
(
[[["英語","English",null,null,2]
,[null,null,"Eigo","ˈiNG(ɡ)liSH"]
]
,[["noun",["英語","英国人"]
,[["英語",["English","English language"]
,null,0.47980523]
,["英国人",["English","Englishman"]
]
]
,"English",1]
,["adjective",["英国の","英語の"]
,[["英国の",["English","British"]
]
,["英語の",["English"]
]
]
,"English",3]
]
,"en",null,null,[["English",null,[["英語",1000,true,false]
]
,[[0,7]
]
,"English",0,0]
]
,1.0,[]
,[["en"]
,null,[1.0]
,["en"]
]
,null,null,null,[["adjective",[["relating to England or its people or language.","m_en_gbus0324780.005"]
]
,"English"]
,["noun",[["the language of England, widely used in many varieties throughout the world.","m_en_gbus0324780.010"]
,["the people of England.","m_en_gbus0324780.014"]
]
,"English"]
]
,[[["an \u003cb\u003eEnglish\u003c/b\u003e book",null,null,null,3,"neid_6195"]
,["her \u003cb\u003eEnglish\u003c/b\u003e is very good",null,null,null,3,"neid_6197"]
,["put that into \u003cb\u003eEnglish\u003c/b\u003e",null,null,null,3,"neid_6197"]
,["how do you say that in \u003cb\u003eEnglish\u003c/b\u003e?",null,null,null,3,"neid_6197"]
,["he's doing \u003cb\u003eEnglish\u003c/b\u003e at university",null,null,null,3,"neid_6197"]
,["say that in \u003cb\u003eEnglish\u003c/b\u003e",null,null,null,3,"neid_6197"]
,["she's \u003cb\u003eEnglish\u003c/b\u003e",null,null,null,3,"neid_6196"]
,["he speaks \u003cb\u003eEnglish\u003c/b\u003e",null,null,null,3,"neid_6197"]
,["\u003cb\u003eEnglish\u003c/b\u003e class",null,null,null,3,"neid_6195"]
,["\u003cb\u003eEnglish\u003c/b\u003e dictionary",null,null,null,3,"neid_6195"]
,["the \u003cb\u003eEnglish\u003c/b\u003e language",null,null,null,3,"neid_6195"]
,["\u003cb\u003eEnglish\u003c/b\u003e teacher",null,null,null,3,"neid_6195"]
,["they're speaking \u003cb\u003eEnglish\u003c/b\u003e",null,null,null,3,"neid_6197"]
,["what's the \u003cb\u003eEnglish\u003c/b\u003e for 'bia'?",null,null,null,3,"neid_6197"]
,["a film in \u003cb\u003eEnglish\u003c/b\u003e",null,null,null,3,"neid_6197"]
,["an \u003cb\u003eEnglish\u003c/b\u003e word",null,null,null,3,"neid_6195"]
,["she has a degree in \u003cb\u003eEnglish\u003c/b\u003e",null,null,null,3,"neid_6197"]
,["\u003cb\u003eEnglish\u003c/b\u003e exam",null,null,null,3,"neid_6195"]
]
]
]
)

GuiControl,, Edt, % txtJsn(json)
;GuiControl,, Edt, % prnJsn(json)

Return

GuiClose:
  ^Esc:: ExitApp

txtJsn(r, i:="   ", d:=0, b:="") { ; by RRR inspired by txtArr
    loop, % IsObject(r)? r.length: (r:= CreateScriptObj().("(" r ")")).length
		c.= IsObject(v:=r[k:=A_Index-1])? b k ":`n" txtJsn(v, i, d+1, b i): b k ": " v "`n", d>0? "": t:=c
    Return d>0? c: t
}

prnJsn(r, i:="   ", d:=50, b:="") { ; by RRR inspired by prnArr
    loop, % IsObject(r)? r.length: (r:= CreateScriptObj().("(" r ")")).length
        l.= b (k:=A_Index-1) ": ", (IsObject(v:=r[k]) && d>1)? l.=(t:=prnJsn(v, i, d-1, b i))? "`n" t: "": l.=v, l.= "`n"
    return RTrim(l, "`n")
}

CreateScriptObj() { ; by teadrinker
   static doc
   doc := ComObjCreate("htmlfile"), doc.write("<meta http-equiv='X-UA-Compatible' content='IE=9'>")
   Return ObjBindMethod(doc.parentWindow, "eval")
}

This will work only for "flat" arrays (of any depth), not for "dictionarys" (associative arrays), but teadrinker has solution for it too!

[LeFunk]

Is there a way to replace some parts of the translation?
For example, I’d like to replace hyphens with en-dashes, something like:

clipboard := StrReplace(clipboard,"-","–")

But it doesn’t seem to have any effect, wherever I might try adding it?

[rommmcek]

Try:

Code: Select all

r:= GoogleTranslate("Hello, World!", "en", "ru")
MsgBox % StrReplace(r,"-","–")

[LeFunk]

Thanks, got it!

[Hs1988]

Hello there! The scripts in this post are AMAZING . I have really enjoyed testing them
As a mechanical engineer I have used AHK for several application, but I am not a programmer at all. What I would need is to modify the script made for @rommmcek (which includes Phonetic Transcriptions) in order to get a the full phonetic transcription of any text. The @rommmcek 's script works perfectly, but only provides the phonetic transcription when the text has few words, otherwise the phonetic transcription is blank.

I have tried to modify by myself but I cannot understand why the script stops providing the phonetic transcription when the text has many words ( about more than 45 ). Is what I need possible?

Thank you in advance!

[rommmcek]

For

•私は病院で働いています。•毎日働く時間帯が違います。•私の仕事は英語の先生です。•私は生徒ではありません。•大学生です。•私はフランス料理が好きです。•私は日本食が好きです。•私は１８０センチです。•私の趣味は買い物です。•私はアメリカ出身です。•フランスから来ました。•私はブラジルの出身です。•初めまして。•はじめまして、私の名前はダグラスです、よろしくお願いします。

this (ad hoc) fix seems to work on the input side. Replace Src.= Str ((Pr1:= ojson[0][1][3])? "`n[" Pr1 "]": "") with:

Code: Select all

loop, % pln:=oJSON[0].length
        Str.= (Pr1:= ojson[0][A_Index-1][3])? "`n[" Pr1 "]": "", A_Index=pln? Src:= Str: ""

P.s.: Can you provide examples for both input and output if possible?

[Hs1988]

WOW! It worked perfectly. Now, no matter how long the text is, the full phonetic transcription is provided and matches with traslate.google.com

This script will save me tons of hours in my work.

You are my new hero @rommmcek. Thank you so so much!

[Pulover]

Thank you so much for this!

[Fuchisa]

Did not work on me at all

[Fuchisa]

Teadrinker versions say today weather is good and some russian stuff after then nothing comes. Osprey's version did not even return.

[teadrinker]

Teadrinker versions say today weather is good and some russian stuff after then nothing comes.

How do you use it? Write your code.

[Fuchisa]

Teadrinker versions say today weather is good and some russian stuff after then nothing comes.

How do you use it? Write your code.

I cant use it I do not know autohotkey lang. I copied your first message.

[garry]

maybe try example with GUI ( page-1 )

Code: Select all

-select language , copy marked text ctrl+c > see translation in selected language
-click AUDIO button to hear the text

[Fuchisa]

maybe try example with GUI ( page-1 )

Code: Select all

-select language , copy marked text ctrl+c > see translation in selected language
-click AUDIO button to hear the text

Thanks garry, example 2 worked on me.

[pgeugene]

Although now I can click and drag LButton to select only One word for translation.
However I found it easier and faster to double click Lbutton to select single word
How to modify the script if I want to Double click LBotton to select only One word for translation

[Haswell]

Hi all.
Is there a new workable solution?
I try to use this one:
https://www.autohotkey.com/boards/viewtopic.php?f=6&t=63835&p=344751#p344640

And have such an issue:

[rommmcek]

Thee must be some kind of misunderstanding. The script in your link does not contain any MsgBox.
Run the script, click with the left mouse button at the start of the desired text to translate and hold the button, drag the mouse to the end of the desired text to translate and release the left mouse button. The translation is displayed in the ToolTip. Then press Esc to delete the ToolTip. Still works for me, however script is now a bit obsolete and you should edit it at least at this line.

I found it easier and faster to double click Lbutton to select single word

Actually your question doesn't belong here! Anyway, try:

Spoiler

Code: Select all

#NoEnv  ; Recommended for performance and compatibility with future AutoHotkey releases.
; #Warn  ; Enable warnings to assist with detecting common errors.
SendMode Input  ; Recommended for new scripts due to its superior speed and reliability.
SetWorkingDir %A_ScriptDir%  ; Ensures a consistent starting directory.

~LButton:: 
    DClickT := DllCall("GetDoubleClickTime")
    MouseGetPos X0, Y0
    KeyWait, % SubStr(A_ThisHotkey, 2)
     if (A_TimeSinceThisHotkey > DClickT) {
        MouseGetPos X, Y 
        If ( sqrt( (X-X0)**2 + (Y-Y0)**2 ) < 5 )
            Return 
        sleep, 200
        Clipboard:=""
        Send ^c
        ClipWait, 0
        Translate()
    }
    else if (A_ThisHotkey = A_PriorHotkey && A_TimeSincePriorHotkey < dclickT) {
        MouseGetPos X, Y 
        If ( sqrt((X-X0)**2+(Y-Y0)**2) > 5 )
            Return 
        Sleep, 350
        Clipboard:=""
        Send ^c
        ClipWait, 0
        Translate()
    } 
return

Translate() {
    If (RegExmatch(clipboard, "[^\x00-\x7F]"))
        r:= GoogleTranslate(clipboard)
    Else
        r:= GoogleTranslate(clipboard,, "ja")
    ToolTip % r.3 "`n`n" r.4
}

F2:: ToolTip % r.3 "`n`n" r.4
~Esc:: ToolTip

GoogleTranslate(str, from := "auto", to := "en")  { ;function by RRR based on teadrinkers GoogleTranslate()
   static JS := CreateScriptObj(), _ := JS.( GetJScript() ) := JS.("delete ActiveXObject; delete GetObject;")

    json := SendRequest(JS, str, to, from, proxy := "")
    oJSON := JS.( "(" json ")" )
    
    step1:= oJSON[0][0][8][0][0][1], step2:= oJSON[0][0][8][1][0][1]
    int:= (step1? "1: " step1: "") (step2? "   2: " step2: "")
    
    loop, % lln:=oJSON[8][0].length
        lng1.= oJSON[8][0][A_Index-1] (A_Index<lln? ", ": "")
    loop, % lln:=oJSON[8][0].length
        lng2.= oJSON[8][3][A_Index-1] (A_Index<lln? ", ": "")
    lng := "a: " (ls:=oJSON[2]) "   b: " lng1 "   c: " lng2
    
    loop, % pln:=oJSON[0].length
        Str.= (Pr1:= ojson[0][A_Index-1][3])? "`n[" Pr1 "]": "", A_Index=pln? Src:= Str: ""

    Dym:= ojson[7][1]
¬   ((Tof:= ojson[7][5])=0)? Src.= (Dym? "`n  ►Did you mean: ▌" Dym "?": "")
         : (Tof=-1)? Src.= (Dym? "`n  ►Showing result for ▌" Dym "`n  ►Translate instead ▌" Str: ""): ""
    Loop % lln:= oJSON[0].length
        mTr .= oJSON[0][A_Index-1][0] (A_Index<lln? "": ((Pr2:= ojson[0][1][2])? "`n[" Pr2 "]": ""))
        
    Main:= Src "`n----------------------`n" mTr
    loop, % ojson[1].length
    {
        trn.= "♦ " ojson[1][cW:=A_Index-1][0] "`n"
        Loop, % ojson[1][cW][2].length
        {
            Loop, % ln:=ojson[1][cW][2][tW:=A_Index-1][1].length
                tr.= ojson[1][cW][2][tW][1][A_Index-1] (A_Index<ln? ", ": "")
                  ;. (Mod(A_Index, 5)=0&&A_Index<ln? "`n       ": "")
            trn.= "    ▪ " ((ar:=ojson[1][cW][2][A_Index-1][4])? ar " ": "")
                 . ojson[1][cW][2][A_Index-1][0] "  ► " tr "`n",  tr:= ""
        }
    ;}    trn:= (trn? "▬ Translations of  ►" oJSON[1][0][3] "◄`n" RTrim(trn, "`n"): "")
    }    trn:= (trn? "▬ Translations of  ▌" oJSON[1][0][3] "`n" RTrim(trn, "`n"): "")

    loop, % ojson[11].length
    {
        syn.= "♦ " ojson[11][cW:=A_Index-1][0] "  ▌" ojson[11][cW][2] "`n"
        Loop, % ojson[11][cw].length
            Loop, % ojson[11][cW][cN:=A_Index].length
                Loop, % ojson[11][cW][cN][sW:=A_Index-1].length
                    Loop, % ln:=ojson[11][cW][cN][sW][tW:=A_Index-1].length
                        syn.= (A_Index=1? "    ▪ ": "") ojson[11][cW][cN][sW][tW][A_Index-1] (A_Index<ln? ", ": "`n")
    }   syn:= (syn? "▬ Synonims`n" RTrim(syn, "`n"): "")
   
    loop, % ojson[12].length
    {
        def.= "♦ " ojson[12][cW:=A_Index-1][0] "  ▌" ojson[12][cW][2] "`n"
        loop, % ojson[12][cW][1].length
            qu:= ojson[12][0][1][A_Index-1][2]
          , def.= "    ▪ " ojson[12][cW][1][A_Index-1][0] (qu? "`n     """ qu """" "`n": "`n")
    }  def:= (def? "▬ Definitions`n" RTrim(def, "`n "): "")

    loop, % ln:=ojson[13][0].length
        exp.= "    ♦ " ojson[13][0][A_Index-1][0] (A_Index<ln? "`n": "")
    exp:= (exp? "▬ Examples`n" StrReplace(StrReplace(exp, "<b>", "▌"), "</b>"): "")

   Return [int, lng, Main, trn, syn, def, exp, Str, ls, mTr]
}

SendRequest(JS, str, tl, sl, proxy) { ; by malcev
   static http
   ComObjError(false)
   loop
   {
      if !http
      {
         http := ComObjCreate("WinHttp.WinHttpRequest.5.1")
     ¬:= ( proxy && http.SetProxy(2, proxy) )
         http.open( "get", "https://translate.google.com", 1 )
         http.SetRequestHeader("User-Agent", "Mozilla/5.0 (Windows NT 10.0; Win64; x64; rv:47.0) Gecko/20100101 Firefox/47.0")
         http.send()
         http.WaitForResponse(-1)
      }
      http.open( "POST", "https://translate.google.com/translate_a/single?client=webapp&sl="
         . sl . "&tl=" . tl . "&hl=en" ;. tl                                              ; &hl=en by RRR
         . "&dt=at&dt=bd&dt=ex&dt=ld&dt=md&dt=qca&dt=rw&dt=rm&dt=ss&dt=t&ie=UTF-8&oe=UTF-8&otf=0&ssel=0&tsel=0&pc=1&kc=1"
         . "&tk=" . JS.("tk").(str), 1 )

      http.SetRequestHeader("Content-Type", "application/x-www-form-urlencoded;charset=utf-8")
      http.SetRequestHeader("User-Agent", "Mozilla/5.0 (Windows NT 10.0; Win64; x64; rv:47.0) Gecko/20100101 Firefox/47.0")
      http.send("q=" . URIEncode(str))
      http.WaitForResponse(-1)
      if !InStr(http.responsetext, "<form id=""captcha-form""")
         break
      http := ""
      Sleep, 300 ; by RRR
   }
   Return http.responsetext
}

URIEncode(str, encoding := "UTF-8")  {
   VarSetCapacity(var, StrPut(str, encoding))
   StrPut(str, &var, encoding)

   While code := NumGet(Var, A_Index - 1, "UChar")  {
      bool := (code > 0x7F || code < 0x30 || code = 0x3D)
      UrlStr .= bool ? "%" . Format("{:02X}", code) : Chr(code)
   }
   Return UrlStr
}

GetJScript()
{
   script =
   (
      var TKK = ((function() {
        var a = 561666268;
        var b = 1526272306;
        return 406398 + '.' + (a + b);
      })());

      function b(a, b) {
        for (var d = 0; d < b.length - 2; d += 3) {
            var c = b.charAt(d + 2),
                c = "a" <= c ? c.charCodeAt(0) - 87 : Number(c),
                c = "+" == b.charAt(d + 1) ? a >>> c : a << c;
            a = "+" == b.charAt(d) ? a + c & 4294967295 : a ^ c
        }
        return a
      }

      function tk(a) {
          for (var e = TKK.split("."), h = Number(e[0]) || 0, g = [], d = 0, f = 0; f < a.length; f++) {
              var c = a.charCodeAt(f);
              128 > c ? g[d++] = c : (2048 > c ? g[d++] = c >> 6 | 192 : (55296 == (c & 64512) && f + 1 < a.length && 56320 == (a.charCodeAt(f + 1) & 64512) ?
              (c = 65536 + ((c & 1023) << 10) + (a.charCodeAt(++f) & 1023), g[d++] = c >> 18 | 240,
              g[d++] = c >> 12 & 63 | 128) : g[d++] = c >> 12 | 224, g[d++] = c >> 6 & 63 | 128), g[d++] = c & 63 | 128)
          }
          a = h;
          for (d = 0; d < g.length; d++) a += g[d], a = b(a, "+-a^+6");
          a = b(a, "+-3^+b+-f");
          a ^= Number(e[1]) || 0;
          0 > a && (a = (a & 2147483647) + 2147483648);
          a `%= 1E6;
          return a.toString() + "." + (a ^ h)
      }
   )
   Return script
}

CreateScriptObj() {
   static doc
   doc := ComObjCreate("htmlfile")
   doc.write("<meta http-equiv='X-UA-Compatible' content='IE=9'>")
   Return ObjBindMethod(doc.parentWindow, "eval")
}

It supports Click and drag, double click as well as tripple click (whole line in most editors, whole paragraph in most browsers)

[kunkel321]

Hi Teadrinker and All,
Is there a list somewhere of the different languages that this sctipt will work with? And also, what the abbreviations for them are? For example:
ru = Russian
es = Spanish
en = English
...Others?