WinCloseAuto() : Closes automatically when specified windows show up

[SKAN]

WinCloseAuto(SetHook, WEP.1, WEP.2, WEP.3, WEP.4)
WinCloseAuto() will monitor and close up to 4 windows.
 
Parameters::
SetHook parameter should not be omitted and should be True to set Hook on, or False to Unhook.
WEP.1 .. WEP.4 are WinExist() parameters which needs to be passed as separate array for each parameter.
Note: WinExist() has 4 parameters. The examples below utilizes only the first parameter

Usage examples:
The following code will auto-close whenever Calculator, Notepad or Windows Task Manager shows up.
 

Code: Select all

#NoEnv
#Warn
#SingleInstance, Force
Process, Priority,,High
#Persistent ; <== required

WinCloseAuto( True, ["ahk_class Notepad"]
                  , ["ahk_class CalcFrame"] 
                  , ["Windows Task Manager ahk_class #32770"] )

 
The following example is similar to above except you can toggle the hook between on and off with the Hotkey. F2
 

Code: Select all

#NoEnv
#Warn
#SingleInstance, Force
Process, Priority,,High
Hook := 0

F2:: WinCloseAuto( Hook:=!Hook, ["ahk_class Notepad"]
                              , ["ahk_class CalcFrame"] 
                              , ["Windows Task Manager ahk_class #32770"] )

 

---

 
The function:
 

Code: Select all

WinCloseAuto(P*) {        ; WinCloseAuto v0.50 by SKAN on D36I/D36I @ tiny.cc/wincloseauto
Static CBA:=RegisterCallBack("WinCloseAuto"), WEP:="", hHook:=0, EVENT_OBJECT_SHOW:=0x8002
  If IsObject(P)
     Return (P.1=1 && (WEP:=P)) ? hHook:=DllCall("SetWinEventHook","Int",EVENT_OBJECT_SHOW
           ,"Int",EVENT_OBJECT_SHOW, "Ptr",0, "Ptr",CBA, "Int",0, "Int",0, "Int",0, "Ptr")
          : (P.1=0 && (WEP:="")="") ? DllCall("UnhookWinEvent", "Ptr",hHook) : "" 
  If WinExist((WEP.2)*) || WinExist((WEP.3)*)  || WinExist((WEP.4)*) || WinExist((WEP.5)*) 
     PostMessage, 0x112, 0xF060 ;  WM_SYSCOMMAND, SC_CLOSE
}

[Kisang Kim]

wonderfull, thank you.

can i make wantclose.ini and list up like

------ list ini file -----------------------------
ahk_class Notepad
ahk_class CalcFram
Windows Task Manager ahk_class #32770

sorry i'm biginner

[need4speed]

thanks for the script.
In my test Closing Win10 calculator (ahk_class Windows.UI.Core.CoreWindow) is not working.

Code: Select all

WinClose, ahk_class WinCloseWindows.UI.Core.CoreWindow

does not work either, do you know why?

[SKAN]

wonderfull, thank you.

Welcome.. and welcome to AutoHotkey

can i make wantclose.ini and list up like

------ list ini file -----------------------------
ahk_class Notepad
ahk_class CalcFram
Windows Task Manager ahk_class #32770

sorry i'm biginner

 
 
wantclose.ini should contain following:

Code: Select all

[WinList]
1=ahk_class Notepad
2=ahk_class CalcFrame
3=Windows Task Manager ahk_class #32770

and should be in the same folder as the following script:

Code: Select all

#NoEnv
#Warn
#SingleInstance, Force
Process, Priority,,High
SetWorkingDir, %A_ScriptDir%
#Persistent

ObjWEP:=[], WinTitle:=""
Loop
{
  IniRead, WinTitle, wantclose.ini, WinList, %A_Index%
  If (WinTitle="ERROR")
     Break
  ObjWEP.Push(StrSplit(WinTitle,",", A_Space))   
} 

WinCloseAuto(True, ObjWEP*)
Return ; // end of auto-execute section


WinCloseAuto(P*) {        ; WinCloseAuto v0.50 by SKAN on D36I/D36I @ tiny.cc/wincloseauto
Static CBA:=RegisterCallBack("WinCloseAuto"), WEP:="", hHook:=0, EVENT_OBJECT_SHOW:=0x8002
  If IsObject(P)
     Return (P.1=1 && (WEP:=P)) ? hHook:=DllCall("SetWinEventHook","Int",EVENT_OBJECT_SHOW
           ,"Int",EVENT_OBJECT_SHOW, "Ptr",0, "Ptr",CBA, "Int",0, "Int",0, "Int",0, "Ptr")
          : (P.1=0 && (WEP:="")="") ? DllCall("UnhookWinEvent", "Ptr",hHook) : "" 
  If WinExist((WEP.2)*) || WinExist((WEP.3)*)  || WinExist((WEP.4)*) || WinExist((WEP.5)*) 
     PostMessage, 0x112, 0xF060 ;  WM_SYSCOMMAND, SC_CLOSE
}

[SKAN]

thanks for the script.
In my test Closing Win10 calculator (ahk_class Windows.UI.Core.CoreWindow) is not working.

Code: Select all

WinClose, ahk_class WinCloseWindows.UI.Core.CoreWindow

does not work either, do you know why?

Ah! Thanks. Didn't test it in Win10. Will do and reply.

[SKAN]

In my test Closing Win10 calculator (ahk_class Windows.UI.Core.CoreWindow) is not working.

Did a quick test.
AHK Window Spy shows Calculator ahk_class ApplicationFrameWindow for me in Win10 ?!

[need4speed]

AHK Window Spy shows Calculator ahk_class ApplicationFrameWindow for me in Win10 ?!

thanks for checking, you're right. The problem was caused by me when using the WinSpyM Finder Tool,
I accidentally selected the control Windows.UI.Core.CoreWindow not ApplicationFrameWindow.

Win10 flat design is pretty weird, I don't like these hidden borders (5px) left and right.

[adrian_9832]

very useful thanks!

[Netmano]

Awesome script. Incredible that you can so much with few lings of code.
I really need to learn how to wield this power myself, I will reverse engineer your case

[SKAN]

@adrian_9832 / @Netmano : Thanks for the feedback

[SKAN]

After 4 weeks observation, I will say the following works fine for dismissing PD ads.

Code: Select all

WinCloseAuto(True, ["Panda Dome ahk_exe PSUAConsole.exe",,,"Panda Dome"])

[andymbody]

Thanks @SKAN !

Is there a V2 version of this. I am trying to decipher your compressed function so I can convert, but not successful yet. So I thought I would ask.

Thanks!
Andy