Extract text from a string with tabs

[Didier3L]

Bonjour,
Je cherche à extraire du texte d'une chaine de caractère du presse papier délimité par des tabulations ?

Hello,
I'm trying to extract text from a character string in the tab-delimited clipboard?

Contents of the paper press :

Code: Select all

Jean	Dupont	10 Rue des roses	75016	Paris

I would like to retrieve in a variable each element
prenom = Jean
nom = Dupont
adresse = 10 Rue des roses
CP = 75016
ville = Paris

How can I do ?

[garry]

example for text file / or use clipboard ( instead of variable aac )

Code: Select all

FileSelectFile, FL1, 3,%a_desktop%, Choose text file:,Supported Files (*.txt;*.csv)
If FL1 =
  ExitApp
f2=%a_scriptdir%\NEW.txt
ifexist,%f2%
  filedelete,%f2%
fileread,aac,%fl1%              ;- read txt-file to memory
Loop,parse,aac,`n,`r            ;- parse each line by `n ascii-10 (EndOfLine ascii 13,10 )
  {
  x:= a_loopfield
  if x=
     continue
  stringsplit,C,x,`t
    e .= "prenom=" . c1 . ";Nom=" . c2 . ";Adresse=" . c3 . ";CP=" . c4 . ";Ville=" . c5 . "`r`n"
  }
fileappend,%e%,%f2%
e=
run,%f2%
exitapp

[F4Jonatas]

Code: Select all

MsgBox, % Main( "Jean	Dupont	10 Rue des roses	75016	Paris" ).Adresse
ExitApp

Main( String ) {
	Local Result := {}
	Local Keys := [ "Prenom", "Nom", "Adresse", "CP", "Ville" ]
	Local LoopField := ""
	Local Count := 1

	While ( Count := RegExMatch( String, "i)([^\t]+)", LoopField, Count + StrLen( LoopField ) )) {
		Result[ Keys[ A_Index ] ] := LoopField
	}

	Return Result
}

Tell me if it worked.

[Xeo786]

I am totally blank at regex so two simple way come to my mind

Code: Select all

H_array := ["prenom","nom","adresse","CP","ville"]
clipboard := "Jean	Dupont	10 Rue des roses	75016	Paris" ; remove this line to access live clipboard

ArryClip:=[] 
for a, b in StrSplit(clipboard, "`t") ;1st way 
	ArryClip.Insert(b)

MainClip := {}
Loop, parse, clipboard, %a_tab% ; 2nd way
	MainClip[ H_array[ A_Index ] ] := A_LoopField

msgbox % MainClip.adresse "`n|||OR|||`n" ArryClip[3]
clipboard =
return 

its up to you how would you like to achive your goal

[jmeneses]

Another way

Code: Select all

xString := "Jean	Dupont	10 Rue des roses	75016	Paris" 
RegExMatch(xString,"^(?P<Prenom>\w+)\t(?P<Nom>\w+)\t(?P<adresse>\S.+\w+)\t(?P<CP>\d.+)\t(?P<ville>\w.+)$",My)
Msgbox % "prenom" A_Tab "(" MyPrenom ")`nnom" A_Tab "(" MyNom  ")`nadresse" A_Tab "(" Myadresse 
. ")`nCP" A_Tab "(" MyCP ")`nVille" A_Tab "(" MyVille ")"

[F4Jonatas]

This way was faster, but creates global variables.

Another way

Code: Select all

xString := "Jean	Dupont	10 Rue des roses	75016	Paris" 
RegExMatch(xString,"^(?P<Prenom>\w+)\t(?P<Nom>\w+)\t(?P<adresse>\S.+\w+)\t(?P<CP>\d.+)\t(?P<ville>\w.+)$",My)
Msgbox % "prenom" A_Tab "(" MyPrenom ")`nnom" A_Tab "(" MyNom  ")`nadresse" A_Tab "(" Myadresse 
. ")`nCP" A_Tab "(" MyCP ")`nVille" A_Tab "(" MyVille ")"

While this does not create a global or local variable.

Code: Select all

MsgBox, % Main( "Jean	Dupont	10 Rue des roses	75016	Paris" ).Adresse
ExitApp

Main( String ) {
	Local Result := {}
	Local Keys := [ "Prenom", "Nom", "Adresse", "CP", "Ville" ]
	Local LoopField := ""
	Local Count := 1

	While ( Count := RegExMatch( String, "i)([^\t]+)", LoopField, Count + StrLen( LoopField ) )) {
		Result[ Keys[ A_Index ] ] := LoopField
	}

	Return Result
}

Xeo786. Your code did not work as well

[jeeswg]

Using a parsing loop:

Code: Select all

q::
Clipboard := "Jean	Dupont	10 Rue des roses	75016	Paris"
Loop, Parse, Clipboard, %A_Tab%
{
(A_Index = 1) ? (prenom := A_LoopField) : ""
(A_Index = 2) ? (nom := A_LoopField) : ""
(A_Index = 3) ? (adresse := A_LoopField) : ""
(A_Index = 4) ? (CP := A_LoopField) : ""
(A_Index = 5) ? (ville := A_LoopField) : ""
}

MsgBox % prenom "`r`n" nom "`r`n" adresse "`r`n" CP "`r`n" ville
Return

[Didier3L]

Merci à tous