[INI tools] INI2Array Array2INI

[Xeo786]

INI tools uses Native AHK INI read and write commands,

Examples

Code: Select all

;Making 2d Array from INI and Saving that 2d Array as INI to new location
;The Benefit is it will clean the INI, it will put every stuff in ascending order and have removed all the empty lines and Gaps
;The Disadvantage is you get all the comments removed
Array2INI(INI2Array(iniFile), newLocationINI)

;This simply doing the same to existing INI
CleanINI(iniFile) 

;Simply returning Array of All the Sections
Sections := GetINISections(iniFile)

;Thats how you get every key, Section and Values from into 1D array
array := INI2Array(iniFile)	

Lib

Spoiler

Code: Select all

Array2INI(iniArray,Saveto)
{
	for Sec, Seclines in iniArray
		for k, v in Seclines
			IniWrite, % v, % Saveto, % Sec, % k
}

INI2Array(iniFile)
{
	iniarray := []
	for i, Sec in GetINISections(iniFile)
	{	
		IniRead, SecLines, % iniFile, % Sec
		for k, line in StrSplit(SecLines, "`n")
		{
			IniRead, Val , % iniFile, % Sec, % Key := substr(line, 1, instr(line,"=")-1)
			iniarray[Sec,Key] := Val
		}
	}
	return iniarray
}

GetINISections(iniFile)
{
	IniRead, SectionNames, % iniFile
	return StrSplit(SectionNames, "`n")
}

CleanINI(iniFile)
{
	iniarray := INI2Array(iniFile)
	FileDelete, % iniFile
	while FileExist(iniFile)
		sleep, 100
	Array2INI(iniArray,iniFile)
}

[burque505]

@Xeo786, looks useful, thanks for sharing it.
Regards,
burque505