Using one key combination for several commands? Topic is solved

[Scr1pter]

Hi,

Depending on how many times a key combination was pressed,
I would like to execute different commands.

I tried it with a test example, but it didn't work:

Code: Select all

MyNumber := 0
~^+F11::
MyNumber := MyNumber ++
Sleep 3000

if (MyNumber = 1) Run, Calc.exe
if (MyNumber = 2) Run, mspaint.exe

If Ctrl+Shift+F11 gets pressed one time and within 3000 ms not a second time,
Calc.exe should be executed.
If it gets pressed a second time within 3000 ms,
Calc.exe should not be executed but mspaint.exe.

How must be the working code?
Since I got no syntax error when running the code, I guess it's a logical mistake.
Maybe MyNumber is always 0...

Regards

[GEV]

Code: Select all

^+F11::	
CtrlShiftF11_count++      	; start counter
If (CtrlShiftF11_count = 1)
	SetTimer CtrlShiftF11_action, -50
return

	CtrlShiftF11_action:
KeyWait, Ctrl, L
KeyWait, Shift, L
	If (CtrlShiftF11_count = 1)
		MsgBox, CtrlShiftF11_action 1
	If (CtrlShiftF11_count = 2)
		MsgBox, CtrlShiftF11_action 2
; ...
CtrlShiftF11_count := 0      	; reset counter
return

[DyaTactic]

While the hotkey is waiting, no new instances can run due to the default setting of #MaxThreadsPerHotkey. You can change the setting with this command or use SetTimer to work with multiple instances.

Code: Select all

MyNumber := 0

~^+F11::
	;MyNumber := MyNumber ++
	MyNumber ++
	If MyNumber = 1	; Only with the first press: Run the label ‘CtrlShiftF11’ in a new thread.
		SetTimer, CtrlShiftF11, -3000	; Use a negetive value to run the timer only once.
	Return

CtrlShiftF11:
	if (MyNumber = 1)
		Run, Calc.exe
	if (MyNumber = 2)
		Run, mspaint.exe
	if (MyNumber = 3)
		MsgBox hjk
	
	MyNumber := 0
	Return

[Scr1pter]

Thanks for the fast answer - it works perfectly

Also thank you to you, DyaTactic.

Cheers!