How to empty an array?

[arathra]

This should be easy but for the life of me I can't get it working.

How can I empty an array?

Code: Select all

global SearchWordsArray := Object()
; fill it with stuff, do stuff with it then... try this but it doesn't appear to work
SearchWordsArray.RemoveAll()
; then refill with other stuff and so on

Thanks for any help!

[Helgef]

There is no such built in method. Can't you just overwrite the array?

[Guest]

Why would you need to have a builtin method? Just clear it

Code: Select all

Array:=["a","b"]
MsgBox % ">" Array[1] "<"
Array:=[]
MsgBox % ">" Array[1] "<"
Array.Push("a")
MsgBox % ">" Array[1] "<"

[jNizM]

Freeing Objects

[arathra]

I didn't realise that wasn't a method - I found it in the archived forums but obviously made a mistake.

This appears to work then:

Code: Select all

global SearchWordsArray := Object()
; fill it with stuff, do stuff with it then... empty it thus:
SearchWordsArray := Object()
; then refill with other stuff and so on

Does this seem right?

[Grendahl]

To empty the entire SearchWordsArray, per the link that jNizM posted...

Code: Select all

SearchWordsArray := ""

[arathra]

With this:

Code: Select all

global SearchWordsArray := Object()
; do some stuff
SearchWordsArray := ""
; load array

Then the array does not load and returns a length of 0.

This, however, loads and returns a length appropriate to what was inserted:

Code: Select all

global SearchWordsArray := Object()
; do some stuff
SearchWordsArray := Object()
; load array

I don't know if it's creating 2 SearchWordsArray objects or if redeclaring it is overwriting the first.

[Grendahl]

Of course the first example doesn't work... you empty the array before trying to load it.

[lexikos]

SearchWordsArray := "" does not necessarily "empty the array". It does not even necessarily free the array.

Code: Select all

SearchWordsArray := Object()
SecondReference := SearchWordsArray

if (SecondReference == SearchWordsArray)
    MsgBox Both variables contain the same array.

SearchWordsArray.Push(42)
MsgBox % SecondReference[1] ; 42

SearchWordsArray := ""
MsgBox % SecondReference[1] ; 42 -- Array is not empty!

An array object is just a value. If you store some other value in the variable (such as ""), it won't contain the array anymore.

There are only two ways to empty an array:

1. Remove all of its items.
2. Ensure there are no more references to the array; then it will be both emptied and deleted.

There are multiple ways to remove all items. The most efficient way can only be used if you know the range of values, and the array does not use objects as keys. If it is a simple array rather than an associative array, it is easy:

Code: Select all

if SearchWordsArray.MinIndex() != ""  ; Not empty.
    SearchWordsArray.Delete(SearchWordsArray.MinIndex(), SearchWordsArray.MaxIndex())

If you know the first array index is always 1,

Code: Select all

SearchWordsArray.Delete(1, SearchWordsArray.Length())

If it is an associative array using strings as keys, you need to choose a string last_key >= all existing keys.

Code: Select all

SearchWordsArray.Delete("", last_key)

If you only have one reference to the array, the easier solution is to replace it with a new array.