Disable all keyboard buttons

[chaoscreater]

Hello,
I added an option to also hide the screen and choose the hiding color
Press Alt + F3 to test

how to use the function:
hk(keyboard:=false, mouse:=0, message:="", timeout:=3, displayonce:=false,screen:=false, screencolor:="blue")

keyboard (true/false).......................... disable/enable keyboard
mouse=1........................................ disable all mouse buttons
mouse=2........................................ disable right mouse button only
msessage....................................... display a message
timeout........................................ how long to display the message in sec
displayonce (true/false) ...................... display a message only once or always
hide the screen (true/false)................... hide or show everything
ScreenColor ................................... RGB Hex background color for the hiding GUI

Code: Select all

#SingleInstance force

!F1::hk(1,1,"KEYBOARD AND MOUSE LOCKED!  -  ALT+F2 TO UNLOCK")              ; Disable all keyboard keys and mouse buttons
!F2::hk(0,0,"KEYBOARD AND MOUSE UNLOCKED!  -  ALT-F1 TO LOCK")              ; Enable all keyboard keys and mouse buttons
!F3::hk(1,1,"KEYBOARD MOUSE AND SCREEN LOCKED!  -  ALT+F2 TO UNLOCK",,,1,"teal")   ; Disable keyboard mouse and screen


hk(keyboard:=false, mouse:=0, message:="", timeout:=3, displayonce:=false,screen:=false, screencolor:="blue") { 

;keyboard (true/false).......................... disable/enable keyboard
;mouse=1........................................ disable all mouse buttons
;mouse=2........................................ disable right mouse button only
;msessage....................................... display a message
;timeout........................................ how long to display the message in sec
;displayonce (true/false) ...................... display a message only once or always
;hide the screen (true/false)................... hide or show everything
;ScreenColor ................................... RGB Hex background color for the hiding GUI 


   static AllKeys, z, d, kb, ms, sc
   z:=message, d:=displayonce, kb:=keyboard, ms:=mouse, sc:=screen

      For k,v in AllKeys {
           Hotkey, *%v%, Block_Input, off         ; initialisation
      }
   if !AllKeys {
      s := "||NumpadEnter|Home|End|PgUp|PgDn|Left|Right|Up|Down|Del|Ins|"
      Loop, 254
         k := GetKeyName(Format("VK{:0X}", A_Index))
       , s .= InStr(s, "|" k "|") ? "" : k "|"
      For k,v in {Control:"Ctrl",Escape:"Esc"}
         AllKeys := StrReplace(s, k, v)
      AllKeys := StrSplit(Trim(AllKeys, "|"), "|")
   }
   ;------------------
   if (mouse!=2)  ; if mouse=1 disable right and left mouse buttons  if mouse=0 don't disable mouse buttons
    {
        For k,v in AllKeys {
           IsMouseButton := Instr(v, "Wheel") || Instr(v, "Button")
           Hotkey, *%v%, Block_Input, % (keyboard && !IsMouseButton) || (mouse && IsMouseButton) ? "On" : "Off"
        }
    }
   if (mouse=2)   ;disable right mouse button (but not left mouse)
    {                
     ExcludeKeys:="LButton"
      For k,v in AllKeys {
           IsMouseButton := Instr(v, "Wheel") || Instr(v, "Button")
           if v not in %ExcludeKeys%
           Hotkey, *%v%, Block_Input, % (keyboard && !IsMouseButton) || (mouse && IsMouseButton) ? "On" : "Off"
        }
    }
   if d
    {
   if (z != "") {
      Progress, +AlwaysOnTop W2000 H43 b zh0 cwFF0000 FM20 CTFFFFFF,, %z%
      SetTimer, TimeoutTimer, % -timeout*1000
   }
   else
      Progress, Off
     }
   Block_Input:
   if (d!=1)
    {
   if (z != "") {
	    if (kb || ms)
			Progress, W2000 H43 b zh0 cwFF0000 FM20 CTFFFFFF,, %z%
		else
			Progress, W2000 H43 b zh0 cw009F00 FM20 CTFFFFFF,, %z%
		SetTimer, TimeoutTimer, % -timeout*1000
   }
   else
      Progress, Off
     }


if (sc=1)
   { 
     Gui screen:  -Caption
     Gui screen: Color,  % screencolor
     Gui screen: Show, x0 y0 h74 w%a_screenwidth% h%a_screenheight%, New GUI Window
   }
   else
      gui screen: Hide


   Return
   TimeoutTimer:
   Progress, Off
   Return
}

Cheers

I'm running into a weird issue. All I'm doing is just changing from ALT+F1 to SHIFT+ALT+F1 and ALT+F2 to SHIFT+ALT+F2.

If I press SHIFT+ALT+F2, it triggers the unlock, great. However, if I lock first (with SHIFT+ALT+F1) and then try to unlock, it won't trigger the unlock. Any ideas why?

[SpeedMaster]

If I press SHIFT+ALT+F2, it triggers the unlock, great. However, if I lock first (with SHIFT+ALT+F1) and then try to unlock, it won't trigger the unlock. Any ideas why?

Combinations of three or more keys are generally not supported but you can try this...

Code: Select all

+!F1::
; always make  sure that the keys are released before blocking the keyboard ! :)
KeyWait, shift, up  
KeyWait, alt, up
KeyWait, F1, up
hk(1,1,"KEYBOARD AND MOUSE LOCKED!  -  Shift-ALT-F2 TO UNLOCK")              ; Disable all keyboard keys and mouse buttons
return

+F2::
if GetKeyState("Alt", "P")                                                  ; Press in this order Shift-Alt-F2   (Alt Shift F2 will not work)
hk(0,0,"KEYBOARD AND MOUSE UNLOCKED!  - ALT-Shift-F1 TO LOCK")              ; Enable all keyboard keys and mouse buttons
return

Regards

[zed6250jb]

Is there a way to leave the script attached intact, but add an activation based on timer to disabled kb and mouse? so for example after 5 minuets automatically disable kb and mouse. There is also another additional idea to add to that and create an idle rest watchdog so everytime a key or mouse has activity the timer resets without disable. Please let me know.

[zed6250jb]

attached

[A Keymaker]

How these scripts would have to be modified in order to:
[...]

A-B: yes

C-E: I will take care of this soon

[A Keymaker]

How these scripts would have to be modified in order to:
[...]

[...]
C-E: I will take care of this soon

C and E [i.e.. blocking of mouse input] can be achieved with this script

Code: Select all

counter := 0

BlockInput, MouseMove
Hotkey, *LButton, BlockInputMouseMoveClick
Hotkey, *MButton, BlockInputMouseMoveClick
Hotkey, *RButton, BlockInputMouseMoveClick
Hotkey, *WheelUp, BlockInputMouseMoveClick
Hotkey, *WheelDown, BlockInputMouseMoveClick
Hotkey, *WheelLeft, BlockInputMouseMoveClick
Hotkey, *WheelRight, BlockInputMouseMoveClick
Hotkey, *XButton1, BlockInputMouseMoveClick
Hotkey, *XButton2, BlockInputMouseMoveClick

$MButton::   ; A single click with Middle Mouse Button restores input by closing this AHK file. But because the script for blocking of input and the one for keeping monitor off both use Middle Mouse Button as a fail-safe / turn off, instead of 1 MMB click 2 fast ones are required
*/
    counter++
    if (counter = 1)
    {
        ExitApp
    }
return

BlockInputMouseMoveClick()
{
    return
}

with a turn off switch in form of single Middle Mouse Click. [And thus the D issue I have ditched entirely]

[rockitdontstopit]

This is a simple script that disables all keyboard buttons except escape. To end the script, simply press escape and a message box will pop up.
What might be the use for this script? Personally, I used it when I was cleaning my keyboard and had to remove all the keys, so I wouldn't mess up my computer by spamming random buttons (I know, I know, I could have turned off my computer, but who has time for that.) but you are free to use the script as you wish.

Why not just win lock with WIN + L? That's what I do when I want to clean my keyboard with rubbing alcohol when it starts to feel sticky.

[A Keymaker]

[...]
Why not just win lock with WIN + L? That's what I do when I want to clean my keyboard with rubbing alcohol when it starts to feel sticky.

Your method forces user later on to enter password for Windows and does not alleviate issue of kids, pets and cockroaches playing with the keyboard

When I clean any computer hardware I disconnect it from power source or at least kill its input mechanically

[X-Knight]

[Mod edit: Removed empty codebox.]

Can someone make me a code for "Disable all Keyboard Buttons" while I'm holding my "Mouse Button 2" and when I release the "Mouse Button 2", It'll "Enable all Keyboard Buttons"

[GEV]

Can someone make me a code for "Disable all Keyboard Buttons" while I'm holding my "Mouse Button 2" and when I release the "Mouse Button 2", It'll "Enable all Keyboard Buttons"

Code: Select all

#Requires AutoHotkey v1.1
#InstallKeybdHook

XButton2::
	BlockKeyboard("On")
	KeyWait XButton2
	BlockKeyboard("Off")
return

BlockKeyboard(state){
    ; https://stackoverflow.com/a/61700303/3419297
    Loop, 512
    {
        Key := Format("SC{:X}",A_Index)
        If (state = "On")
            Hotkey, *%Key%, do_nothing, On UseErrorLevel
        else
            Hotkey, *%Key%, do_nothing, Off UseErrorLevel
    }
    do_nothing:
    return
}

[A Keymaker]

If anybody is interested in a feedback, then for me with my Logitech Mouse MX Anywhere 2 Business Travel / Logitech Mouse MX Anywhere 2 For Amazon on Windows 10 Enterprise 20H2 x64 [10.0.19042] the above code does nothing

[GEV]

@A Keymaker
I editet it adding

Code: Select all

#InstallKeybdHook

[A Keymaker]

My keys are still not blocked when that side mouse button is being pressed

[GEV]

Works here (Logitech G700).