Multipart - Create form-data for http request

[tmplinshi]

New Version:

CreateFormData - Creates "multipart/form-data" for http post
https://autohotkey.com/boards/viewtopic.php?f=6&t=7647

This function is similar to the cURL option "--form".

Class Multipart (Only works in ANSI!)

Spoiler

Code: Select all

; Description: Create form-data for http request (Only works in ANSI!)
; AHK Version: 1.1.14.03 A32
Class Multipart
{
	Make(ByRef PostData, ByRef PostHeader, Array_FormData*) {
		static CRLF := "`r`n"
		static DW   := "UInt"
		static ptr  := (A_PtrSize = "") ? DW : "Ptr"

		PostData := ""
		Boundary := this.RandomBoundary()

		For Index, FormData in Array_FormData
		{
			If (  pos := InStr(FormData, "=")  )
				FormData_Name    := SubStr(FormData, 1, pos-1)
			  , FormData_Content := SubStr(FormData, pos+1)
			Else
				FormData_Name    := FormData

			If (  SubStr(FormData_Content, 1, 1) = "@"  )  {
				FilePath := SubStr(FormData_Content, 2)

				FileRead, binData, %FilePath%
				FileGetSize, binSize, %FilePath%
				SplitPath, FilePath, FileName

				VarSetCapacity( placeholder, binSize, 32 )
				PostData .= "------------------------------" Boundary CRLF
				            . "Content-Disposition: form-data; name=""" FormData_Name """; filename=""" FileName """" CRLF
                            . "Content-Type: " this.MimeType(binData) CRLF CRLF
                offset   := StrLen( PostData )
                PostData .= placeholder CRLF
			}
			Else
			{
				If (  SubStr(FormData_Content, 1, 1) = "<"  )
					FileRead, FormData_Content, % SubStr(FormData_Content, 2)

				PostData .= "------------------------------" Boundary CRLF
				            . "Content-Disposition: form-data; name=""" FormData_Name """" CRLF CRLF
				            . FormData_Content CRLF
			}
		}

		PostData .= "------------------------------" Boundary "--" CRLF
		If offset
			DllCall( "RtlMoveMemory", Ptr, &PostData + offset, Ptr, &binData, DW, binSize )

		PostHeader := "Content-Type: multipart/form-data; boundary=----------------------------" Boundary

		Return Boundary
	}

	MimeType(ByRef binData) {
		static HeaderList := ["424D"     , "4749463"  , "FFD8FFE"   , "89504E4"  , "4657530"                      , "49492A0"   ]
		static TypeList   := ["image/bmp", "image/gif", "image/jpeg", "image/png", "application/x-shockwave-flash", "image/tiff"]

		this.toHex(binData, hex, 4)

		For Index, Header in HeaderList
			If RegExMatch(hex, "^" Header)
				Return TypeList[ Index ]

		Return "application/octet-stream"
	}

	toHex( ByRef V, ByRef H, dataSz=0 )  { ; http://goo.gl/b2Az0W (by SKAN)
		P := ( &V-1 ), VarSetCapacity( H,(dataSz*2) ), Hex := "123456789ABCDEF0"
		Loop, % dataSz ? dataSz : VarSetCapacity( V )
			H  .=  SubStr(Hex, (*++P >> 4), 1) . SubStr(Hex, (*P & 15), 1)
	}

	RandomBoundary() {
		static CharList := "0|1|2|3|4|5|6|7|8|9|a|b|c|d|e|f|g|h|i|j|k|l|m|n|o|p|q|r|s|t|u|v|w|x|y|z"
		Sort, CharList, D| Random
		StringReplace, Boundary, CharList, |,, All
		Return SubStr(Boundary, 1, 12)
	}
}

Usage: Multipart.Make(ByRef PostData, ByRef PostHeader, "name=content" [, "name=content", ...])
To force the 'content' part to be a file, prefix the file name with an @ sign. To just get the content part from a file, prefix the file name with the symbol <.

Examples:

• Example 1 - Upload image to Google Images
  Spoiler

  Code: Select all

  If A_IsUnicode
  {
  	MsgBox, 48, :(, Please use AutoHotkey ANSI version to run!
  	ExitApp
  }
  
  ; curl http://www.google.com/searchbyimage/upload -F "encoded_image=@smile.gif"
  
  #Include <HTTPRequest> ; http://www.autohotkey.com/board/topic/67989-func-httprequest-for-web-apis-ahk-b-ahk-lunicodex64/
  #Include <Class_Multipart>
  
  Multipart.Make(PostData, PostHeader, "encoded_image=@smile.gif")
  HttpRequest("http://www.google.com/searchbyimage/upload", PostData, PostHeader, "+NO_AUTO_REDIRECT")
  Run, % RegExReplace(PostHeader, "^.*Location: ([^\r\n]+).*$", "$1")
  Return

• Example 2 - Upload image to http://uploadpie.com/
  Spoiler

  Code: Select all

  If A_IsUnicode
  {
  	MsgBox, 48, :(, Please use AutoHotkey ANSI version to run!
  	ExitApp
  }
  
  #Include <HTTPRequest> ; http://www.autohotkey.com/board/topic/67989-func-httprequest-for-web-apis-ahk-b-ahk-lunicodex64/
  #Include <Class_Multipart>
  
  ; curl http://uploadpie.com/ -F "uploadedfile=@smile.gif" -F "expire=1" -F "MAX_FILE_SIZE=3145728" -F "upload=1"
  
  Multipart.Make(PostData, PostHeader, "uploadedfile=@smile.gif", "expire=1", "MAX_FILE_SIZE=3145728", "upload=1")
  HttpRequest("http://uploadpie.com/", PostData, PostHeader)
  Run, % RegExReplace(PostData, "s)^.*id=""uploaded"" value=""([^""]+).*", "$1")
  Return

• Example 3 - Upload code to http://pastebin.com
  Spoiler

  Code: Select all

  If A_IsUnicode
  {
  	MsgBox, 48, :(, Please use AutoHotkey ANSI version to run!
  	ExitApp
  }
  
  #Include <HTTPRequest> ; http://www.autohotkey.com/board/topic/67989-func-httprequest-for-web-apis-ahk-b-ahk-lunicodex64/
  #Include <Class_Multipart>
  
  ; curl http://pastebin.com/post.php -F "submit_hidden=submit_hidden" -F "post_key=" -F "paste_private=0" -F "paste_name=Test Title" -F "paste_format=149" -F "paste_expire_date=N" -F "paste_code=<test.ahk"
  Multipart.Make(PostData, PostHeader
  	, "submit_hidden=submit_hidden"
  	, "post_key="
  	, "paste_private=0"
  	, "paste_name=Test Title"
  	, "paste_format=149"
  	, "paste_expire_date=N"
  	, "paste_code=<test.ahk") ; Read content from test.ahk. Or "paste_code=MsgBox, Hi"
  HttpRequest("http://pastebin.com/post.php", PostData, PostHeader, "+NO_AUTO_REDIRECT")
  Run, % "http://pastebin.com" RegExReplace(PostHeader, "i)^.*Location: ([^\r\n]+).*$", "$1")
  Return

Download: https://www.dropbox.com/s/coxud571yseda6q/Multipart.7z

Hope someone can make a Unicode version, and a WinHttp sample. I've asked this question at here weeks ago.

[nepter]

Unicode problem solved?

[tmplinshi]

not yet... can you help? ^_^

[nepter]

Wait for VxE to update multipart support in HTTPRqeuest.
Or modify yourself

[arcticir]

你们够了

[Peace1]

Hi tmplinshi,

Sorry to bump this old topic but i need your help please. I'm trying to upload files using your method but i can"t manage it :\

Here is my post where i explain my issue.

Perhaps you are more skilled than me and you can manage it better

Thank you in advance, regards.

[tmplinshi]

Hello Peace1,

Please try the new version CreateFormData(), which support AHK Unicode. Let me know if you encounter any issue.

[Peace1]

Hello Peace1,

Please try the new version CreateFormData(), which support AHK Unicode. Let me know if you encounter any issue.

Hi tmplinshi,

Thank you for the link, i'm trying to understand how i can do it but i'm not very skilled with HTTP Request and Headers. I know how to post and create Ticket for my project using AHK code but for upload file is little hard for me.

Can you try it for me, please ?

Regards.